mojo/services/network/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//mojo/public/mojo_application.gni")
   6
   7 if (is_android) {
   8   import("//build/config/android/rules.gni")
   9
  10   java_library_path = "$target_out_dir/java_library.dex.jar"
  11
  12   mojo_android_application("network") {
  13     output_name = "network_service"
  14     input_so = "$root_out_dir/lib.stripped/libnetwork_service$android_product_extension"
  15     input_dex_jar = java_library_path
  16     deps = [
  17       ":java_library",
  18       ":native_library",
  19     ]
  20   }
  21
  22   shared_library("native_library") {
  23     output_name = "network_service"
  24
  25     sources = [
  26       "android_hooks.cc",
  27     ]
  28
  29     deps = [
  30       ":sources",
  31       "//base",
  32       "//net",
  33     ]
  34   }
  35
  36   android_standalone_library("java_library") {
  37     dex_path = java_library_path
  38
  39     deps = [
  40       "//net/android:net_java",
  41     ]
  42   }
  43 } else {
  44   mojo_native_application("network") {
  45     output_name = "network_service"
  46
  47     deps = [
  48       ":sources",
  49     ]
  50   }
  51 }
  52
  53 source_set("lib") {
  54   sources = [
  55     "cookie_store_impl.cc",
  56     "cookie_store_impl.h",
  57     "http_connection_impl.cc",
  58     "http_connection_impl.h",
  59     "http_server_impl.cc",
  60     "http_server_impl.h",
  61     "mojo_persistent_cookie_store.cc",
  62     "mojo_persistent_cookie_store.h",
  63     "net_adapters.cc",
  64     "net_adapters.h",
  65     "net_address_type_converters.cc",
  66     "net_address_type_converters.h",
  67     "network_context.cc",
  68     "network_context.h",
  69     "network_service_delegate.cc",
  70     "network_service_delegate.h",
  71     "network_service_delegate_observer.h",
  72     "network_service_impl.cc",
  73     "network_service_impl.h",
  74     "tcp_bound_socket_impl.cc",
  75     "tcp_bound_socket_impl.h",
  76     "tcp_connected_socket_impl.cc",
  77     "tcp_connected_socket_impl.h",
  78     "tcp_server_socket_impl.cc",
  79     "tcp_server_socket_impl.h",
  80     "udp_socket_impl.cc",
  81     "udp_socket_impl.h",
  82     "url_loader_factory_impl.cc",
  83     "url_loader_factory_impl.h",
  84     "url_loader_impl.cc",
  85     "url_loader_impl.h",
  86     "web_socket_impl.cc",
  87     "web_socket_impl.h",
  88   ]
  89
  90   deps = [
  91     "//base",
  92     "//components/filesystem/public/interfaces",
  93     "//mojo/application/public/cpp",
  94     "//mojo/common:common_base",
  95     "//mojo/common:url_type_converters",
  96     "//mojo/services/network/public/cpp",
  97     "//mojo/services/network/public/interfaces",
  98     "//net",
  99     "//net:extras",
 100     "//net:http_server",
 101     "//url",
 102     "//sql/mojo",
 103     "//third_party/mojo/src/mojo/public/cpp/system:system",
 104   ]
 105 }
 106
 107 source_set("sources") {
 108   visibility = [ ":*" ]
 109
 110   sources = [
 111     "main.cc",
 112   ]
 113
 114   deps = [
 115     ":lib",
 116     "//base",
 117     "//mojo/application/public/cpp",
 118     "//mojo/services/network/public/cpp",
 119     "//mojo/services/network/public/interfaces",
 120     "//third_party/mojo/src/mojo/public/c/system:for_shared_library",
 121     "//third_party/mojo/src/mojo/public/cpp/bindings:bindings",
 122   ]
 123 }
 124
 125 mojo_native_application("apptests") {
 126   output_name = "network_service_apptests"
 127   testonly = true
 128
 129   sources = [
 130     "http_server_apptest.cc",
 131     "udp_socket_apptest.cc",
 132     "url_loader_impl_apptest.cc",
 133   ]
 134
 135   deps = [
 136     ":lib",
 137     ":network",
 138     "//base",
 139     "//mojo/application/public/cpp:sources",
 140     "//mojo/application/public/cpp:test_support",
 141     "//mojo/common:common_base",
 142     "//mojo/services/network/public/cpp",
 143     "//mojo/services/network/public/interfaces",
 144     "//net",
 145     "//net:test_support",
 146     "//testing/gtest",
 147     "//third_party/mojo/src/mojo/public/cpp/bindings:callback",
 148   ]
 149 }