chrome/browser/ui/cocoa/infobars/infobar_utilities.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/infobars/infobar_utilities.h"
   6
   7 #include "base/mac/scoped_nsobject.h"
   8 #import "chrome/browser/ui/cocoa/infobars/infobar_container_controller.h"
   9 #import "chrome/browser/ui/cocoa/infobars/infobar_gradient_view.h"
  10 #include "chrome/browser/ui/infobar_container_delegate.h"
  11 #import "components/infobars/core/infobar.h"
  12 #import "ui/base/cocoa/nsview_additions.h"
  13
  14 @interface InfobarLabelTextField : NSTextField
  15 @end
  16
  17 @implementation InfobarLabelTextField
  18
  19 - (void)drawRect:(NSRect)rect {
  20   NSView* infobarGradientView = [self superview];
  21   [self cr_drawUsingAncestor:infobarGradientView inRect:rect];
  22   [super drawRect:rect];
  23 }
  24
  25 - (BOOL)isOpaque {
  26   return YES;
  27 }
  28
  29 @end
  30
  31 namespace InfoBarUtilities {
  32
  33 // Move the |toMove| view |spacing| pixels before/after the |anchor| view.
  34 // |after| signifies the side of |anchor| on which to place |toMove|.
  35 void MoveControl(NSView* anchor, NSView* toMove, int spacing, bool after) {
  36   NSRect anchorFrame = [anchor frame];
  37   NSRect toMoveFrame = [toMove frame];
  38
  39   // At the time of this writing, OS X doesn't natively support BiDi UIs, but
  40   // it doesn't hurt to be forward looking.
  41   bool toRight = after;
  42
  43   if (toRight) {
  44     toMoveFrame.origin.x = NSMaxX(anchorFrame) + spacing;
  45   } else {
  46     // Place toMove to theleft of anchor.
  47     toMoveFrame.origin.x = NSMinX(anchorFrame) -
  48         spacing - NSWidth(toMoveFrame);
  49   }
  50   [toMove setFrame:toMoveFrame];
  51 }
  52
  53 // Check that the control |before| is ordered visually before the |after|
  54 // control. Also, check that there is space between them.
  55 bool VerifyControlOrderAndSpacing(id before, id after) {
  56   NSRect beforeFrame = [before frame];
  57   NSRect afterFrame = [after frame];
  58   return NSMinX(afterFrame) >= NSMaxX(beforeFrame);
  59 }
  60
  61 // Vertically center |toMove| in its container.
  62 void VerticallyCenterView(NSView* toMove) {
  63   NSRect superViewFrame = [[toMove superview] frame];
  64   NSRect viewFrame = [toMove frame];
  65   // If the superview is the infobar view, then subtract out the anti-spoof
  66   // height so that the content is centered in the content area of the infobar,
  67   // rather than in the total height (which includes the bulge).
  68   CGFloat superHeight = NSHeight(superViewFrame);
  69   if ([[toMove superview] isKindOfClass:[InfoBarGradientView class]])
  70     superHeight = InfoBarContainerDelegate::kDefaultBarTargetHeight;
  71   viewFrame.origin.y =
  72       floor((superHeight - NSHeight(viewFrame)) / 2.0);
  73   [toMove setFrame:viewFrame];
  74 }
  75
  76 // Creates a label control in the style we need for the infobar's labels
  77 // within |bounds|.
  78 NSTextField* CreateLabel(NSRect bounds) {
  79   NSTextField* ret = [[InfobarLabelTextField alloc] initWithFrame:bounds];
  80   [ret setEditable:NO];
  81   [ret setDrawsBackground:NO];
  82   [ret setBordered:NO];
  83   return ret;
  84 }
  85
  86 // Adds an item with the specified properties to |menu|.
  87 void AddMenuItem(NSMenu *menu, id target, SEL selector, NSString* title,
  88     int tag, bool enabled, bool checked) {
  89   if (tag == -1) {
  90     [menu addItem:[NSMenuItem separatorItem]];
  91   } else {
  92     base::scoped_nsobject<NSMenuItem> item(
  93         [[NSMenuItem alloc] initWithTitle:title
  94                                    action:selector
  95                             keyEquivalent:@""]);
  96     [item setTag:tag];
  97     [menu addItem:item];
  98     [item setTarget:target];
  99     if (checked)
 100       [item setState:NSOnState];
 101     if (!enabled)
 102       [item setEnabled:NO];
 103   }
 104 }
 105
 106 }  // namespace InfoBarUtilities