ui/gl/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 if (is_android) {
   9   import("//build/config/android/config.gni")
  10   import("//build/config/android/rules.gni")
  11 }
  12
  13 config("gl_config") {
  14   if (use_x11) {
  15     defines = [ "GL_GLEXT_PROTOTYPES" ]
  16   }
  17 }
  18
  19 component("gl") {
  20   output_name = "gl_wrapper"  # Avoid colliding with OS X"s libGL.dylib.
  21
  22   sources = [
  23     "android/gl_jni_registrar.cc",
  24     "android/gl_jni_registrar.h",
  25     "android/scoped_java_surface.cc",
  26     "android/scoped_java_surface.h",
  27     "android/surface_texture.cc",
  28     "android/surface_texture.h",
  29     "android/surface_texture_listener.cc",
  30     "android/surface_texture_listener.h",
  31     "gl_bindings.cc",
  32     "gl_bindings.h",
  33     "gl_bindings_autogen_gl.cc",
  34     "gl_bindings_autogen_gl.h",
  35     "gl_bindings_autogen_osmesa.cc",
  36     "gl_bindings_autogen_osmesa.h",
  37     "gl_bindings_skia_in_process.cc",
  38     "gl_bindings_skia_in_process.h",
  39     "gl_context.cc",
  40     "gl_context.h",
  41     "gl_context_android.cc",
  42     "gl_context_mac.mm",
  43     "gl_context_osmesa.cc",
  44     "gl_context_osmesa.h",
  45     "gl_context_stub.cc",
  46     "gl_context_stub.h",
  47     "gl_context_stub_with_extensions.cc",
  48     "gl_context_stub_with_extensions.h",
  49     "gl_context_win.cc",
  50     "gl_enums.cc",
  51     "gl_enums.h",
  52     "gl_enums_implementation_autogen.h",
  53     "gl_export.h",
  54     "gl_fence.cc",
  55     "gl_fence.h",
  56     "gl_fence_arb.cc",
  57     "gl_fence_arb.h",
  58     "gl_fence_nv.cc",
  59     "gl_fence_nv.h",
  60     "gl_gl_api_implementation.cc",
  61     "gl_gl_api_implementation.h",
  62     "gl_image.h",
  63     "gl_image_memory.cc",
  64     "gl_image_memory.h",
  65     "gl_image_ref_counted_memory.cc",
  66     "gl_image_ref_counted_memory.h",
  67     "gl_image_shared_memory.cc",
  68     "gl_image_shared_memory.h",
  69     "gl_image_stub.cc",
  70     "gl_image_stub.h",
  71     "gl_implementation.cc",
  72     "gl_implementation.h",
  73     "gl_implementation_android.cc",
  74     "gl_implementation_mac.cc",
  75     "gl_implementation_win.cc",
  76     "gl_osmesa_api_implementation.cc",
  77     "gl_osmesa_api_implementation.h",
  78     "gl_share_group.cc",
  79     "gl_share_group.h",
  80     "gl_state_restorer.cc",
  81     "gl_state_restorer.h",
  82     "gl_surface.cc",
  83     "gl_surface.h",
  84     "gl_surface_android.cc",
  85     "gl_surface_mac.cc",
  86     "gl_surface_osmesa.cc",
  87     "gl_surface_osmesa.h",
  88     "gl_surface_stub.cc",
  89     "gl_surface_stub.h",
  90     "gl_surface_win.cc",
  91     "gl_switches.cc",
  92     "gl_switches.h",
  93     "gl_version_info.cc",
  94     "gl_version_info.h",
  95     "gpu_switching_manager.cc",
  96     "gpu_switching_manager.h",
  97     "gpu_timing.cc",
  98     "gpu_timing.h",
  99     "scoped_binders.cc",
 100     "scoped_binders.h",
 101     "scoped_make_current.cc",
 102     "scoped_make_current.h",
 103     "sync_control_vsync_provider.cc",
 104     "sync_control_vsync_provider.h",
 105   ]
 106
 107   defines = [ "GL_IMPLEMENTATION" ]
 108
 109   include_dirs = [
 110     "//third_party/switfshader/include",
 111     "//third_party/mesa/src/include",
 112   ]
 113
 114   all_dependent_configs = [ ":gl_config" ]
 115
 116   public_configs = [ "//third_party/khronos:khronos_headers" ]
 117
 118   deps = [
 119     "//base/third_party/dynamic_annotations",
 120     "//skia",
 121   ]
 122   public_deps = [
 123     "//base",
 124     "//third_party/mesa:mesa_headers",
 125     "//ui/events/platform",
 126     "//ui/gfx",
 127     "//ui/gfx/geometry",
 128   ]
 129
 130   if (is_win || is_android || is_linux) {
 131     sources += [
 132       "egl_util.cc",
 133       "egl_util.h",
 134       "gl_bindings_autogen_egl.cc",
 135       "gl_bindings_autogen_egl.h",
 136       "gl_context_egl.cc",
 137       "gl_context_egl.h",
 138       "gl_fence_egl.cc",
 139       "gl_fence_egl.h",
 140       "gl_image_egl.cc",
 141       "gl_image_egl.h",
 142       "gl_surface_egl.cc",
 143       "gl_surface_egl.h",
 144     ]
 145   }
 146   if (is_android || is_linux) {
 147     sources += [
 148       "gl_implementation_osmesa.cc",
 149       "gl_implementation_osmesa.h",
 150     ]
 151   }
 152   if (is_linux) {
 153     deps += [ "//third_party/libevent" ]
 154     sources += [
 155       "gl_image_linux_dma_buffer.cc",
 156       "gl_image_linux_dma_buffer.h",
 157     ]
 158   }
 159   if (use_x11) {
 160     sources += [
 161       "gl_bindings_autogen_glx.cc",
 162       "gl_bindings_autogen_glx.h",
 163       "gl_context_glx.cc",
 164       "gl_context_glx.h",
 165       "gl_context_x11.cc",
 166       "gl_egl_api_implementation.cc",
 167       "gl_egl_api_implementation.h",
 168       "gl_glx_api_implementation.cc",
 169       "gl_glx_api_implementation.h",
 170       "gl_image_glx.cc",
 171       "gl_image_glx.h",
 172       "gl_implementation_x11.cc",
 173       "gl_surface_glx.cc",
 174       "gl_surface_glx.h",
 175       "gl_surface_x11.cc",
 176     ]
 177
 178     configs += [
 179       "//build/config/linux:x11",
 180       "//build/config/linux:xcomposite",
 181       "//build/config/linux:xext",
 182     ]
 183
 184     deps += [ "//ui/gfx/x" ]
 185   }
 186   if (is_win) {
 187     sources += [
 188       "angle_platform_impl.cc",
 189       "angle_platform_impl.h",
 190       "gl_bindings_autogen_wgl.cc",
 191       "gl_bindings_autogen_wgl.h",
 192       "gl_context_wgl.cc",
 193       "gl_context_wgl.h",
 194       "gl_egl_api_implementation.cc",
 195       "gl_egl_api_implementation.h",
 196       "gl_surface_wgl.cc",
 197       "gl_surface_wgl.h",
 198       "gl_wgl_api_implementation.cc",
 199       "gl_wgl_api_implementation.h",
 200     ]
 201
 202     libs = [ "dwmapi.lib" ]
 203     ldflags = [ "/DELAYLOAD:dwmapi.dll" ]
 204
 205     data_deps = [
 206       "//third_party/angle:libEGL",
 207       "//third_party/angle:libGLESv2",
 208       "//third_party/mesa:osmesa",
 209     ]
 210   }
 211   if (is_mac) {
 212     sources += [
 213       "gl_context_cgl.cc",
 214       "gl_context_cgl.h",
 215       "gl_fence_apple.cc",
 216       "gl_fence_apple.h",
 217       "gl_image_io_surface.h",
 218       "gl_image_io_surface.mm",
 219       "scoped_cgl.cc",
 220       "scoped_cgl.h",
 221     ]
 222
 223     libs = [
 224       "IOSurface.framework",
 225       "OpenGL.framework",
 226       "Quartz.framework",
 227     ]
 228   }
 229   if (is_android) {
 230     sources += [
 231       "gl_egl_api_implementation.cc",
 232       "gl_egl_api_implementation.h",
 233       "gl_image_surface_texture.cc",
 234       "gl_image_surface_texture.h",
 235     ]
 236
 237     defines += [
 238       "GL_GLEXT_PROTOTYPES",
 239       "EGL_EGLEXT_PROTOTYPES",
 240     ]
 241
 242     libs = [ "android" ]
 243
 244     deps += [
 245       ":gl_jni_headers",
 246       "//ui/android:ui_java",
 247     ]
 248   }
 249   if (use_ozone) {
 250     sources += [
 251       "gl_context_ozone.cc",
 252       "gl_egl_api_implementation.cc",
 253       "gl_egl_api_implementation.h",
 254       "gl_implementation_ozone.cc",
 255       "gl_surface_ozone.cc",
 256     ]
 257     deps += [
 258       "//ui/ozone",
 259       "//ui/ozone:ozone_base",
 260     ]
 261   }
 262 }
 263
 264 source_set("gl_unittest_utils") {
 265   testonly = true
 266   sources = [
 267     "gl_bindings_autogen_mock.cc",
 268     "gl_bindings_autogen_mock.h",
 269     "gl_mock.cc",
 270     "gl_mock.h",
 271     "gl_mock_autogen_gl.h",
 272     "gpu_timing_fake.cc",
 273     "gpu_timing_fake.h",
 274   ]
 275
 276   configs += [ "//third_party/khronos:khronos_headers" ]
 277
 278   deps = [
 279     ":gl",
 280     "//testing/gmock",
 281   ]
 282 }
 283
 284 source_set("test_support") {
 285   sources = [
 286     "test/gl_surface_test_support.cc",
 287     "test/gl_surface_test_support.h",
 288   ]
 289
 290   configs += [ "//third_party/khronos:khronos_headers" ]
 291
 292   deps = [
 293     ":gl",
 294   ]
 295
 296   if (use_x11) {
 297     configs += [ "//build/config/linux:x11" ]
 298     deps += [
 299       "//ui/gfx/x",
 300       "//ui/platform_window/x11",
 301     ]
 302   }
 303 }
 304
 305 # TODO(GYP): Delete this after we've converted everything to GN.
 306 # The _run targets exist only for compatibility w/ GYP.
 307 group("gl_unittests_run") {
 308   testonly = true
 309   deps = [
 310     ":gl_unittests",
 311   ]
 312 }
 313
 314 test("gl_unittests") {
 315   sources = [
 316     "gl_api_unittest.cc",
 317     "gpu_timing_unittest.cc",
 318     "test/run_all_unittests.cc",
 319   ]
 320
 321   if (is_win || is_android || is_linux) {
 322     sources += [
 323       "egl_api_unittest.cc",
 324       "test/egl_initialization_displays_unittest.cc",
 325     ]
 326   }
 327
 328   include_dirs = [ "//third_party/khronos" ]
 329
 330   deps = [
 331     ":gl",
 332     ":gl_unittest_utils",
 333     ":test_support",
 334     "//base",
 335     "//base/test:test_support",
 336     "//testing/gmock",
 337     "//testing/gtest",
 338   ]
 339 }
 340
 341 if (is_android) {
 342   generate_jar_jni("surface_jni_headers") {
 343     jni_package = "ui/gl"
 344     classes = [ "android/view/Surface.class" ]
 345   }
 346
 347   generate_jni("gl_jni_headers") {
 348     deps = [
 349       ":surface_jni_headers",
 350     ]
 351     sources = [
 352       "../android/java/src/org/chromium/ui/gl/SurfaceTextureListener.java",
 353       "../android/java/src/org/chromium/ui/gl/SurfaceTexturePlatformWrapper.java",
 354     ]
 355     jni_package = "ui/gl"
 356   }
 357 }