build/config/win/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/compiler/compiler.gni")
   6 import("//build/config/sanitizers/sanitizers.gni")
   7 import("//build/config/win/visual_studio_version.gni")
   8
   9 # Compiler setup for the Windows SDK. Applied to all targets.
  10 config("sdk") {
  11   # The include path is the stuff returned by the script.
  12   #include_dirs = msvc_config[0]  TODO(brettw) make this work.
  13
  14   defines = [
  15     "_ATL_NO_OPENGL",
  16     "_WINDOWS",
  17     "CERT_CHAIN_PARA_HAS_EXTRA_FIELDS",
  18     "NTDDI_VERSION=0x06030000",
  19     "PSAPI_VERSION=1",
  20     "WIN32",
  21     "_SECURE_ATL",
  22
  23     # This is required for ATL to use XP-safe versions of its functions.
  24     "_USING_V110_SDK71_",
  25   ]
  26 }
  27
  28 # Sets the default Windows build version. This is separated because some
  29 # targets need to manually override it for their compiles.
  30 config("winver") {
  31   defines = [
  32     "_WIN32_WINNT=0x0603",
  33     "WINVER=0x0603",
  34   ]
  35 }
  36
  37 # Linker flags for Windows SDK setup, this is applied only to EXEs and DLLs.
  38 config("sdk_link") {
  39   if (current_cpu == "x64") {
  40     ldflags = [ "/MACHINE:X64" ]
  41     lib_dirs = [
  42       "$windows_sdk_path\Lib\winv6.3\um\x64",
  43       "$visual_studio_path\VC\lib\amd64",
  44       "$visual_studio_path\VC\atlmfc\lib\amd64",
  45     ]
  46   } else {
  47     ldflags = [
  48       "/MACHINE:X86",
  49       "/SAFESEH",  # Not compatible with x64 so use only for x86.
  50     ]
  51     lib_dirs = [
  52       "$windows_sdk_path\Lib\winv6.3\um\x86",
  53       "$visual_studio_path\VC\lib",
  54       "$visual_studio_path\VC\atlmfc\lib",
  55     ]
  56     if (!is_syzyasan) {
  57       ldflags += [ "/largeaddressaware" ]
  58     }
  59   }
  60 }
  61
  62 # This default linker setup is provided separately from the SDK setup so
  63 # targets who want different library configurations can remove this and specify
  64 # their own.
  65 config("common_linker_setup") {
  66   ldflags = [
  67     "/FIXED:NO",
  68     "/ignore:4199",
  69     "/ignore:4221",
  70     "/NXCOMPAT",
  71
  72     # Suggested by Microsoft Devrel to avoid
  73     #   LINK : fatal error LNK1248: image size (80000000)
  74     #   exceeds maximum allowable size (80000000)
  75     # which started happening more regularly after VS2013 Update 4.
  76     "/maxilksize:2147483647",
  77   ]
  78
  79   # ASLR makes debugging with windbg difficult because Chrome.exe and
  80   # Chrome.dll share the same base name. As result, windbg will name the
  81   # Chrome.dll module like chrome_<base address>, where <base address>
  82   # typically changes with each launch. This in turn means that breakpoints in
  83   # Chrome.dll don't stick from one launch to the next. For this reason, we
  84   # turn ASLR off in debug builds.
  85   if (is_debug) {
  86     ldflags += [ "/DYNAMICBASE:NO" ]
  87   } else {
  88     ldflags += [ "/DYNAMICBASE" ]
  89   }
  90
  91   # Delay loaded DLLs.
  92   ldflags += [
  93     "/DELAYLOAD:dbghelp.dll",
  94     "/DELAYLOAD:dwmapi.dll",
  95     "/DELAYLOAD:shell32.dll",
  96     "/DELAYLOAD:uxtheme.dll",
  97   ]
  98 }
  99
 100 # Subsystem --------------------------------------------------------------------
 101
 102 # This is appended to the subsystem to specify a minimum version.
 103 if (current_cpu == "x64") {
 104   # The number after the comma is the minimum required OS version.
 105   # 5.02 = Windows Server 2003.
 106   subsystem_version_suffix = ",5.02"
 107 } else {
 108   # 5.01 = Windows XP.
 109   subsystem_version_suffix = ",5.01"
 110 }
 111
 112 config("console") {
 113   ldflags = [ "/SUBSYSTEM:CONSOLE$subsystem_version_suffix" ]
 114 }
 115 config("windowed") {
 116   ldflags = [ "/SUBSYSTEM:WINDOWS$subsystem_version_suffix" ]
 117 }
 118
 119 # Incremental linking ----------------------------------------------------------
 120
 121 incremental_linking_on_switch = [ "/INCREMENTAL" ]
 122 incremental_linking_off_switch = [ "/INCREMENTAL:NO" ]
 123 if (is_debug) {
 124   default_incremental_linking_switch = incremental_linking_on_switch
 125 } else {
 126   default_incremental_linking_switch = incremental_linking_off_switch
 127 }
 128
 129 # Applies incremental linking or not depending on the current configuration.
 130 config("default_incremental_linking") {
 131   ldflags = default_incremental_linking_switch
 132 }
 133
 134 # Explicitly on or off incremental linking
 135 config("incremental_linking") {
 136   ldflags = incremental_linking_on_switch
 137 }
 138 config("no_incremental_linking") {
 139   ldflags = incremental_linking_off_switch
 140 }
 141
 142 # Some large modules can't handle incremental linking in some situations. This
 143 # config should be applied to large modules to turn off incremental linking
 144 # when it won't work.
 145 config("default_large_module_incremental_linking") {
 146   if (symbol_level > 0 && (current_cpu == "x86" || !is_component_build)) {
 147     # When symbols are on, things get so large that the tools fail due to the
 148     # size of the .ilk files.
 149     ldflags = incremental_linking_off_switch
 150   } else {
 151     # Otherwise just do the default incremental linking for this build type.
 152     ldflags = default_incremental_linking_switch
 153   }
 154 }
 155
 156 # Character set ----------------------------------------------------------------
 157
 158 # Not including this config means "ansi" (8-bit system codepage).
 159 config("unicode") {
 160   defines = [
 161     "_UNICODE",
 162     "UNICODE",
 163   ]
 164 }
 165
 166 # Lean and mean ----------------------------------------------------------------
 167
 168 # Some third party code might not compile with WIN32_LEAN_AND_MEAN so we have
 169 # to have a separate config for it. Remove this config from your target to
 170 # get the "bloaty and accomodating" version of windows.h.
 171 config("lean_and_mean") {
 172   defines = [ "WIN32_LEAN_AND_MEAN" ]
 173 }
 174
 175 # Nominmax --------------------------------------------------------------------
 176
 177 # Some third party code defines NOMINMAX before including windows.h, which
 178 # then causes warnings when it's been previously defined on the command line.
 179 # For such targets, this config can be removed.
 180
 181 config("nominmax") {
 182   defines = [ "NOMINMAX" ]
 183 }
 184
 185 # Target WinRT ----------------------------------------------------------------
 186
 187 # When targeting Windows Runtime, certain compiler/linker flags are necessary.
 188
 189 config("target_winrt") {
 190   defines = [
 191     "WINRT",
 192     "WINAPI_FAMILY=WINAPI_FAMILY_PC_APP",
 193   ]
 194   cflags_cc = [
 195     "/ZW",
 196     "/EHsc",
 197   ]
 198 }
 199
 200 # Internal stuff --------------------------------------------------------------
 201
 202 # Config used by the MIDL template to disable warnings.
 203 config("midl_warnings") {
 204   if (is_clang) {
 205     # MIDL generates code like "#endif !_MIDL_USE_GUIDDEF_".
 206     cflags = [ "-Wno-extra-tokens" ]
 207   }
 208 }