mojo/application/public/cpp/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # GYP version: mojo/mojo_base.gyp:mojo_application_base
   6 source_set("cpp") {
   7   public_deps = [
   8     ":sources",
   9     ":init_commandline",
  10   ]
  11 }
  12
  13 # Like the target above, but without special commandline initialization that
  14 # apps use.
  15 source_set("cpp_for_chromium") {
  16   public_deps = [
  17     ":sources",
  18   ]
  19 }
  20
  21 source_set("sources") {
  22   sources = [
  23     "app_lifetime_helper.h",
  24     "application_connection.h",
  25     "application_delegate.h",
  26     "application_impl.h",
  27     "application_runner.h",
  28     "connect.h",
  29     "interface_factory.h",
  30     "interface_factory_impl.h",
  31     "lib/app_lifetime_helper.cc",
  32     "lib/application_connection.cc",
  33     "lib/application_delegate.cc",
  34     "lib/application_impl.cc",
  35     "lib/application_runner.cc",
  36     "lib/interface_factory_connector.h",
  37     "lib/service_connector_registry.cc",
  38     "lib/service_connector_registry.h",
  39     "lib/service_provider_impl.cc",
  40     "lib/service_registry.cc",
  41     "lib/service_registry.h",
  42     "service_connector.h",
  43     "service_provider_impl.h",
  44   ]
  45
  46   deps = [
  47     "//base",
  48     "//mojo/application/public/interfaces",
  49     "//mojo/common",
  50     "//mojo/environment:chromium",
  51     "//third_party/mojo/src/mojo/public/cpp/bindings",
  52     "//third_party/mojo/src/mojo/public/cpp/system",
  53   ]
  54 }
  55
  56 source_set("init_commandline") {
  57   sources = [
  58     "lib/init_commandline.cc",
  59   ]
  60 }
  61
  62 source_set("content_handler") {
  63   sources = [
  64     "content_handler_factory.h",
  65     "lib/content_handler_factory.cc",
  66   ]
  67   deps = [
  68     ":cpp",
  69
  70     # TODO: this code should not depend on base.
  71     "//base",
  72     "//mojo/application/public/interfaces:interfaces_cpp_sources",
  73
  74     # TODO: this code should not depend on mojo/common.
  75     "//mojo/common:common_base",
  76     "//mojo/services/network/public/interfaces",
  77   ]
  78 }
  79
  80 source_set("test_support") {
  81   testonly = true
  82   sources = [
  83     "application_test_base.h",
  84     "lib/application_test_base.cc",
  85     "lib/application_test_main.cc",
  86   ]
  87
  88   deps = [
  89     ":cpp",
  90     "//base",
  91     "//base/test:test_support",
  92     "//mojo/application/public/interfaces:interfaces_cpp_sources",
  93     "//third_party/mojo/src/mojo/public/cpp/bindings",
  94     "//third_party/mojo/src/mojo/public/cpp/environment",
  95     "//third_party/mojo/src/mojo/public/cpp/system",
  96     "//testing/gtest",
  97   ]
  98
  99   data_deps = []
 100   if (is_android) {
 101     data_deps += [ "//mojo/android" ]
 102   }
 103   if (!is_component_build) {
 104     data_deps += [ "//mojo/runner" ]
 105   }
 106 }