skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 if (current_cpu == "arm") {
   9   import("//build/config/arm.gni")
  10 }
  11 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
  12   import("//build/config/mips.gni")
  13 }
  14
  15 skia_support_gpu = !is_ios
  16 skia_support_pdf = !is_ios && (enable_basic_printing || enable_print_preview)
  17
  18 # The list of Skia defines that are to be set for blink.
  19 gypi_blink_skia_defines =
  20     exec_script("//build/gypi_to_gn.py",
  21                 [
  22                   rebase_path(
  23                       "//third_party/WebKit/public/blink_skia_config.gypi"),
  24                   "--replace=<(skia_include_path)=//third_party/skia/include",
  25                   "--replace=<(skia_src_path)=//third_party/skia/src",
  26                 ],
  27                 "scope",
  28                 [ "//third_party/WebKit/public/blink_skia_config.gypi" ])
  29
  30 # The list of Skia defines that are to be set for chromium.
  31 gypi_skia_defines =
  32     exec_script("//build/gypi_to_gn.py",
  33                 [
  34                   rebase_path(
  35                       "//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  36                   "--replace=<(skia_include_path)=//third_party/skia/include",
  37                   "--replace=<(skia_src_path)=//third_party/skia/src",
  38                 ],
  39                 "scope",
  40                 [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  41
  42 # The list of Skia core sources that are to be set for chromium.
  43 gypi_skia_core =
  44     exec_script("//build/gypi_to_gn.py",
  45                 [
  46                   rebase_path("//third_party/skia/gyp/core.gypi"),
  47                   "--replace=<(skia_include_path)=//third_party/skia/include",
  48                   "--replace=<(skia_src_path)=//third_party/skia/src",
  49                 ],
  50                 "scope",
  51                 [ "//third_party/skia/gyp/core.gypi" ])
  52
  53 # The list of Skia gpu sources that are to be set for chromium.
  54 if (skia_support_gpu) {
  55   gypi_skia_gpu =
  56       exec_script("//build/gypi_to_gn.py",
  57                   [
  58                     rebase_path("//third_party/skia/gyp/gpu.gypi"),
  59                     "--replace=<(skia_include_path)=//third_party/skia/include",
  60                     "--replace=<(skia_src_path)=//third_party/skia/src",
  61                   ],
  62                   "scope",
  63                   [ "//third_party/skia/gyp/gpu.gypi" ])
  64 }
  65
  66 # The list of Skia pdf sources that are to be set for chromium.
  67 if (skia_support_pdf) {
  68   gypi_skia_pdf =
  69       exec_script("//build/gypi_to_gn.py",
  70                   [
  71                     rebase_path("//third_party/skia/gyp/pdf.gypi"),
  72                     "--replace=<(skia_include_path)=//third_party/skia/include",
  73                     "--replace=<(skia_src_path)=//third_party/skia/src",
  74                   ],
  75                   "scope",
  76                   [ "//third_party/skia/gyp/pdf.gypi" ])
  77 }
  78
  79 # The list of Skia effects that are to be set for chromium.
  80 gypi_skia_effects =
  81     exec_script("//build/gypi_to_gn.py",
  82                 [
  83                   rebase_path("//third_party/skia/gyp/effects.gypi"),
  84                   "--replace=<(skia_include_path)=//third_party/skia/include",
  85                   "--replace=<(skia_src_path)=//third_party/skia/src",
  86                 ],
  87                 "scope",
  88                 [ "//third_party/skia/gyp/effects.gypi" ])
  89
  90 # The list of Skia utils that are to be set for chromium.
  91 gypi_skia_utils =
  92     exec_script("//build/gypi_to_gn.py",
  93                 [
  94                   rebase_path("//third_party/skia/gyp/utils.gypi"),
  95                   "--replace=<(skia_include_path)=//third_party/skia/include",
  96                   "--replace=<(skia_src_path)=//third_party/skia/src",
  97                 ],
  98                 "scope",
  99                 [ "//third_party/skia/gyp/utils.gypi" ])
 100
 101 gypi_skia_opts =
 102     exec_script("//build/gypi_to_gn.py",
 103                 [
 104                   rebase_path("//third_party/skia/gyp/opts.gypi"),
 105                   "--replace=<(skia_include_path)=//third_party/skia/include",
 106                   "--replace=<(skia_src_path)=//third_party/skia/src",
 107                 ],
 108                 "scope",
 109                 [ "//third_party/skia/gyp/opts.gypi" ])
 110
 111 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
 112 gypi_values =
 113     exec_script("//build/gypi_to_gn.py",
 114                 [
 115                   rebase_path("skia_gn_files.gypi"),
 116                   "--replace=<(skia_include_path)=//third_party/skia/include",
 117                   "--replace=<(skia_src_path)=//third_party/skia/src",
 118                 ],
 119                 "scope",
 120                 [ "skia_gn_files.gypi" ])
 121
 122 # External-facing config for dependent code.
 123 config("skia_config") {
 124   include_dirs = [
 125     "config",
 126     "ext",
 127     "//third_party/skia/include/c",
 128     "//third_party/skia/include/config",
 129     "//third_party/skia/include/core",
 130     "//third_party/skia/include/effects",
 131     "//third_party/skia/include/images",
 132     "//third_party/skia/include/lazy",
 133     "//third_party/skia/include/pathops",
 134     "//third_party/skia/include/pdf",
 135     "//third_party/skia/include/pipe",
 136     "//third_party/skia/include/ports",
 137     "//third_party/skia/include/utils",
 138   ]
 139
 140   defines = gypi_blink_skia_defines.blink_skia_defines
 141   defines += gypi_skia_defines.skia_for_chromium_defines
 142
 143   defines += []
 144
 145   if (component_mode == "shared_library") {
 146     defines += [
 147       "SKIA_DLL",
 148       "GR_GL_IGNORE_ES3_MSAA=0",
 149     ]
 150   }
 151
 152   if (skia_support_gpu) {
 153     include_dirs += [
 154       "//third_party/skia/include/gpu",
 155       "//third_party/skia/src/gpu",
 156     ]
 157     defines += [ "SK_SUPPORT_GPU=1" ]
 158   } else {
 159     defines += [ "SK_SUPPORT_GPU=0" ]
 160   }
 161
 162   if (is_android) {
 163     defines += [
 164       "SK_BUILD_FOR_ANDROID",
 165       "USE_CHROMIUM_SKIA",
 166     ]
 167   }
 168
 169   if (is_mac) {
 170     defines += [ "SK_BUILD_FOR_MAC" ]
 171   }
 172 }
 173
 174 # Internal-facing config for Skia library code.
 175 config("skia_library_config") {
 176   # These include directories are only included for Skia code and are not
 177   # exported to dependents. It's not clear if this is on purpose, but this
 178   # matches the GYP build.
 179   include_dirs = [
 180     "//third_party/skia/include/private",
 181     "//third_party/skia/src/core",
 182     "//third_party/skia/src/image",
 183     "//third_party/skia/src/opts",
 184     "//third_party/skia/src/pdf",
 185     "//third_party/skia/src/ports",
 186     "//third_party/skia/src/sfnt",
 187     "//third_party/skia/src/utils",
 188     "//third_party/skia/src/lazy",
 189   ]
 190   if (is_mac || is_ios) {
 191     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 192   }
 193   if (is_mac) {
 194     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 195   }
 196
 197   defines = []
 198
 199   if (component_mode == "shared_library") {
 200     defines += [ "SKIA_IMPLEMENTATION=1" ]
 201   }
 202
 203   if (current_cpu == "arm") {
 204     if (arm_use_neon) {
 205       defines += [ "SK_ARM_HAS_NEON" ]
 206     } else if (arm_optionally_use_neon) {
 207       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 208     }
 209   }
 210
 211   # Settings for text blitting, chosen to approximate the system browser.
 212   if (is_linux) {
 213     defines += [
 214       "SK_GAMMA_EXPONENT=1.2",
 215       "SK_GAMMA_CONTRAST=0.2",
 216     ]
 217   } else if (is_android) {
 218     defines += [
 219       "SK_GAMMA_APPLY_TO_A8",
 220       "SK_GAMMA_EXPONENT=1.4",
 221       "SK_GAMMA_CONTRAST=0.0",
 222     ]
 223   } else if (is_win) {
 224     defines += [
 225       "SK_GAMMA_SRGB",
 226       "SK_GAMMA_CONTRAST=0.5",
 227     ]
 228   } else if (is_mac) {
 229     defines += [
 230       "SK_GAMMA_SRGB",
 231       "SK_GAMMA_CONTRAST=0.0",
 232     ]
 233   }
 234
 235   if (is_android) {
 236     defines += [
 237       # Android devices are typically more memory constrained, so default to a
 238       # smaller glyph cache (it may be overriden at runtime when the renderer
 239       # starts up, depending on the actual device memory).
 240       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576",  # 1024 * 1024
 241     ]
 242   } else {
 243     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 244   }
 245
 246   if (is_win) {
 247     include_dirs += [
 248       "//third_party/skia/include/utils/win",
 249       "//third_party/skia/src/utils/win",
 250     ]
 251
 252     defines += [
 253       # On windows, GDI handles are a scarse system-wide resource so we have to
 254       # keep the glyph cache, which holds up to 4 GDI handles per entry, to a
 255       # fairly small size. http://crbug.com/314387
 256       "SK_DEFAULT_FONT_CACHE_COUNT_LIMIT=256",
 257     ]
 258
 259     cflags = [
 260       "/wd4244",  # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 261       "/wd4267",  # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 262       "/wd4341",  # signed value is out of range for enum constant.
 263       "/wd4345",  # Object is default-initialized if initialization is omitted.
 264       "/wd4390",  # ';'empty statement found in looping;is it what was intended?
 265       "/wd4554",  # 'operator' : check operator precedence for possible error
 266       "/wd4748",  # compiler will disable optimizations if a function has inline
 267                   # assembly code contains flow control(jmp or jcc) statements.
 268
 269       "/wd4800",  # forcing value to bool 'true/false'(assigning int to bool).
 270     ]
 271   }
 272 }
 273
 274 component("skia") {
 275   sources = [
 276     # Chrome sources.
 277     "ext/SkDiscardableMemory_chrome.cc",
 278     "ext/SkMemory_new_handler.cpp",
 279     "ext/analysis_canvas.cc",
 280     "ext/benchmarking_canvas.cc",
 281     "ext/convolver.cc",
 282     "ext/event_tracer_impl.cc",
 283     "ext/fontmgr_default_win.cc",
 284     "ext/google_logging.cc",
 285     "ext/image_operations.cc",
 286     "ext/opacity_filter_canvas.cc",
 287     "ext/pixel_ref_utils.cc",
 288     "ext/platform_canvas.cc",
 289     "ext/platform_device.cc",
 290     "ext/platform_device_linux.cc",
 291     "ext/platform_device_mac.cc",
 292     "ext/platform_device_win.cc",
 293     "ext/recursive_gaussian_convolution.cc",
 294     "ext/skia_utils_base.cc",
 295     "ext/skia_utils_ios.mm",
 296     "ext/skia_utils_mac.mm",
 297     "ext/skia_utils_win.cc",
 298   ]
 299
 300   if (current_cpu == "x86" || current_cpu == "x64") {
 301     sources += [ "ext/convolver_SSE2.cc" ]
 302   } else if (current_cpu == "mipsel" && mips_dsp_rev >= 2) {
 303     sources += [ "ext/convolver_mips_dspr2.cc" ]
 304   }
 305
 306   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 307   sources += gypi_skia_core.sources
 308   sources += gypi_skia_effects.sources
 309   sources += gypi_skia_utils.sources
 310   sources += gypi_values.skia_library_sources
 311
 312   # This and skia_opts are really the same conceptual target so share headers.
 313   allow_circular_includes_from = [ ":skia_opts" ]
 314
 315   if (current_cpu == "arm") {
 316     sources += [ "//third_party/skia/src/core/SkUtilsArm.cpp" ]
 317   }
 318
 319   # GPU
 320   if (skia_support_gpu) {
 321     sources += gypi_skia_gpu.skgpu_sources
 322     sources += gypi_skia_gpu.skgpu_null_gl_sources
 323   }
 324
 325   # Remove unused util files include in utils.gypi
 326   sources -= [
 327     "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 328     "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 329     "//third_party/skia/src/utils/SkCamera.cpp",
 330     "//third_party/skia/src/utils/SkCubicInterval.cpp",
 331     "//third_party/skia/src/utils/SkCullPoints.cpp",
 332     "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 333     "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 334     "//third_party/skia/src/utils/SkInterpolator.cpp",
 335     "//third_party/skia/src/utils/SkLayer.cpp",
 336     "//third_party/skia/src/utils/SkMD5.cpp",
 337     "//third_party/skia/src/utils/SkMeshUtils.cpp",
 338     "//third_party/skia/src/utils/SkNinePatch.cpp",
 339     "//third_party/skia/src/utils/SkOSFile.cpp",
 340     "//third_party/skia/src/utils/SkParsePath.cpp",
 341     "//third_party/skia/src/utils/SkSHA1.cpp",
 342
 343     # We don't currently need to change thread affinity, so leave out this complexity for now.
 344     "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 345     "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 346
 347     #testing
 348     "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 349   ]
 350
 351   if (is_win) {
 352     sources -= [
 353       # Keeping _win.cpp
 354       "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 355       "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 356     ]
 357   } else {
 358     sources -= [
 359       # Keeping _pthread.cpp and _pthread_other.cpp.
 360       "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 361     ]
 362   }
 363
 364   # need separate win section to handle chromes auto gn filter
 365   # (build/config/BUILDCONFIG.gn)
 366   if (is_win) {
 367     sources -= [
 368       #windows
 369       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 370       "//third_party/skia/src/utils/win/SkIStream.cpp",
 371       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 372     ]
 373   }
 374
 375   if (is_android && (!enable_basic_printing && !enable_print_preview)) {
 376     sources -= [ "ext/skia_utils_base.cc" ]
 377   }
 378
 379   # Fixup skia library sources.
 380   if (is_win) {
 381     sources -= [
 382       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 383       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 384       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 385     ]
 386   } else {
 387     sources -= [
 388       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 389       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 390       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 391       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 392       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 393       "//third_party/skia/src/ports/SkTLS_win.cpp",
 394       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 395     ]
 396   }
 397   if (!is_android) {
 398     sources -= [
 399       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 400       "//third_party/skia/src/ports/SkFontMgr_android_factory.cpp",
 401       "//third_party/skia/src/ports/SkFontMgr_android_parser.cpp",
 402     ]
 403   }
 404   if (!is_mac) {
 405     sources -= [ "//third_party/skia/src/ports/SkFontHost_mac.cpp" ]
 406   }
 407
 408   if (!is_linux) {
 409     sources -= [
 410       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 411       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 412       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 413     ]
 414   }
 415
 416   if (!is_linux && !is_android) {
 417     sources -= [
 418       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 419       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 420     ]
 421   }
 422
 423   # Select the right BitmapPlatformDevice.
 424   if (is_win) {
 425     sources += [ "ext/bitmap_platform_device_win.cc" ]
 426   } else if (is_mac) {
 427     sources += [ "ext/bitmap_platform_device_mac.cc" ]
 428   } else if (use_cairo) {
 429     sources += [ "ext/bitmap_platform_device_cairo.cc" ]
 430   } else {
 431     sources += [ "ext/bitmap_platform_device_skia.cc" ]
 432   }
 433
 434   if (is_clang) {
 435     # Skia won't compile with some of the more strict clang warnings.
 436     # e.g. it does:
 437     #  SkASSERT(!"sk_out_of_memory");
 438     configs -= [ "//build/config/clang:extra_warnings" ]
 439   }
 440
 441   configs -= [ "//build/config/compiler:chromium_code" ]
 442   configs += [
 443     ":skia_library_config",
 444     "//build/config/compiler:no_chromium_code",
 445   ]
 446   public_configs = [ ":skia_config" ]
 447
 448   deps = [
 449     ":skia_opts",
 450     "//base",
 451     "//base/third_party/dynamic_annotations",
 452     "//third_party/zlib",
 453   ]
 454
 455   if (is_linux) {
 456     configs += [
 457       "//build/config/linux:fontconfig",
 458       "//build/config/linux:freetype2",
 459     ]
 460     if (use_pango) {
 461       configs += [ "//build/config/linux:pangocairo" ]
 462     }
 463     deps += [ "//third_party/icu:icuuc" ]
 464   }
 465
 466   if (is_android) {
 467     set_sources_assignment_filter([])
 468     sources += [ "ext/platform_device_linux.cc" ]
 469     set_sources_assignment_filter(sources_assignment_filter)
 470     deps += [
 471       "//third_party/expat",
 472       "//third_party/freetype-android:freetype",
 473       "//third_party/android_tools:cpu_features",
 474     ]
 475   }
 476
 477   if (skia_support_pdf) {
 478     deps += [ "//third_party/sfntly" ]
 479     sources += gypi_skia_pdf.sources
 480   }
 481
 482   if (is_android && !is_debug) {
 483     configs -= [ "//build/config/compiler:optimize" ]
 484     configs += [ "//build/config/compiler:optimize_max" ]
 485   }
 486 }
 487
 488 # Separated out so it can be compiled with different flags for SSE.
 489 if (current_cpu == "x86" || current_cpu == "x64") {
 490   source_set("skia_opts_sse3") {
 491     sources = gypi_skia_opts.ssse3_sources
 492     if (!is_win || is_clang) {
 493       cflags = [ "-mssse3" ]
 494     }
 495     if (is_win) {
 496       defines = [ "SK_CPU_SSE_LEVEL=31" ]
 497     }
 498     visibility = [ ":skia_opts" ]
 499     configs -= [ "//build/config/compiler:chromium_code" ]
 500     configs += [
 501       ":skia_config",
 502       ":skia_library_config",
 503       "//build/config/compiler:no_chromium_code",
 504     ]
 505   }
 506   source_set("skia_opts_sse4") {
 507     sources = gypi_skia_opts.sse41_sources
 508     if (!is_win || is_clang) {
 509       cflags = [ "-msse4.1" ]
 510     }
 511     if (is_win) {
 512       defines = [ "SK_CPU_SSE_LEVEL=41" ]
 513     }
 514     visibility = [ ":skia_opts" ]
 515     configs -= [ "//build/config/compiler:chromium_code" ]
 516     configs += [
 517       ":skia_config",
 518       ":skia_library_config",
 519       "//build/config/compiler:no_chromium_code",
 520     ]
 521   }
 522 }
 523 source_set("skia_opts") {
 524   cflags = []
 525   defines = []
 526
 527   deps = [
 528     "//base",
 529   ]
 530
 531   if (current_cpu == "x86" || current_cpu == "x64") {
 532     sources = gypi_skia_opts.sse2_sources
 533     deps += [
 534       ":skia_opts_sse3",
 535       ":skia_opts_sse4",
 536     ]
 537   } else if (current_cpu == "arm") {
 538     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 539     # ARM), the compiler doesn't like that.
 540     cflags += [ "-fomit-frame-pointer" ]
 541
 542     if (arm_version >= 7) {
 543       sources = gypi_skia_opts.armv7_sources
 544       if (arm_use_neon || arm_optionally_use_neon) {
 545         sources += gypi_skia_opts.neon_sources
 546
 547         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 548         # when running this.
 549         if (!arm_use_neon) {
 550           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 551           cflags += [ "-mfpu=neon" ]
 552         }
 553       }
 554     } else {
 555       sources = gypi_skia_opts.none_sourcees
 556     }
 557   } else if (current_cpu == "mipsel") {
 558     cflags += [ "-fomit-frame-pointer" ]
 559
 560     if (mips_dsp_rev >= 1) {
 561       sources = gypi_skia_opts.mips_dsp_sources
 562     } else {
 563       sources = gypi_skia_opts.none_sources
 564     }
 565   } else {
 566     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 567   }
 568
 569   if (is_android && !is_debug) {
 570     configs -= [ "//build/config/compiler:optimize" ]
 571     configs += [ "//build/config/compiler:optimize_max" ]
 572   }
 573
 574   configs -= [ "//build/config/compiler:chromium_code" ]
 575   configs += [
 576     ":skia_config",
 577     ":skia_library_config",
 578     "//build/config/compiler:no_chromium_code",
 579   ]
 580
 581   visibility = [ ":skia" ]
 582 }
 583
 584 # TODO(GYP): Delete this after we've converted everything to GN.
 585 # The _run targets exist only for compatibility w/ GYP.
 586 group("skia_unittests_run") {
 587   testonly = true
 588   deps = [
 589     ":skia_unittests",
 590   ]
 591 }
 592
 593 test("skia_unittests") {
 594   sources = [
 595     "ext/analysis_canvas_unittest.cc",
 596     "ext/bitmap_platform_device_mac_unittest.cc",
 597     "ext/convolver_unittest.cc",
 598     "ext/image_operations_unittest.cc",
 599     "ext/pixel_ref_utils_unittest.cc",
 600     "ext/platform_canvas_unittest.cc",
 601     "ext/recursive_gaussian_convolution_unittest.cc",
 602     "ext/refptr_unittest.cc",
 603     "ext/skia_utils_ios_unittest.mm",
 604     "ext/skia_utils_mac_unittest.mm",
 605   ]
 606
 607   if (!is_win && !is_mac) {
 608     sources -= [ "ext/platform_canvas_unittest.cc" ]
 609   }
 610
 611   deps = [
 612     ":skia",
 613     "//base",
 614     "//base/test:run_all_unittests",
 615     "//cc:test_support",  # TODO: Fix this test to not depend on cc.
 616     "//testing/gtest",
 617     "//ui/gfx",
 618     "//ui/gfx/geometry",
 619   ]
 620 }
 621
 622 if (is_linux && !is_chromeos) {
 623   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 624   executable("image_operations_bench") {
 625     sources = [
 626       "ext/image_operations_bench.cc",
 627     ]
 628
 629     deps = [
 630       ":skia",
 631       "//base",
 632     ]
 633   }
 634
 635   executable("filter_fuzz_stub") {
 636     testonly = true
 637     sources = [
 638       "tools/filter_fuzz_stub/filter_fuzz_stub.cc",
 639     ]
 640
 641     deps = [
 642       ":skia",
 643       "//base",
 644       "//base/test:test_support",
 645     ]
 646   }
 647 }