ui/gfx/screen_mac.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "ui/gfx/screen.h"
   6
   7 #import <ApplicationServices/ApplicationServices.h>
   8 #import <Cocoa/Cocoa.h>
   9
  10 #include <map>
  11
  12 #include "base/logging.h"
  13 #include "base/mac/sdk_forward_declarations.h"
  14 #include "base/timer/timer.h"
  15 #include "ui/gfx/display.h"
  16 #include "ui/gfx/display_change_notifier.h"
  17
  18 namespace {
  19
  20 // The delay to handle the display configuration changes.
  21 // See comments in ScreenMac::HandleDisplayReconfiguration.
  22 const int64 kConfigureDelayMs = 500;
  23
  24 gfx::Rect ConvertCoordinateSystem(NSRect ns_rect) {
  25   // Primary monitor is defined as the monitor with the menubar,
  26   // which is always at index 0.
  27   NSScreen* primary_screen = [[NSScreen screens] objectAtIndex:0];
  28   float primary_screen_height = [primary_screen frame].size.height;
  29   gfx::Rect rect(NSRectToCGRect(ns_rect));
  30   rect.set_y(primary_screen_height - rect.y() - rect.height());
  31   return rect;
  32 }
  33
  34 NSScreen* GetMatchingScreen(const gfx::Rect& match_rect) {
  35   // Default to the monitor with the current keyboard focus, in case
  36   // |match_rect| is not on any screen at all.
  37   NSScreen* max_screen = [NSScreen mainScreen];
  38   int max_area = 0;
  39
  40   for (NSScreen* screen in [NSScreen screens]) {
  41     gfx::Rect monitor_area = ConvertCoordinateSystem([screen frame]);
  42     gfx::Rect intersection = gfx::IntersectRects(monitor_area, match_rect);
  43     int area = intersection.width() * intersection.height();
  44     if (area > max_area) {
  45       max_area = area;
  46       max_screen = screen;
  47     }
  48   }
  49
  50   return max_screen;
  51 }
  52
  53 gfx::Display GetDisplayForScreen(NSScreen* screen) {
  54   NSRect frame = [screen frame];
  55
  56   CGDirectDisplayID display_id = [[[screen deviceDescription]
  57     objectForKey:@"NSScreenNumber"] unsignedIntValue];
  58
  59   gfx::Display display(display_id, gfx::Rect(NSRectToCGRect(frame)));
  60   NSRect visible_frame = [screen visibleFrame];
  61   NSScreen* primary = [[NSScreen screens] objectAtIndex:0];
  62
  63   // Convert work area's coordinate systems.
  64   if ([screen isEqual:primary]) {
  65     gfx::Rect work_area = gfx::Rect(NSRectToCGRect(visible_frame));
  66     work_area.set_y(frame.size.height - visible_frame.origin.y -
  67                     visible_frame.size.height);
  68     display.set_work_area(work_area);
  69   } else {
  70     display.set_bounds(ConvertCoordinateSystem(frame));
  71     display.set_work_area(ConvertCoordinateSystem(visible_frame));
  72   }
  73   CGFloat scale;
  74   if ([screen respondsToSelector:@selector(backingScaleFactor)])
  75     scale = [screen backingScaleFactor];
  76   else
  77     scale = [screen userSpaceScaleFactor];
  78   display.set_device_scale_factor(scale);
  79   // CGDisplayRotation returns a double. Display::SetRotationAsDegree will
  80   // handle the unexpected situations were the angle is not a multiple of 90.
  81   display.SetRotationAsDegree(static_cast<int>(CGDisplayRotation(display_id)));
  82   return display;
  83 }
  84
  85 class ScreenMac : public gfx::Screen {
  86  public:
  87   ScreenMac() {
  88     displays_ = BuildDisplaysFromQuartz();
  89
  90     CGDisplayRegisterReconfigurationCallback(
  91         ScreenMac::DisplayReconfigurationCallBack, this);
  92   }
  93
  94   virtual bool IsDIPEnabled() override {
  95     return true;
  96   }
  97
  98   virtual gfx::Point GetCursorScreenPoint() override {
  99     NSPoint mouseLocation  = [NSEvent mouseLocation];
 100     // Flip coordinates to gfx (0,0 in top-left corner) using primary screen.
 101     NSScreen* screen = [[NSScreen screens] objectAtIndex:0];
 102     mouseLocation.y = NSMaxY([screen frame]) - mouseLocation.y;
 103     return gfx::Point(mouseLocation.x, mouseLocation.y);
 104   }
 105
 106   virtual gfx::NativeWindow GetWindowUnderCursor() override {
 107     NOTIMPLEMENTED();
 108     return gfx::NativeWindow();
 109   }
 110
 111   virtual gfx::NativeWindow GetWindowAtScreenPoint(const gfx::Point& point)
 112       override {
 113     NOTIMPLEMENTED();
 114     return gfx::NativeWindow();
 115   }
 116
 117   virtual int GetNumDisplays() const override {
 118     return GetAllDisplays().size();
 119
 120   }
 121
 122   virtual std::vector<gfx::Display> GetAllDisplays() const override {
 123     return displays_;
 124   }
 125
 126   virtual gfx::Display GetDisplayNearestWindow(
 127       gfx::NativeView view) const override {
 128     NSWindow* window = nil;
 129 #if !defined(USE_AURA)
 130     if (view)
 131       window = [view window];
 132 #endif
 133     if (!window)
 134       return GetPrimaryDisplay();
 135     NSScreen* match_screen = [window screen];
 136     if (!match_screen)
 137       return GetPrimaryDisplay();
 138     return GetDisplayForScreen(match_screen);
 139   }
 140
 141   virtual gfx::Display GetDisplayNearestPoint(
 142       const gfx::Point& point) const override {
 143     NSPoint ns_point = NSPointFromCGPoint(point.ToCGPoint());
 144
 145     NSArray* screens = [NSScreen screens];
 146     NSScreen* primary = [screens objectAtIndex:0];
 147     ns_point.y = NSMaxY([primary frame]) - ns_point.y;
 148     for (NSScreen* screen in screens) {
 149       if (NSMouseInRect(ns_point, [screen frame], NO))
 150         return GetDisplayForScreen(screen);
 151     }
 152     return GetPrimaryDisplay();
 153   }
 154
 155   // Returns the display that most closely intersects the provided bounds.
 156   virtual gfx::Display GetDisplayMatching(
 157       const gfx::Rect& match_rect) const override {
 158     NSScreen* match_screen = GetMatchingScreen(match_rect);
 159     return GetDisplayForScreen(match_screen);
 160   }
 161
 162   // Returns the primary display.
 163   virtual gfx::Display GetPrimaryDisplay() const override {
 164     // Primary display is defined as the display with the menubar,
 165     // which is always at index 0.
 166     NSScreen* primary = [[NSScreen screens] objectAtIndex:0];
 167     gfx::Display display = GetDisplayForScreen(primary);
 168     return display;
 169   }
 170
 171   virtual void AddObserver(gfx::DisplayObserver* observer) override {
 172     change_notifier_.AddObserver(observer);
 173   }
 174
 175   virtual void RemoveObserver(gfx::DisplayObserver* observer) override {
 176     change_notifier_.RemoveObserver(observer);
 177   }
 178
 179   static void DisplayReconfigurationCallBack(CGDirectDisplayID display,
 180                                              CGDisplayChangeSummaryFlags flags,
 181                                              void* userInfo) {
 182     if (flags & kCGDisplayBeginConfigurationFlag)
 183       return;
 184
 185     static_cast<ScreenMac*>(userInfo)->HandleDisplayReconfiguration();
 186   }
 187
 188   void HandleDisplayReconfiguration() {
 189     // Given that we need to rebuild the list of displays, we want to coalesce
 190     // the events. For that, we use a timer that will be reset every time we get
 191     // a new event and will be fulfilled kConfigureDelayMs after the latest.
 192     if (configure_timer_.get() && configure_timer_->IsRunning()) {
 193       configure_timer_->Reset();
 194       return;
 195     }
 196
 197     configure_timer_.reset(new base::OneShotTimer<ScreenMac>());
 198     configure_timer_->Start(
 199         FROM_HERE,
 200         base::TimeDelta::FromMilliseconds(kConfigureDelayMs),
 201         this,
 202         &ScreenMac::ConfigureTimerFired);
 203   }
 204
 205  private:
 206   void ConfigureTimerFired() {
 207     std::vector<gfx::Display> old_displays = displays_;
 208     displays_ = BuildDisplaysFromQuartz();
 209
 210     change_notifier_.NotifyDisplaysChanged(old_displays, displays_);
 211   }
 212
 213   std::vector<gfx::Display> BuildDisplaysFromQuartz() const {
 214     // Don't just return all online displays.  This would include displays
 215     // that mirror other displays, which are not desired in this list.  It's
 216     // tempting to use the count returned by CGGetActiveDisplayList, but active
 217     // displays exclude sleeping displays, and those are desired.
 218
 219     // It would be ridiculous to have this many displays connected, but
 220     // CGDirectDisplayID is just an integer, so supporting up to this many
 221     // doesn't hurt.
 222     CGDirectDisplayID online_displays[128];
 223     CGDisplayCount online_display_count = 0;
 224     if (CGGetOnlineDisplayList(arraysize(online_displays),
 225                               online_displays,
 226                               &online_display_count) != kCGErrorSuccess) {
 227       return std::vector<gfx::Display>(1, GetPrimaryDisplay());
 228     }
 229
 230     typedef std::map<int64, NSScreen*> ScreenIdsToScreensMap;
 231     ScreenIdsToScreensMap screen_ids_to_screens;
 232     for (NSScreen* screen in [NSScreen screens]) {
 233       NSDictionary* screen_device_description = [screen deviceDescription];
 234       int64 screen_id = [[screen_device_description
 235         objectForKey:@"NSScreenNumber"] unsignedIntValue];
 236       screen_ids_to_screens[screen_id] = screen;
 237     }
 238
 239     std::vector<gfx::Display> displays;
 240     for (CGDisplayCount online_display_index = 0;
 241         online_display_index < online_display_count;
 242         ++online_display_index) {
 243       CGDirectDisplayID online_display = online_displays[online_display_index];
 244       if (CGDisplayMirrorsDisplay(online_display) == kCGNullDirectDisplay) {
 245         // If this display doesn't mirror any other, include it in the list.
 246         // The primary display in a mirrored set will be counted, but those that
 247         // mirror it will not be.
 248         ScreenIdsToScreensMap::iterator foundScreen =
 249           screen_ids_to_screens.find(online_display);
 250         if (foundScreen != screen_ids_to_screens.end()) {
 251             displays.push_back(GetDisplayForScreen(foundScreen->second));
 252         }
 253       }
 254     }
 255
 256     if (!displays.size())
 257       return std::vector<gfx::Display>(1, GetPrimaryDisplay());
 258
 259     return displays;
 260   }
 261
 262   // The displays currently attached to the device.
 263   std::vector<gfx::Display> displays_;
 264
 265   // The timer to delay configuring outputs. See also the comments in
 266   // HandleDisplayReconfiguration().
 267   scoped_ptr<base::OneShotTimer<ScreenMac> > configure_timer_;
 268
 269   gfx::DisplayChangeNotifier change_notifier_;
 270
 271   DISALLOW_COPY_AND_ASSIGN(ScreenMac);
 272 };
 273
 274 }  // namespace
 275
 276 namespace gfx {
 277
 278 #if !defined(USE_AURA)
 279 Screen* CreateNativeScreen() {
 280   return new ScreenMac;
 281 }
 282 #endif
 283
 284 }