content/child/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//content/child/child.gni")
   9
  10 source_set("child") {
  11   # Only the public target should depend on this. All other targets (even
  12   # internal content ones) should depend on the public one.
  13   visibility = [ "//content/public/child:child_sources" ]
  14
  15   sources = rebase_path(content_child_gypi_values.private_child_sources,
  16                         ".",
  17                         "//content")
  18
  19   public_deps = [
  20     "//third_party/mojo/src/mojo/edk/system",
  21   ]
  22
  23   deps = [
  24     "//base",
  25     "//components/mime_util",
  26     "//components/tracing",
  27     "//components/tracing:startup_tracing",
  28     "//components/webcrypto",
  29     "//content/common:mojo_bindings",
  30     "//mojo/application/public/interfaces",
  31     "//mojo/common",
  32     "//mojo/environment:chromium",
  33     "//skia",
  34     "//third_party/icu",
  35     "//ui/base",
  36     "//ui/events/gestures/blink",
  37     "//ui/gfx",
  38     "//ui/gfx/geometry",
  39     "//ui/native_theme",
  40     "//url",
  41   ]
  42
  43   if (!use_default_render_theme) {
  44     sources -= [
  45       "webthemeengine_impl_default.cc",
  46       "webthemeengine_impl_default.h",
  47     ]
  48   }
  49
  50   if (is_android) {
  51     deps += [ "//third_party/android_tools:cpu_features" ]
  52   }
  53
  54   if (enable_plugins) {
  55     deps += [ "//ppapi/proxy" ]
  56   } else {
  57     sources -= [
  58       "browser_font_resource_trusted.cc",
  59       "npapi/plugin_host.cc",
  60       "npapi/plugin_host.h",
  61       "npapi/plugin_instance.cc",
  62       "npapi/plugin_instance.h",
  63       "npapi/plugin_lib.cc",
  64       "npapi/plugin_lib.h",
  65       "npapi/plugin_stream.cc",
  66       "npapi/plugin_stream.h",
  67       "npapi/plugin_stream_posix.cc",
  68       "npapi/plugin_stream_url.cc",
  69       "npapi/plugin_stream_url.h",
  70       "npapi/plugin_string_stream.cc",
  71       "npapi/plugin_string_stream.h",
  72       "npapi/plugin_url_fetcher.cc",
  73       "npapi/plugin_url_fetcher.h",
  74       "npapi/webplugin.h",
  75       "npapi/webplugin_delegate.h",
  76       "npapi/webplugin_delegate_impl.cc",
  77       "npapi/webplugin_delegate_impl.h",
  78       "npapi/webplugin_resource_client.h",
  79     ]
  80
  81     if (is_mac) {
  82       sources -= [
  83         "npapi/plugin_instance_mac.mm",
  84         "npapi/plugin_web_event_converter_mac.h",
  85         "npapi/plugin_web_event_converter_mac.mm",
  86         "npapi/webplugin_accelerated_surface_mac.h",
  87         "npapi/webplugin_delegate_impl_mac.mm",
  88       ]
  89     } else if (is_win) {
  90       sources -= [
  91         "npapi/plugin_stream_win.cc",
  92         "npapi/webplugin_delegate_impl_win.cc",
  93         "npapi/webplugin_ime_win.cc",
  94         "npapi/webplugin_ime_win.h",
  95       ]
  96     } else if (is_android) {
  97       sources -= [ "npapi/webplugin_delegate_impl_android.cc" ]
  98     }
  99     if (use_aura) {
 100       sources -= [ "npapi/webplugin_delegate_impl_aura.cc" ]
 101     }
 102   }
 103
 104   configs += [
 105     "//content:content_implementation",
 106     "//build/config/compiler:no_size_t_to_int_warning",
 107   ]
 108
 109   if (is_ios) {
 110     # iOS only needs a small portion of content; exclude all the
 111     # implementation, and re-include what is used.
 112     sources = []
 113   } else {
 114     deps += [
 115       "//components/scheduler:scheduler",
 116       "//content/app/resources",
 117       "//content/app/strings",
 118       "//crypto:platform",
 119       "//storage/common",
 120       "//third_party/WebKit/public:blink",
 121       "//third_party/WebKit/public:image_resources",
 122       "//third_party/WebKit/public:resources",
 123       "//third_party/npapi",
 124     ]
 125   }
 126
 127   if (use_aura && is_mac) {
 128     # This file is already excluded on non-Mac.
 129     sources -= [ "npapi/webplugin_delegate_impl_mac.mm" ]
 130   }
 131
 132   if (is_win || !use_aura) {
 133     sources -= [ "npapi/webplugin_delegate_impl_aura.cc" ]
 134   }
 135 }