chrome/version.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6
   7 # Runs the version processing script over the given template file to produce
   8 # an output file. This is used for generating various forms of files that
   9 # incorporate the product name and version.
  10 #
  11 # Unlike GYP, this will actually compile the resulting file, so you don't need
  12 # to add it separately to the sources, just depend on the target.
  13 #
  14 # This template automatically includes VERSION, LASTCHANGE, and BRANDING. It
  15 # automatically uses the template file .
  16 # GYP parameterizes this template file but all current invocations use this
  17 # same one. If in the future we need to set it, this should be added as an
  18 # optional argument.
  19 #
  20 # In GYP this is a rule that runs once per ".ver" file. In GN this just
  21 # processes one file per invocation of the template so you may have to have
  22 # multiple targets.
  23 #
  24 # You must specify either sources or a template_file, or both.
  25 #
  26 # Parameters:
  27 #   sources (optional):
  28 #     List of file names to read. When converting a GYP target, this should
  29 #     list the 'source' (see above) as well as any extra_variable_files.
  30 #
  31 #   output:
  32 #     File name of file to write. In GYP this is unspecified and it will
  33 #     make up a file name for you based on the input name, and tack on
  34 #     "_version.rc" to the end. But in GN you need to specify the full name.
  35 #
  36 #   template_file (optional):
  37 #     Template file to use (not a list). Defaults to
  38 #     //chrome/app/chrome_version.rc.version if unspecified.
  39 #     TODO(brettw) remove this default behavior and specify it every time.
  40 #
  41 #   extra_args (optional):
  42 #     Extra arguments to pass to version.py. Any "-f <filename>" args should
  43 #     use sources instead.
  44 #
  45 #   process_only (optional, defaults to false)
  46 #     Set to generate only one action that processes the version file and
  47 #     doesn't attempt to link the result into a source set. This is for if
  48 #     you are processing the version as data only.
  49 #
  50 #   visibility (optional)
  51 #
  52 # Example:
  53 #   process_version("myversion") {
  54 #     sources = [ "myfile.h.in" ]
  55 #     output = "$target_gen_dir/myfile.h"
  56 #     extra_args = ["-e", "FOO=42"]
  57 #     extra_files = [ "foo/BRANDING" ]
  58 #   }
  59 template("process_version") {
  60   assert(defined(invoker.sources) || defined(invoker.template_file),
  61          "Either sources or template_file must be defined for $target_name")
  62   assert(defined(invoker.output), "Output must be defined for $target_name")
  63
  64   process_only = defined(invoker.process_only) && invoker.process_only
  65
  66   if (process_only) {
  67     action_name = target_name
  68   } else {
  69     action_name = target_name + "_action"
  70     source_set_name = target_name
  71   }
  72
  73   action(action_name) {
  74     script = "//build/util/version.py"
  75
  76     lastchange_path = "//build/util/LASTCHANGE"
  77     version_path = "//chrome/VERSION"
  78     if (is_chrome_branded) {
  79       branding_path = "//chrome/app/theme/google_chrome/BRANDING"
  80     } else {
  81       branding_path = "//chrome/app/theme/chromium/BRANDING"
  82     }
  83     if (defined(invoker.template_file)) {
  84       template_path = invoker.template_file
  85     } else {
  86       template_path = "//chrome/app/chrome_version.rc.version"
  87     }
  88
  89     inputs = [
  90       version_path,
  91       lastchange_path,
  92       branding_path,
  93       template_path,
  94     ]
  95
  96     outputs = [
  97       invoker.output,
  98     ]
  99
 100     args = []
 101
 102     if (defined(invoker.sources)) {
 103       inputs += invoker.sources
 104       foreach(i, invoker.sources) {
 105         args += [
 106           "-f",
 107           rebase_path(i, root_build_dir),
 108         ]
 109       }
 110     }
 111
 112     args += [
 113       "-f",
 114       rebase_path(version_path, root_build_dir),
 115       "-f",
 116       rebase_path(branding_path, root_build_dir),
 117       "-f",
 118       rebase_path(lastchange_path, root_build_dir),
 119     ]
 120     if (defined(invoker.extra_args)) {
 121       args += invoker.extra_args
 122     }
 123     args += [
 124       rebase_path(template_path, root_build_dir),
 125       rebase_path(invoker.output, root_build_dir),
 126     ]
 127
 128     if (process_only) {
 129       # When processing only, visibility gets applied to this target.
 130       if (defined(invoker.visibility)) {
 131         visibility = invoker.visibility
 132       }
 133     } else {
 134       # When linking the result, only the source set can depend on the action.
 135       visibility = [ ":$source_set_name" ]
 136     }
 137   }
 138
 139   if (!process_only) {
 140     source_set(source_set_name) {
 141       if (defined(invoker.visibility)) {
 142         visibility = invoker.visibility
 143       }
 144       sources = get_target_outputs(":$action_name")
 145       public_deps = [
 146         ":$action_name",
 147       ]
 148     }
 149   }
 150 }