device/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//testing/test.gni")
   7
   8 if (is_android) {
   9   import("//build/config/android/rules.gni")  # For generate_jni().
  10 }
  11
  12 if (is_mac) {
  13   import("//build/config/mac/mac_sdk.gni")
  14 }
  15
  16 is_linux_without_udev = is_linux && !use_udev
  17 is_linux_without_dbus = is_linux && !use_dbus
  18
  19 test("device_unittests") {
  20   sources = [
  21     "battery/battery_status_manager_win_unittest.cc",
  22     "battery/battery_status_service_unittest.cc",
  23     "bluetooth/bluetooth_adapter_mac_unittest.mm",
  24     "bluetooth/bluetooth_adapter_profile_chromeos_unittest.cc",
  25     "bluetooth/bluetooth_adapter_unittest.cc",
  26     "bluetooth/bluetooth_adapter_win_unittest.cc",
  27     "bluetooth/bluetooth_advertisement_chromeos_unittest.cc",
  28     "bluetooth/bluetooth_audio_sink_chromeos_unittest.cc",
  29     "bluetooth/bluetooth_chromeos_unittest.cc",
  30     "bluetooth/bluetooth_device_unittest.cc",
  31     "bluetooth/bluetooth_device_win_unittest.cc",
  32     "bluetooth/bluetooth_discovery_filter_unittest.cc",
  33     "bluetooth/bluetooth_gatt_chromeos_unittest.cc",
  34     "bluetooth/bluetooth_low_energy_win_unittest.cc",
  35     "bluetooth/bluetooth_service_record_win_unittest.cc",
  36     "bluetooth/bluetooth_socket_chromeos_unittest.cc",
  37     "bluetooth/bluetooth_task_manager_win_unittest.cc",
  38     "bluetooth/bluetooth_uuid_unittest.cc",
  39     "bluetooth/test/bluetooth_test.cc",
  40     "bluetooth/test/bluetooth_test.h",
  41     "bluetooth/test/bluetooth_test_android.cc",
  42     "bluetooth/test/bluetooth_test_android.h",
  43     "bluetooth/test/bluetooth_test_mac.h",
  44     "bluetooth/test/bluetooth_test_mac.mm",
  45     "bluetooth/test/test_bluetooth_adapter_observer.cc",
  46     "bluetooth/test/test_bluetooth_adapter_observer.h",
  47     "nfc/nfc_chromeos_unittest.cc",
  48     "nfc/nfc_ndef_record_unittest.cc",
  49     "test/run_all_unittests.cc",
  50   ]
  51
  52   deps = [
  53     "//base/test:test_support",
  54     "//device/battery",
  55     "//device/battery:mojo_bindings",
  56     "//device/bluetooth",
  57     "//device/nfc",
  58     "//mojo/environment:chromium",
  59     "//net",
  60     "//testing/gmock",
  61     "//testing/gtest",
  62     "//third_party/mojo/src/mojo/edk/system",
  63     "//third_party/mojo/src/mojo/public/cpp/bindings",
  64     "//url",
  65   ]
  66
  67   if (!is_linux_without_dbus && !is_chromeos) {
  68     sources += [ "battery/battery_status_manager_linux_unittest.cc" ]
  69   }
  70
  71   # HID and Serial:
  72   # Android doesn't compile.
  73   # Linux, requires udev.
  74   if (!is_linux_without_udev && !is_android) {
  75     sources += [
  76       "hid/hid_connection_unittest.cc",
  77       "hid/hid_device_filter_unittest.cc",
  78       "hid/hid_report_descriptor_unittest.cc",
  79       "hid/input_service_linux_unittest.cc",
  80       "hid/test_report_descriptors.cc",
  81       "hid/test_report_descriptors.h",
  82       "serial/data_sink_unittest.cc",
  83       "serial/data_source_unittest.cc",
  84       "serial/serial_connection_unittest.cc",
  85       "serial/serial_service_unittest.cc",
  86     ]
  87     deps += [
  88       "//device/hid",
  89       "//device/serial",
  90       "//device/serial:test_support",
  91     ]
  92   }
  93
  94   if (use_udev) {
  95     sources += [ "udev_linux/udev_unittest.cc" ]
  96     deps += [ "//device/udev_linux" ]
  97   }
  98
  99   # USB does not compile on mobile platforms.
 100   if (!is_android && !is_ios) {
 101     sources += [
 102       "devices_app/usb/device_impl_unittest.cc",
 103       "devices_app/usb/device_manager_impl_unittest.cc",
 104       "test/usb_test_gadget_impl.cc",
 105       "usb/usb_context_unittest.cc",
 106       "usb/usb_device_filter_unittest.cc",
 107       "usb/usb_device_handle_unittest.cc",
 108       "usb/usb_ids_unittest.cc",
 109       "usb/usb_service_unittest.cc",
 110     ]
 111     deps += [
 112       "//device/core",
 113       "//device/devices_app:lib",
 114       "//device/devices_app/usb/public/cpp",
 115       "//device/devices_app/usb/public/interfaces",
 116       "//device/usb",
 117       "//device/usb:mocks",
 118       "//third_party/libusb",
 119     ]
 120   }
 121
 122   if (is_android) {
 123     deps += [ ":bluetooth_test_jni_headers" ]
 124     apk_deps = [ ":bluetooth_test_java" ]
 125   }
 126
 127   if (is_chromeos) {
 128     configs += [ "//build/config/linux:dbus" ]
 129
 130     deps += [
 131       "//chromeos",
 132       "//chromeos:test_support",
 133       "//chromeos:test_support_without_gmock",
 134       "//dbus",
 135     ]
 136   }
 137
 138   if (is_posix && !is_android && !is_mac) {
 139     libs = [ "rt" ]
 140   }
 141
 142   if (is_mac) {
 143     deps += [ "//third_party/ocmock" ]
 144     ldflags = [ "-ObjC" ]
 145     libs = [ "IOBluetooth.framework" ]
 146
 147     # In the OSX 10.10 SDK, CoreBluetooth became a top level framework.
 148     # Previously, it was nested in IOBluetooth. In order for Chrome to run on
 149     # OSes older than OSX 10.10, the top level CoreBluetooth framework must be
 150     # weakly linked.
 151     if (mac_sdk_version == "10.10") {
 152       ldflags += [ "-weak_framework CoreBluetooth" ]
 153     }
 154   }
 155 }
 156
 157 if (is_android) {
 158   bluetooth_java_sources_needing_jni = [ "bluetooth/test/android/java/src/org/chromium/device/bluetooth/Fakes.java" ]
 159
 160   generate_jni("bluetooth_test_jni_headers") {
 161     sources = bluetooth_java_sources_needing_jni
 162     jni_package = "bluetooth"
 163   }
 164
 165   android_library("bluetooth_test_java") {
 166     java_files = bluetooth_java_sources_needing_jni
 167     deps = [
 168       "//base:base_java",
 169       "//device/bluetooth:java",
 170     ]
 171   }
 172 }