gpu/config/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6
   7 declare_args() {
   8   # Use the PCI lib to collect GPU information on Linux.
   9   use_libpci = true
  10 }
  11
  12 source_set("config") {
  13   sources = [
  14     "dx_diag_node.cc",
  15     "dx_diag_node.h",
  16     "gpu_blacklist.cc",
  17     "gpu_blacklist.h",
  18     "gpu_control_list.cc",
  19     "gpu_control_list.h",
  20     "gpu_control_list_jsons.h",
  21     "gpu_driver_bug_list.cc",
  22     "gpu_driver_bug_list.h",
  23     "gpu_driver_bug_list_json.cc",
  24     "gpu_driver_bug_workaround_type.h",
  25     "gpu_dx_diagnostics_win.cc",
  26     "gpu_feature_type.h",
  27     "gpu_info.cc",
  28     "gpu_info.h",
  29     "gpu_info_collector.cc",
  30     "gpu_info_collector.h",
  31     "gpu_info_collector_android.cc",
  32     "gpu_info_collector_linux.cc",
  33     "gpu_info_collector_linux.h",
  34     "gpu_info_collector_mac.mm",
  35     "gpu_info_collector_ozone.cc",
  36     "gpu_info_collector_win.cc",
  37     "gpu_info_collector_x11.cc",
  38     "gpu_test_config.cc",
  39     "gpu_test_config.h",
  40     "gpu_test_expectations_parser.cc",
  41     "gpu_test_expectations_parser.h",
  42     "gpu_util.cc",
  43     "gpu_util.h",
  44     "software_rendering_list_json.cc",
  45   ]
  46
  47   configs += [
  48     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  49     "//build/config/compiler:no_size_t_to_int_warning",
  50     "//gpu:gpu_implementation",
  51   ]
  52
  53   deps = [
  54     "//base",
  55     "//gpu/command_buffer/service",
  56     "//third_party/re2",
  57     "//ui/gl",
  58   ]
  59
  60   # Prefer mesa GL headers to system headers, which cause problems on Win.
  61   include_dirs = [ "//third_party/mesa/src/include" ]
  62
  63   if (is_win) {
  64     deps += [ "//third_party/libxml" ]
  65     libs = [
  66       "dxguid.lib",
  67       "setupapi.lib",
  68     ]
  69
  70     if (is_chrome_branded && is_official_build) {
  71       sources += [
  72         "//third_party/amd/AmdCfxPxExt.h",
  73         "//third_party/amd/amd_videocard_info_win.cc",
  74       ]
  75     }
  76   }
  77   if (use_libpci) {
  78     defines = [ "USE_LIBPCI=1" ]
  79   }
  80   if (is_linux && use_libpci && (use_x11 || use_ozone)) {
  81     deps += [ "//build/config/linux:libpci" ]
  82   }
  83   if (is_linux && use_x11) {
  84     configs += [
  85       "//build/config/linux:x11",
  86       "//build/config/linux:xext",
  87     ]
  88     deps += [
  89       "//third_party/libXNVCtrl",
  90       "//ui/gfx/x",
  91     ]
  92   } else {
  93     sources -= [ "gpu_info_collector_x11.cc" ]
  94   }
  95   if (!use_ozone) {
  96     sources -= [ "gpu_info_collector_ozone.cc" ]
  97   }
  98 }