ui/base/cocoa/base_view.mm

   1 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "ui/base/cocoa/base_view.h"
   6
   7 #include "base/mac/mac_util.h"
   8
   9 NSString* kViewDidBecomeFirstResponder =
  10     @"Chromium.kViewDidBecomeFirstResponder";
  11 NSString* kSelectionDirection = @"Chromium.kSelectionDirection";
  12
  13 @implementation BaseView
  14
  15 - (instancetype)initWithFrame:(NSRect)frame {
  16   if ((self = [super initWithFrame:frame])) {
  17     [self enableTracking];
  18   }
  19   return self;
  20 }
  21
  22 - (instancetype)initWithCoder:(NSCoder*)decoder {
  23   if ((self = [super initWithCoder:decoder])) {
  24     [self enableTracking];
  25   }
  26   return self;
  27 }
  28
  29 - (void)dealloc {
  30   [self disableTracking];
  31   [super dealloc];
  32 }
  33
  34 - (void)enableTracking {
  35   if (trackingArea_.get())
  36     return;
  37
  38   NSTrackingAreaOptions trackingOptions = NSTrackingMouseEnteredAndExited |
  39                                           NSTrackingMouseMoved |
  40                                           NSTrackingActiveAlways |
  41                                           NSTrackingInVisibleRect;
  42   trackingArea_.reset([[CrTrackingArea alloc] initWithRect:NSZeroRect
  43                                                    options:trackingOptions
  44                                                      owner:self
  45                                                   userInfo:nil]);
  46   [self addTrackingArea:trackingArea_.get()];
  47 }
  48
  49 - (void)disableTracking {
  50   if (trackingArea_.get()) {
  51     [self removeTrackingArea:trackingArea_.get()];
  52     trackingArea_.reset();
  53   }
  54 }
  55
  56 - (void)updateTrackingAreas {
  57   [super updateTrackingAreas];
  58
  59   // NSTrackingInVisibleRect doesn't work correctly with Lion's window resizing,
  60   // http://crbug.com/176725 / http://openradar.appspot.com/radar?id=2773401 .
  61   // Work around it by reinstalling the tracking area after window resize.
  62   // This AppKit bug is fixed on Yosemite, so we only apply this workaround on
  63   // 10.7 to 10.9.
  64   if (base::mac::IsOSMavericksOrEarlier() && base::mac::IsOSLionOrLater()) {
  65     [self disableTracking];
  66     [self enableTracking];
  67   }
  68 }
  69
  70 - (void)mouseEvent:(NSEvent*)theEvent {
  71   // This method left intentionally blank.
  72 }
  73
  74 - (EventHandled)keyEvent:(NSEvent*)theEvent {
  75   // The default implementation of this method does not handle any key events.
  76   // Derived classes should return kEventHandled if they handled an event,
  77   // otherwise it will be forwarded on to |super|.
  78   return kEventNotHandled;
  79 }
  80
  81 - (void)mouseDown:(NSEvent*)theEvent {
  82   dragging_ = YES;
  83   [self mouseEvent:theEvent];
  84 }
  85
  86 - (void)rightMouseDown:(NSEvent*)theEvent {
  87   [self mouseEvent:theEvent];
  88 }
  89
  90 - (void)otherMouseDown:(NSEvent*)theEvent {
  91   [self mouseEvent:theEvent];
  92 }
  93
  94 - (void)mouseUp:(NSEvent*)theEvent {
  95   [self mouseEvent:theEvent];
  96
  97   dragging_ = NO;
  98   if (pendingExitEvent_.get()) {
  99     NSEvent* exitEvent =
 100         [NSEvent enterExitEventWithType:NSMouseExited
 101                                location:[theEvent locationInWindow]
 102                           modifierFlags:[theEvent modifierFlags]
 103                               timestamp:[theEvent timestamp]
 104                            windowNumber:[theEvent windowNumber]
 105                                 context:[theEvent context]
 106                             eventNumber:[pendingExitEvent_.get() eventNumber]
 107                          trackingNumber:[pendingExitEvent_.get() trackingNumber]
 108                                userData:[pendingExitEvent_.get() userData]];
 109     [self mouseEvent:exitEvent];
 110     pendingExitEvent_.reset();
 111   }
 112 }
 113
 114 - (void)rightMouseUp:(NSEvent*)theEvent {
 115   [self mouseEvent:theEvent];
 116 }
 117
 118 - (void)otherMouseUp:(NSEvent*)theEvent {
 119   [self mouseEvent:theEvent];
 120 }
 121
 122 - (void)mouseMoved:(NSEvent*)theEvent {
 123   [self mouseEvent:theEvent];
 124 }
 125
 126 - (void)mouseDragged:(NSEvent*)theEvent {
 127   [self mouseEvent:theEvent];
 128 }
 129
 130 - (void)rightMouseDragged:(NSEvent*)theEvent {
 131   [self mouseEvent:theEvent];
 132 }
 133
 134 - (void)otherMouseDragged:(NSEvent*)theEvent {
 135   [self mouseEvent:theEvent];
 136 }
 137
 138 - (void)mouseEntered:(NSEvent*)theEvent {
 139   if (pendingExitEvent_.get()) {
 140     pendingExitEvent_.reset();
 141     return;
 142   }
 143
 144   [self mouseEvent:theEvent];
 145 }
 146
 147 - (void)mouseExited:(NSEvent*)theEvent {
 148   // The tracking area will send an exit event even during a drag, which isn't
 149   // how the event flow for drags should work. This stores the exit event, and
 150   // sends it when the drag completes instead.
 151   if (dragging_) {
 152     pendingExitEvent_.reset([theEvent retain]);
 153     return;
 154   }
 155
 156   [self mouseEvent:theEvent];
 157 }
 158
 159 - (void)keyDown:(NSEvent*)theEvent {
 160   if ([self keyEvent:theEvent] != kEventHandled)
 161     [super keyDown:theEvent];
 162 }
 163
 164 - (void)keyUp:(NSEvent*)theEvent {
 165   if ([self keyEvent:theEvent] != kEventHandled)
 166     [super keyUp:theEvent];
 167 }
 168
 169 - (void)flagsChanged:(NSEvent*)theEvent {
 170   if ([self keyEvent:theEvent] != kEventHandled)
 171     [super flagsChanged:theEvent];
 172 }
 173
 174 - (gfx::Rect)flipNSRectToRect:(NSRect)rect {
 175   gfx::Rect new_rect(NSRectToCGRect(rect));
 176   new_rect.set_y(NSHeight([self bounds]) - new_rect.bottom());
 177   return new_rect;
 178 }
 179
 180 - (NSRect)flipRectToNSRect:(gfx::Rect)rect {
 181   NSRect new_rect(NSRectFromCGRect(rect.ToCGRect()));
 182   new_rect.origin.y = NSHeight([self bounds]) - NSMaxY(new_rect);
 183   return new_rect;
 184 }
 185
 186 @end