ui/base/ime/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 component("ime") {
   9   output_name = "ui_base_ime"
  10   sources = [
  11     "candidate_window.cc",
  12     "candidate_window.h",
  13     "chromeos/character_composer.cc",
  14     "chromeos/character_composer.h",
  15     "chromeos/component_extension_ime_manager.cc",
  16     "chromeos/component_extension_ime_manager.h",
  17     "chromeos/composition_text_chromeos.cc",
  18     "chromeos/composition_text_chromeos.h",
  19     "chromeos/extension_ime_util.cc",
  20     "chromeos/extension_ime_util.h",
  21     "chromeos/fake_ime_keyboard.cc",
  22     "chromeos/fake_ime_keyboard.h",
  23     "chromeos/fake_input_method_delegate.cc",
  24     "chromeos/fake_input_method_delegate.h",
  25     "chromeos/ime_bridge.cc",
  26     "chromeos/ime_bridge.h",
  27     "chromeos/ime_keyboard.cc",
  28     "chromeos/ime_keyboard.h",
  29     "chromeos/ime_keyboard_ozone.cc",
  30     "chromeos/ime_keyboard_ozone.h",
  31     "chromeos/ime_keyboard_x11.cc",
  32     "chromeos/ime_keyboard_x11.h",
  33     "chromeos/ime_keymap.cc",
  34     "chromeos/ime_keymap.h",
  35     "chromeos/input_method_delegate.h",
  36     "chromeos/input_method_descriptor.cc",
  37     "chromeos/input_method_descriptor.h",
  38     "chromeos/input_method_manager.cc",
  39     "chromeos/input_method_manager.h",
  40     "chromeos/input_method_whitelist.cc",
  41     "chromeos/input_method_whitelist.h",
  42     "chromeos/mock_component_extension_ime_manager_delegate.cc",
  43     "chromeos/mock_component_extension_ime_manager_delegate.h",
  44     "chromeos/mock_ime_candidate_window_handler.cc",
  45     "chromeos/mock_ime_candidate_window_handler.h",
  46     "chromeos/mock_ime_engine_handler.cc",
  47     "chromeos/mock_ime_engine_handler.h",
  48     "chromeos/mock_ime_input_context_handler.cc",
  49     "chromeos/mock_ime_input_context_handler.h",
  50     "composition_text.cc",
  51     "composition_text.h",
  52     "composition_text_util_pango.cc",
  53     "composition_text_util_pango.h",
  54     "composition_underline.h",
  55     "infolist_entry.cc",
  56     "infolist_entry.h",
  57     "input_method.h",
  58     "input_method_auralinux.cc",
  59     "input_method_auralinux.h",
  60     "input_method_base.cc",
  61     "input_method_base.h",
  62     "input_method_chromeos.cc",
  63     "input_method_chromeos.h",
  64     "input_method_delegate.h",
  65     "input_method_factory.cc",
  66     "input_method_factory.h",
  67     "input_method_initializer.cc",
  68     "input_method_initializer.h",
  69     "input_method_mac.h",
  70     "input_method_mac.mm",
  71     "input_method_minimal.cc",
  72     "input_method_minimal.h",
  73     "input_method_observer.h",
  74     "input_method_win.cc",
  75     "input_method_win.h",
  76     "linux/fake_input_method_context.cc",
  77     "linux/fake_input_method_context.h",
  78     "linux/fake_input_method_context_factory.cc",
  79     "linux/fake_input_method_context_factory.h",
  80     "linux/linux_input_method_context.h",
  81     "linux/linux_input_method_context_factory.cc",
  82     "linux/linux_input_method_context_factory.h",
  83     "mock_input_method.cc",
  84     "mock_input_method.h",
  85     "remote_input_method_delegate_win.h",
  86     "remote_input_method_win.cc",
  87     "remote_input_method_win.h",
  88     "text_input_client.cc",
  89     "text_input_client.h",
  90     "text_input_type.h",
  91     "ui_base_ime_export.h",
  92     "win/imm32_manager.cc",
  93     "win/imm32_manager.h",
  94     "win/tsf_input_scope.cc",
  95     "win/tsf_input_scope.h",
  96   ]
  97
  98   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  99   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 100
 101   defines = [ "UI_BASE_IME_IMPLEMENTATION" ]
 102
 103   deps = [
 104     "//base",
 105     "//base/third_party/dynamic_annotations",
 106     "//base:i18n",
 107     "//net",
 108     "//third_party/icu",
 109     "//ui/base",
 110     "//ui/events",
 111     "//ui/gfx",
 112     "//ui/gfx/geometry",
 113     "//url",
 114   ]
 115
 116   if (!use_aura || (!is_linux && !use_ozone)) {
 117     sources -= [
 118       "input_method_auralinux.cc",
 119       "input_method_auralinux.h",
 120     ]
 121   }
 122
 123   if (!toolkit_views && !use_aura) {
 124     sources -= [
 125       "input_method_factory.cc",
 126       "input_method_factory.h",
 127       "input_method_minimal.cc",
 128       "input_method_minimal.h",
 129     ]
 130   }
 131
 132   if (is_chromeos) {
 133     deps += [
 134       "//chromeos",
 135       "//chromeos/ime:gencode",
 136       "//ui/events:dom_keycode_converter",
 137     ]
 138     if (!use_ozone) {
 139       sources -= [
 140         "chromeos/ime_keyboard_ozone.cc",
 141         "chromeos/ime_keyboard_ozone.h",
 142       ]
 143     }
 144     if (!use_x11) {
 145       sources -= [
 146         "chromeos/ime_keyboard_x11.cc",
 147         "chromeos/ime_keyboard_x11.h",
 148       ]
 149     }
 150   }
 151
 152   if (use_pango) {
 153     configs += [ "//build/config/linux:pangocairo" ]
 154   } else {
 155     sources -= [
 156       "composition_text_util_pango.cc",
 157       "composition_text_util_pango.h",
 158     ]
 159   }
 160   if (use_x11) {
 161     configs += [ "//build/config/linux:x11" ]
 162     deps += [ "//ui/gfx/x" ]
 163   }
 164
 165   if (is_win) {
 166     cflags = [ "/wd4324" ]  # Structure was padded due to __declspec(align()), which is
 167                             # uninteresting.
 168
 169     libs = [ "imm32.lib" ]
 170   }
 171
 172   if (use_ozone) {
 173     deps += [
 174       "//ui/ozone",
 175       "//ui/events/ozone:events_ozone_layout",
 176     ]
 177   }
 178 }