remoting/webapp/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # Keep in sync with targets in remoting/remoting_client.gypi.
   6
   7 import("//build/config/features.gni")
   8 import("//remoting/webapp/build_template.gni")
   9 import("//remoting/webapp/files.gni")
  10
  11 group("webapp") {
  12   deps = [
  13     ":webapp_v1",
  14     ":ar_sample_app",
  15     ":credits",
  16     ":ar_shared_module",
  17   ]
  18
  19   if (enable_internal_app_remoting_targets) {
  20     deps += [ "//remoting/internal:ar_internal_apps" ]
  21   }
  22
  23   if (enable_nacl) {
  24     deps += [ ":webapp_v2" ]
  25   }
  26 }
  27
  28 # GYP version: remoting/remoting_client:remoting_credits
  29 action("credits") {
  30   about_credits_file = "$target_gen_dir/credits.html"
  31   script = "//tools/licenses.py"
  32
  33   inputs = [
  34     "base/html/credits.tmpl",
  35     "base/html/credits_entry.tmpl",
  36   ]
  37
  38   outputs = [
  39     about_credits_file,
  40   ]
  41
  42   args = [
  43     "credits",
  44     rebase_path(about_credits_file, root_build_dir),
  45     "--file-template",
  46     rebase_path("base/html/credits.tmpl", root_build_dir),
  47     "--entry-template",
  48     rebase_path("base/html/credits_entry.tmpl", root_build_dir),
  49   ]
  50 }
  51
  52 desktop_remoting_webapp("webapp_v1") {
  53   webapp_type = "v1"
  54   output_dir = "remoting/remoting-webapp"
  55   zip_path = "remoting/remoting-webapp.zip"
  56   extra_files = []
  57 }
  58
  59 desktop_remoting_webapp("webapp_v2") {
  60   webapp_type = "v2_pnacl"
  61   output_dir = "remoting/remoting-webapp.v2"
  62   zip_path = "remoting/remoting-webapp.v2.zip"
  63   extra_files = [
  64     "crd/remoting_client_pnacl.nmf.jinja2",
  65     # TODO(garykac): Get correct path to this.
  66     #"<(PRODUCT_DIR)/remoting_client_plugin_newlib.pexe",
  67   ]
  68 }
  69
  70 app_remoting_webapp("ar_sample_app") {
  71   app_key = "Sample_App"
  72   app_id = "ljacajndfccfgnfohlgkdphmbnpkjflk"
  73   app_client_id = "sample_client_id"
  74   app_vendor = ""
  75   app_name = "sample_app"
  76   app_fullname = "App Remoting Client"
  77   app_description = "App Remoting client"
  78   app_capabilities = [ "GOOGLE_DRIVE" ]
  79   manifest_key = "remotingdevbuild"
  80 }
  81
  82 app_remoting_shared_module("ar_shared_module") {
  83   #app_client_id = "sample_client_id"
  84   app_name = "shared_module"
  85 }
  86
  87 # GYP version: remoting/remoting_tests.gypi:remoting_browser_test_resources
  88 copy("browser_test_resources") {
  89   sources = remoting_webapp_browsertest_main_html_extra_files
  90   outputs = [
  91     "$root_out_dir/remoting/browser_test_resources/{{source_file_part}}",
  92   ]
  93 }
  94
  95 remoting_unit_test_out_dir = "$root_out_dir/remoting/unittests"
  96
  97 group("unit_tests") {
  98   data_deps = [
  99     ":blanketjs",
 100     ":js_files",
 101     ":qunit",
 102     ":sinonjs",
 103   ]
 104 }
 105
 106 copy("js_files") {
 107   # This list corresponds to webapp_js_files in remoting_webapp_unittests
 108   # target in GYP.
 109   sources = remoting_webapp_unittest_html_all_js_files +
 110             remoting_webapp_wcs_sandbox_html_js_files +
 111             remoting_webapp_background_html_js_files +
 112             remoting_webapp_unittests_all_files
 113   outputs = [
 114     "$remoting_unit_test_out_dir/{{source_file_part}}",
 115   ]
 116 }
 117
 118 copy("blanketjs") {
 119   sources = [
 120     "//third_party/blanketjs/src/blanket.js",
 121     "//third_party/blanketjs/src/qunit_adapter.js",
 122   ]
 123   outputs = [
 124     "$remoting_unit_test_out_dir/blanketjs/{{source_file_part}}",
 125   ]
 126 }
 127
 128 copy("sinonjs") {
 129   sources = [
 130     "//third_party/sinonjs/src/sinon-qunit.js",
 131     "//third_party/sinonjs/src/sinon.js",
 132   ]
 133   outputs = [
 134     "$remoting_unit_test_out_dir/sinonjs/{{source_file_part}}",
 135   ]
 136 }
 137
 138 copy("qunit") {
 139   sources = [
 140     "//third_party/qunit/src/browser_test_harness.js",
 141     "//third_party/qunit/src/qunit.css",
 142     "//third_party/qunit/src/qunit.js",
 143   ]
 144   outputs = [
 145     "$remoting_unit_test_out_dir/qunit/{{source_file_part}}",
 146   ]
 147 }