chrome/browser/metrics/drive_metrics_provider_mac.mm

   1 // Copyright 2015 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "chrome/browser/metrics/drive_metrics_provider.h"
   6
   7 #include <CoreFoundation/CoreFoundation.h>
   8 #include <DiskArbitration/DiskArbitration.h>
   9 #include <Foundation/Foundation.h>
  10 #include <IOKit/IOKitLib.h>
  11 #include <IOKit/storage/IOStorageDeviceCharacteristics.h>
  12 #include <stdlib.h>
  13 #include <sys/stat.h>
  14
  15 #include "base/files/file_path.h"
  16 #include "base/mac/foundation_util.h"
  17 #include "base/mac/mac_util.h"
  18 #include "base/mac/scoped_cftyperef.h"
  19 #include "base/mac/scoped_ioobject.h"
  20
  21 // static
  22 bool DriveMetricsProvider::HasSeekPenalty(const base::FilePath& path,
  23                                           bool* has_seek_penalty) {
  24   struct stat path_stat;
  25   if (stat(path.value().c_str(), &path_stat) < 0)
  26     return false;
  27
  28   const char* dev_name = devname(path_stat.st_dev, S_IFBLK);
  29   if (!dev_name)
  30     return false;
  31
  32   std::string bsd_name("/dev/");
  33   bsd_name.append(dev_name);
  34
  35   base::ScopedCFTypeRef<DASessionRef> session(
  36       DASessionCreate(kCFAllocatorDefault));
  37   if (!session)
  38     return false;
  39
  40   base::ScopedCFTypeRef<DADiskRef> disk(DADiskCreateFromBSDName(
  41       kCFAllocatorDefault, session, bsd_name.c_str()));
  42   if (!disk)
  43     return false;
  44
  45   base::mac::ScopedIOObject<io_object_t> io_media(DADiskCopyIOMedia(disk));
  46   base::ScopedCFTypeRef<CFDictionaryRef> characteristics(
  47       static_cast<CFDictionaryRef>(IORegistryEntrySearchCFProperty(
  48           io_media,
  49           kIOServicePlane,
  50           CFSTR(kIOPropertyDeviceCharacteristicsKey),
  51           kCFAllocatorDefault,
  52           kIORegistryIterateRecursively | kIORegistryIterateParents)));
  53   if (!characteristics)
  54     return false;
  55
  56   CFStringRef type_ref = base::mac::GetValueFromDictionary<CFStringRef>(
  57       characteristics, CFSTR(kIOPropertyMediumTypeKey));
  58   if (!type_ref)
  59     return false;
  60
  61   NSString* type = base::mac::CFToNSCast(type_ref);
  62   if ([type isEqualToString:@kIOPropertyMediumTypeRotationalKey]) {
  63     *has_seek_penalty = true;
  64     return true;
  65   } else if ([type isEqualToString:@kIOPropertyMediumTypeSolidStateKey]) {
  66     *has_seek_penalty = false;
  67     return true;
  68   }
  69
  70   // TODO(dbeam): should I look for these Rotational/Solid State keys in
  71   // |characteristics|? What if I find device characteristic but there's no
  72   // type? Assume rotational?
  73   return false;
  74 }