chrome/browser/ui/cocoa/bookmarks/bookmark_menu_bridge.h

   1 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 // C++ controller for the bookmark menu; one per AppController (which
   6 // means there is only one).  When bookmarks are changed, this class
   7 // takes care of updating Cocoa bookmark menus.  This is not named
   8 // BookmarkMenuController to help avoid confusion between languages.
   9 // This class needs to be C++, not ObjC, since it derives from
  10 // BookmarkModelObserver.
  11 //
  12 // Most Chromium Cocoa menu items are static from a nib (e.g. New
  13 // Tab), but may be enabled/disabled under certain circumstances
  14 // (e.g. Cut and Paste).  In addition, most Cocoa menu items have
  15 // firstResponder: as a target.  Unusually, bookmark menu items are
  16 // created dynamically.  They also have a target of
  17 // BookmarkMenuCocoaController instead of firstResponder.
  18 // See BookmarkMenuBridge::AddNodeToMenu()).
  19
  20 #ifndef CHROME_BROWSER_UI_COCOA_BOOKMARKS_BOOKMARK_MENU_BRIDGE_H_
  21 #define CHROME_BROWSER_UI_COCOA_BOOKMARKS_BOOKMARK_MENU_BRIDGE_H_
  22
  23 #include <map>
  24
  25 #include "base/mac/scoped_nsobject.h"
  26 #include "chrome/browser/bookmarks/bookmark_model_observer.h"
  27 #import "chrome/browser/ui/cocoa/main_menu_item.h"
  28
  29 class BookmarkNode;
  30 class Profile;
  31 @class NSImage;
  32 @class NSMenu;
  33 @class NSMenuItem;
  34 @class BookmarkMenuCocoaController;
  35
  36 class BookmarkMenuBridge : public BookmarkModelObserver,
  37                            public MainMenuItem {
  38  public:
  39   BookmarkMenuBridge(Profile* profile, NSMenu* menu);
  40   virtual ~BookmarkMenuBridge();
  41
  42   // BookmarkModelObserver:
  43   virtual void BookmarkModelLoaded(BookmarkModel* model,
  44                                    bool ids_reassigned) OVERRIDE;
  45   virtual void BookmarkModelBeingDeleted(BookmarkModel* model) OVERRIDE;
  46   virtual void BookmarkNodeMoved(BookmarkModel* model,
  47                                  const BookmarkNode* old_parent,
  48                                  int old_index,
  49                                  const BookmarkNode* new_parent,
  50                                  int new_index) OVERRIDE;
  51   virtual void BookmarkNodeAdded(BookmarkModel* model,
  52                                  const BookmarkNode* parent,
  53                                  int index) OVERRIDE;
  54   virtual void BookmarkNodeRemoved(BookmarkModel* model,
  55                                    const BookmarkNode* parent,
  56                                    int old_index,
  57                                    const BookmarkNode* node) OVERRIDE;
  58   virtual void BookmarkAllNodesRemoved(BookmarkModel* model) OVERRIDE;
  59   virtual void BookmarkNodeChanged(BookmarkModel* model,
  60                                    const BookmarkNode* node) OVERRIDE;
  61   virtual void BookmarkNodeFaviconChanged(BookmarkModel* model,
  62                                           const BookmarkNode* node) OVERRIDE;
  63   virtual void BookmarkNodeChildrenReordered(BookmarkModel* model,
  64                                              const BookmarkNode* node) OVERRIDE;
  65
  66   // MainMenuItem:
  67   virtual void ResetMenu() OVERRIDE;
  68   virtual void BuildMenu() OVERRIDE;
  69
  70   // Rebuilds the main bookmark menu, if it has been marked invalid.
  71   void UpdateMenu(NSMenu* bookmark_menu);
  72
  73   // Rebuilds a bookmark menu that's a submenu of another menu.
  74   void UpdateSubMenu(NSMenu* bookmark_menu);
  75
  76   // I wish I had a "friend @class" construct.
  77   BookmarkModel* GetBookmarkModel();
  78   Profile* GetProfile();
  79
  80  protected:
  81   // Rebuilds the bookmark content of supplied menu.
  82   void UpdateMenuInternal(NSMenu* bookmark_menu, bool is_submenu);
  83
  84   // Clear all bookmarks from the given bookmark menu.
  85   void ClearBookmarkMenu(NSMenu* menu);
  86
  87   // Mark the bookmark menu as being invalid.
  88   void InvalidateMenu()  { menuIsValid_ = false; }
  89
  90   // Helper for adding the node as a submenu to the menu with the
  91   // given title.
  92   // If |add_extra_items| is true, also adds extra menu items at bottom of
  93   // menu, such as "Open All Bookmarks".
  94   void AddNodeAsSubmenu(NSMenu* menu,
  95                         const BookmarkNode* node,
  96                         bool add_extra_items);
  97
  98   // Helper for recursively adding items to our bookmark menu.
  99   // All children of |node| will be added to |menu|.
 100   // If |add_extra_items| is true, also adds extra menu items at bottom of
 101   // menu, such as "Open All Bookmarks".
 102   // TODO(jrg): add a counter to enforce maximum nodes added
 103   void AddNodeToMenu(const BookmarkNode* node, NSMenu* menu,
 104                      bool add_extra_items);
 105
 106   // Helper for adding an item to our bookmark menu. An item which has a
 107   // localized title specified by |message_id| will be added to |menu|.
 108   // The item is also bound to |node| by tag. |command_id| selects the action.
 109   void AddItemToMenu(int command_id,
 110                      int message_id,
 111                      const BookmarkNode* node,
 112                      NSMenu* menu,
 113                      bool enabled);
 114
 115   // This configures an NSMenuItem with all the data from a BookmarkNode. This
 116   // is used to update existing menu items, as well as to configure newly
 117   // created ones, like in AddNodeToMenu().
 118   // |set_title| is optional since it is only needed when we get a
 119   // node changed notification.  On initial build of the menu we set
 120   // the title as part of alloc/init.
 121   void ConfigureMenuItem(const BookmarkNode* node, NSMenuItem* item,
 122                          bool set_title);
 123
 124   // Returns the NSMenuItem for a given BookmarkNode.
 125   NSMenuItem* MenuItemForNode(const BookmarkNode* node);
 126
 127   // Return the Bookmark menu.
 128   virtual NSMenu* BookmarkMenu();
 129
 130   // Start watching the bookmarks for changes.
 131   void ObserveBookmarkModel();
 132
 133  private:
 134   friend class BookmarkMenuBridgeTest;
 135
 136   // True iff the menu is up-to-date with the actual BookmarkModel.
 137   bool menuIsValid_;
 138
 139   Profile* profile_;  // weak
 140   BookmarkMenuCocoaController* controller_;  // strong
 141
 142   // The folder image so we can use one copy for all.
 143   base::scoped_nsobject<NSImage> folder_image_;
 144
 145   // In order to appropriately update items in the bookmark menu, without
 146   // forcing a rebuild, map the model's nodes to menu items.
 147   std::map<const BookmarkNode*, NSMenuItem*> bookmark_nodes_;
 148 };
 149
 150 #endif  // CHROME_BROWSER_UI_COCOA_BOOKMARKS_BOOKMARK_MENU_BRIDGE_H_