net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//url/config.gni")
   9
  10 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  11 # Currently, that file can't be imported multiple times.  Make this always
  12 # imported when http://crbug.com/393704 is fixed.
  13 if (!is_android) {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16
  17 if (is_android) {
  18   import("//build/config/android/config.gni")
  19   import("//build/config/android/rules.gni")
  20 } else if (is_mac) {
  21   import("//build/config/mac/mac_sdk.gni")
  22 }
  23
  24 # The list of net files is kept in net.gypi. Read it.
  25 gypi_values = exec_script(
  26     "//build/gypi_to_gn.py",
  27     [ rebase_path("net.gypi") ],
  28     "scope",
  29     [ "net.gypi" ])
  30
  31 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  32 # configuration (krb5.conf and so on).
  33 use_kerberos = !is_chromeos && !is_android && !is_ios
  34
  35 # The way the cache uses mmap() is inefficient on some Android devices. If
  36 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  37 # pretty confident that mmap-ing the index would not hurt any existing x86
  38 # android devices, but we cannot be so sure about the variety of ARM devices.
  39 # So enable it for x86 only for now.
  40 posix_avoid_mmap = is_android && cpu_arch != "x86"
  41
  42 # WebSockets and socket stream code are used everywhere except iOS.
  43 enable_websockets = !is_ios
  44 use_v8_in_net = !is_ios
  45 enable_built_in_dns = !is_ios
  46 disable_ftp_support = is_ios
  47
  48 declare_args() {
  49   # Disables support for file URLs.  File URL support requires use of icu.
  50   disable_file_support = false
  51 }
  52
  53 config("net_config") {
  54   defines = []
  55   if (posix_avoid_mmap) {
  56     defines += [ "POSIX_AVOID_MMAP" ]
  57   }
  58   if (disable_file_support) {
  59     defines += [ "DISABLE_FILE_SUPPORT" ]
  60   }
  61 }
  62
  63 # Disables Windows warning about size to int truncations.
  64 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  65 config("net_win_size_truncation") {
  66   if (is_win) {
  67     cflags = [ "/wd4267" ]
  68   }
  69 }
  70
  71 component("net") {
  72   sources =
  73     gypi_values.net_nacl_common_sources +
  74     gypi_values.net_non_nacl_sources
  75
  76   cflags = []
  77   defines = [
  78     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  79     # 0) which implies that we run pkg_config on kerberos and link to that
  80     # rather than setting this define which will dynamically open it. That
  81     # doesn't seem to be set in the regular builds, so we're skipping this
  82     # capability here.
  83     "DLOPEN_KERBEROS",
  84     "NET_IMPLEMENTATION"
  85   ]
  86   configs += [ ":net_win_size_truncation" ]
  87   public_configs = [ ":net_config" ]
  88   include_dirs = []
  89
  90   public_deps = [
  91     "//crypto",
  92     "//crypto:platform"
  93   ]
  94   deps = [
  95    ":net_resources",
  96     "//base",
  97     "//base:i18n",
  98     "//base:prefs",
  99     "//base/third_party/dynamic_annotations",
 100     "//net/base/registry_controlled_domains",
 101     "//sdch",
 102     "//third_party/icu",
 103     "//third_party/zlib",
 104     "//url",
 105   ]
 106
 107   if (use_kerberos) {
 108     defines += [ "USE_KERBEROS" ]
 109     if (is_android) {
 110       include_dirs += [ "/usr/include/kerberosV" ]
 111     }
 112   } else {
 113     sources -= [
 114       "http/http_auth_gssapi_posix.cc",
 115       "http/http_auth_gssapi_posix.h",
 116       "http/http_auth_handler_negotiate.h",
 117       "http/http_auth_handler_negotiate.cc",
 118     ]
 119   }
 120
 121   if (is_posix) {
 122     if (posix_avoid_mmap) {
 123       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 124     } else {
 125       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 126     }
 127   }
 128
 129   if (disable_file_support) {
 130     sources -= [
 131       "base/directory_lister.cc",
 132       "base/directory_lister.h",
 133       "url_request/url_request_file_dir_job.cc",
 134       "url_request/url_request_file_dir_job.h",
 135       "url_request/url_request_file_job.cc",
 136       "url_request/url_request_file_job.h",
 137       "url_request/file_protocol_handler.cc",
 138       "url_request/file_protocol_handler.h",
 139     ]
 140   }
 141
 142   if (disable_ftp_support) {
 143     sources -= [
 144       "ftp/ftp_auth_cache.cc",
 145       "ftp/ftp_auth_cache.h",
 146       "ftp/ftp_ctrl_response_buffer.cc",
 147       "ftp/ftp_ctrl_response_buffer.h",
 148       "ftp/ftp_directory_listing_parser.cc",
 149       "ftp/ftp_directory_listing_parser.h",
 150       "ftp/ftp_directory_listing_parser_ls.cc",
 151       "ftp/ftp_directory_listing_parser_ls.h",
 152       "ftp/ftp_directory_listing_parser_netware.cc",
 153       "ftp/ftp_directory_listing_parser_netware.h",
 154       "ftp/ftp_directory_listing_parser_os2.cc",
 155       "ftp/ftp_directory_listing_parser_os2.h",
 156       "ftp/ftp_directory_listing_parser_vms.cc",
 157       "ftp/ftp_directory_listing_parser_vms.h",
 158       "ftp/ftp_directory_listing_parser_windows.cc",
 159       "ftp/ftp_directory_listing_parser_windows.h",
 160       "ftp/ftp_network_layer.cc",
 161       "ftp/ftp_network_layer.h",
 162       "ftp/ftp_network_session.cc",
 163       "ftp/ftp_network_session.h",
 164       "ftp/ftp_network_transaction.cc",
 165       "ftp/ftp_network_transaction.h",
 166       "ftp/ftp_request_info.h",
 167       "ftp/ftp_response_info.cc",
 168       "ftp/ftp_response_info.h",
 169       "ftp/ftp_server_type_histograms.cc",
 170       "ftp/ftp_server_type_histograms.h",
 171       "ftp/ftp_transaction.h",
 172       "ftp/ftp_transaction_factory.h",
 173       "ftp/ftp_util.cc",
 174       "ftp/ftp_util.h",
 175       "url_request/ftp_protocol_handler.cc",
 176       "url_request/ftp_protocol_handler.h",
 177       "url_request/url_request_ftp_job.cc",
 178       "url_request/url_request_ftp_job.h",
 179     ]
 180   }
 181
 182   if (enable_built_in_dns) {
 183     defines += [ "ENABLE_BUILT_IN_DNS" ]
 184   } else {
 185     sources -= [
 186       "dns/address_sorter_posix.cc",
 187       "dns/address_sorter_posix.h",
 188       "dns/dns_client.cc",
 189     ]
 190   }
 191
 192   if (use_openssl) {
 193     sources -= [
 194       "base/nss_memio.c",
 195       "base/nss_memio.h",
 196       "cert/ct_log_verifier_nss.cc",
 197       "cert/ct_objects_extractor_nss.cc",
 198       "cert/jwk_serializer_nss.cc",
 199       "cert/scoped_nss_types.h",
 200       "cert/test_root_certs_nss.cc",
 201       "cert/x509_util_nss.cc",
 202       "cert/x509_util_nss.h",
 203       "ocsp/nss_ocsp.cc",
 204       "ocsp/nss_ocsp.h",
 205       "quic/crypto/aead_base_decrypter_nss.cc",
 206       "quic/crypto/aead_base_encrypter_nss.cc",
 207       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 208       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 209       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 210       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 211       "quic/crypto/channel_id_nss.cc",
 212       "quic/crypto/p256_key_exchange_nss.cc",
 213       "socket/nss_ssl_util.cc",
 214       "socket/nss_ssl_util.h",
 215       "socket/ssl_client_socket_nss.cc",
 216       "socket/ssl_client_socket_nss.h",
 217       "socket/ssl_server_socket_nss.cc",
 218       "socket/ssl_server_socket_nss.h",
 219     ]
 220     if (is_chromeos) {
 221       sources -= [
 222         "cert/nss_cert_database_chromeos.cc",
 223         "cert/nss_cert_database_chromeos.h",
 224         "cert/nss_profile_filter_chromeos.cc",
 225         "cert/nss_profile_filter_chromeos.h",
 226       ]
 227     }
 228     if (is_linux) {
 229       # These are always removed for non-Linux cases below.
 230       sources -= [
 231         "base/crypto_module_nss.cc",
 232         "base/keygen_handler_nss.cc",
 233         "cert/cert_database_nss.cc",
 234         "cert/nss_cert_database.cc",
 235         "cert/nss_cert_database.h",
 236         "cert/x509_certificate_nss.cc",
 237         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 238         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 239         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 240         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 241         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 242         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 243       ]
 244     }
 245     if (is_ios) {
 246       # Always removed for !ios below.
 247       sources -= [
 248         "cert/cert_verify_proc_nss.cc",
 249         "cert/cert_verify_proc_nss.h",
 250       ]
 251     }
 252     if (is_win) {
 253       sources -= [
 254         "cert/cert/sha256_legacy_support_nss_win.cc",
 255       ]
 256     }
 257   } else {
 258     sources -= [
 259       "base/crypto_module_openssl.cc",
 260       "cert/ct_log_verifier_openssl.cc",
 261       "cert/ct_objects_extractor_openssl.cc",
 262       "cert/jwk_serializer_openssl.cc",
 263       "cert/x509_util_openssl.cc",
 264       "cert/x509_util_openssl.h",
 265       "quic/crypto/aead_base_decrypter_openssl.cc",
 266       "quic/crypto/aead_base_encrypter_openssl.cc",
 267       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 268       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 269       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 270       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 271       "quic/crypto/channel_id_openssl.cc",
 272       "quic/crypto/p256_key_exchange_openssl.cc",
 273       "quic/crypto/scoped_evp_aead_ctx.cc",
 274       "quic/crypto/scoped_evp_aead_ctx.h",
 275       "socket/ssl_client_socket_openssl.cc",
 276       "socket/ssl_client_socket_openssl.h",
 277       "socket/ssl_server_socket_openssl.cc",
 278       "socket/ssl_server_socket_openssl.h",
 279       "socket/ssl_session_cache_openssl.cc",
 280       "socket/ssl_session_cache_openssl.h",
 281       "ssl/openssl_platform_key.h",
 282       "ssl/openssl_ssl_util.cc",
 283       "ssl/openssl_ssl_util.h",
 284     ]
 285     if (is_mac) {
 286       sources -= [
 287         "ssl/openssl_platform_key_mac.cc",
 288       ]
 289     }
 290     if (is_win) {
 291       sources -= [
 292         "cert/sha256_legacy_support_openssl_win.cc",
 293         "ssl/openssl_platform_key_win.cc",
 294       ]
 295     }
 296   }
 297
 298   if (!use_openssl_certs) {
 299     sources -= [
 300       "base/keygen_handler_openssl.cc",
 301       "base/openssl_private_key_store.h",
 302       "base/openssl_private_key_store_memory.cc",
 303       "cert/cert_database_openssl.cc",
 304       "cert/cert_verify_proc_openssl.cc",
 305       "cert/cert_verify_proc_openssl.h",
 306       "cert/test_root_certs_openssl.cc",
 307       "cert/x509_certificate_openssl.cc",
 308       "ssl/openssl_client_key_store.cc",
 309       "ssl/openssl_client_key_store.h",
 310     ]
 311     if (is_android) {
 312       sources -= [
 313         "base/openssl_private_key_store_android.cc",
 314       ]
 315     }
 316   } else if (is_android) {
 317     # Android doesn't use these even when using OpenSSL.
 318     sources -= [
 319       "base/openssl_private_key_store_memory.cc",
 320       "cert/cert_database_openssl.cc",
 321       "cert/cert_verify_proc_openssl.cc",
 322       "cert/test_root_certs_openssl.cc",
 323     ]
 324   }
 325
 326   if (use_glib && !is_chromeos) {
 327     configs += [ "//build/config/linux:gconf" ]
 328     deps += [ "//build/config/linux:gio" ]
 329   }
 330
 331   if (is_linux) {
 332     configs += [ "//build/config/linux:libresolv" ]
 333   } else {
 334     sources -= [
 335       "base/crypto_module_nss.cc",
 336       "base/keygen_handler_nss.cc",
 337       "cert/cert_database_nss.cc",
 338       "cert/nss_cert_database.cc",
 339       "cert/nss_cert_database.h",
 340       "cert/x509_certificate_nss.cc",
 341       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 342       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 343       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 344       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 345       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 346       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 347     ]
 348
 349     if (!is_ios && !use_openssl) {
 350       # These files are part of the partial implementation of NSS on iOS so
 351       # keep them in that case.
 352       sources -= [
 353         "cert/test_root_certs_nss.cc",
 354         "ocsp/nss_ocsp.cc",
 355         "ocsp/nss_ocsp.h",
 356       ]
 357     }
 358   }
 359
 360   if (!use_nss_certs) {
 361     sources -= [
 362       "ssl/client_cert_store_nss.cc",
 363       "ssl/client_cert_store_nss.h",
 364     ]
 365     if (!is_ios) {
 366       # These files are part of the partial implementation of NSS on iOS so
 367       # keep them in that case (even though use_nss_certs is not set).
 368       sources -= [
 369         "cert/cert_verify_proc_nss.cc",
 370         "cert/cert_verify_proc_nss.h",
 371       ]
 372     }
 373     if (is_chromeos) {
 374       # These were already removed on non-ChromeOS.
 375       sources -= [
 376         "ssl/client_cert_store_chromeos.cc",
 377         "ssl/client_cert_store_chromeos.h",
 378       ]
 379     }
 380   }
 381
 382   if (!enable_websockets) {
 383     sources -= [
 384       "websockets/websocket_basic_handshake_stream.cc",
 385       "websockets/websocket_basic_handshake_stream.h",
 386       "websockets/websocket_basic_stream.cc",
 387       "websockets/websocket_basic_stream.h",
 388       "websockets/websocket_channel.cc",
 389       "websockets/websocket_channel.h",
 390       "websockets/websocket_deflate_predictor.h",
 391       "websockets/websocket_deflate_predictor_impl.cc",
 392       "websockets/websocket_deflate_predictor_impl.h",
 393       "websockets/websocket_deflate_stream.cc",
 394       "websockets/websocket_deflate_stream.h",
 395       "websockets/websocket_deflater.cc",
 396       "websockets/websocket_deflater.h",
 397       "websockets/websocket_errors.cc",
 398       "websockets/websocket_errors.h",
 399       "websockets/websocket_extension.cc",
 400       "websockets/websocket_extension.h",
 401       "websockets/websocket_extension_parser.cc",
 402       "websockets/websocket_extension_parser.h",
 403       "websockets/websocket_frame.cc",
 404       "websockets/websocket_frame.h",
 405       "websockets/websocket_frame_parser.cc",
 406       "websockets/websocket_frame_parser.h",
 407       "websockets/websocket_handshake_constants.cc",
 408       "websockets/websocket_handshake_constants.h",
 409       "websockets/websocket_handshake_handler.cc",
 410       "websockets/websocket_handshake_handler.h",
 411       "websockets/websocket_handshake_request_info.cc",
 412       "websockets/websocket_handshake_request_info.h",
 413       "websockets/websocket_handshake_response_info.cc",
 414       "websockets/websocket_handshake_response_info.h",
 415       "websockets/websocket_handshake_stream_base.h",
 416       "websockets/websocket_handshake_stream_create_helper.cc",
 417       "websockets/websocket_handshake_stream_create_helper.h",
 418       "websockets/websocket_inflater.cc",
 419       "websockets/websocket_inflater.h",
 420       "websockets/websocket_mux.h",
 421       "websockets/websocket_stream.cc",
 422       "websockets/websocket_stream.h",
 423     ]
 424   }
 425
 426   if (!enable_mdns) {
 427     sources -= [
 428       "dns/mdns_cache.cc",
 429       "dns/mdns_cache.h",
 430       "dns/mdns_client.cc",
 431       "dns/mdns_client.h",
 432       "dns/mdns_client_impl.cc",
 433       "dns/mdns_client_impl.h",
 434       "dns/record_parsed.cc",
 435       "dns/record_parsed.h",
 436       "dns/record_rdata.cc",
 437       "dns/record_rdata.h",
 438     ]
 439   }
 440
 441   if (is_win) {
 442     sources -= [
 443       "http/http_auth_handler_ntlm_portable.cc",
 444       "socket/socket_libevent.cc",
 445       "socket/socket_libevent.h",
 446       "socket/tcp_socket_libevent.cc",
 447       "socket/tcp_socket_libevent.h",
 448       "udp/udp_socket_libevent.cc",
 449       "udp/udp_socket_libevent.h",
 450     ]
 451   } else {  # !is_win
 452     sources -= [
 453       "base/winsock_init.cc",
 454       "base/winsock_init.h",
 455       "base/winsock_util.cc",
 456       "base/winsock_util.h",
 457       "proxy/proxy_resolver_winhttp.cc",
 458       "proxy/proxy_resolver_winhttp.h",
 459     ]
 460   }
 461
 462   if (is_mac) {
 463     libs = [
 464       "Foundation.framework",
 465       "Security.framework",
 466       "SystemConfiguration.framework",
 467       "resolv",
 468     ]
 469   }
 470
 471   if (is_ios) {
 472     # Add back some sources that were otherwise filtered out. iOS additionally
 473     # doesn't set USE_NSS but needs some of the files.
 474     set_sources_assignment_filter([])
 475     sources += [
 476       "base/net_util_mac.cc",
 477       "base/net_util_mac.h",
 478       "base/network_change_notifier_mac.cc",
 479       "base/network_config_watcher_mac.cc",
 480       "base/platform_mime_util_mac.mm",
 481       "cert/cert_verify_proc_nss.cc",
 482       "cert/cert_verify_proc_nss.h",
 483       "cert/test_root_certs_nss.cc",
 484       "cert/x509_util_nss.cc",
 485       "cert/x509_util_nss.h",
 486       "proxy/proxy_resolver_mac.cc",
 487       "proxy/proxy_server_mac.cc",
 488       "ocsp/nss_ocsp.cc",
 489       "ocsp/nss_ocsp.h",
 490     ]
 491     set_sources_assignment_filter(sources_assignment_filter)
 492
 493     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 494     libs = [
 495       "CFNetwork.framework",
 496       "MobileCoreServices.framework",
 497       "Security.framework",
 498       "SystemConfiguration.framework",
 499       "resolv",
 500     ]
 501   }
 502
 503   if (is_android) {
 504     # Add some Linux sources that were excluded by the filter, but which
 505     # are needed.
 506     set_sources_assignment_filter([])
 507     sources += [
 508       "base/platform_mime_util_linux.cc",
 509       "base/address_tracker_linux.cc",
 510       "base/address_tracker_linux.h",
 511       "base/net_util_linux.cc",
 512       "base/net_util_linux.h"
 513     ]
 514     set_sources_assignment_filter(sources_assignment_filter)
 515
 516     if (!is_android_webview_build) {
 517       deps += [ ":net_jni_headers" ]
 518     }
 519   }
 520
 521   if (use_icu_alternatives_on_android) {
 522     deps -= [
 523       "//base:i18n",
 524       "//third_party/icu",
 525     ]
 526     sources -= [
 527       "base/filename_util_icu.cc",
 528       "base/net_string_util_icu.cc",
 529       "base/net_util_icu.cc",
 530     ]
 531     sources += [
 532       "base/net_string_util_icu_alternatives_android.cc",
 533       "base/net_string_util_icu_alternatives_android.h",
 534     ]
 535   }
 536 }
 537
 538 grit("net_resources") {
 539   source = "base/net_resources.grd"
 540   use_qualified_include = true
 541   outputs = [
 542     "grit/net_resources.h",
 543     "net_resources.pak",
 544     "net_resources.rc",
 545   ]
 546 }
 547
 548 static_library("extras") {
 549   sources = gypi_values.net_extras_sources
 550   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 551   deps = [
 552     ":net",
 553     "//sql:sql",
 554   ]
 555 }
 556
 557 static_library("http_server") {
 558   sources = [
 559     "server/http_connection.cc",
 560     "server/http_connection.h",
 561     "server/http_server.cc",
 562     "server/http_server.h",
 563     "server/http_server_request_info.cc",
 564     "server/http_server_request_info.h",
 565     "server/http_server_response_info.cc",
 566     "server/http_server_response_info.h",
 567     "server/web_socket.cc",
 568     "server/web_socket.h",
 569   ]
 570   configs += [
 571     "//build/config/compiler:wexit_time_destructors",
 572     ":net_win_size_truncation"
 573   ]
 574   deps = [
 575     ":net",
 576     "//base",
 577   ]
 578 }
 579
 580 executable("dump_cache") {
 581   testonly = true
 582   sources = [
 583     "tools/dump_cache/cache_dumper.cc",
 584     "tools/dump_cache/cache_dumper.h",
 585     "tools/dump_cache/dump_cache.cc",
 586     "tools/dump_cache/dump_files.cc",
 587     "tools/dump_cache/dump_files.h",
 588     "tools/dump_cache/simple_cache_dumper.cc",
 589     "tools/dump_cache/simple_cache_dumper.h",
 590     "tools/dump_cache/url_to_filename_encoder.cc",
 591     "tools/dump_cache/url_to_filename_encoder.h",
 592     "tools/dump_cache/url_utilities.h",
 593     "tools/dump_cache/url_utilities.cc",
 594   ]
 595
 596   configs += [ ":net_win_size_truncation" ]
 597
 598   deps = [
 599     "//base",
 600     ":net",
 601     ":test_support",
 602   ]
 603 }
 604
 605 source_set("test_support") {
 606   testonly = true
 607   sources = [
 608     "base/capturing_net_log.cc",
 609     "base/capturing_net_log.h",
 610     "base/load_timing_info_test_util.cc",
 611     "base/load_timing_info_test_util.h",
 612     "base/mock_file_stream.cc",
 613     "base/mock_file_stream.h",
 614     "base/test_completion_callback.cc",
 615     "base/test_completion_callback.h",
 616     "base/test_data_directory.cc",
 617     "base/test_data_directory.h",
 618     "cert/mock_cert_verifier.cc",
 619     "cert/mock_cert_verifier.h",
 620     "cookies/cookie_monster_store_test.cc",
 621     "cookies/cookie_monster_store_test.h",
 622     "cookies/cookie_store_test_callbacks.cc",
 623     "cookies/cookie_store_test_callbacks.h",
 624     "cookies/cookie_store_test_helpers.cc",
 625     "cookies/cookie_store_test_helpers.h",
 626     "disk_cache/disk_cache_test_base.cc",
 627     "disk_cache/disk_cache_test_base.h",
 628     "disk_cache/disk_cache_test_util.cc",
 629     "disk_cache/disk_cache_test_util.h",
 630     "dns/dns_test_util.cc",
 631     "dns/dns_test_util.h",
 632     "dns/mock_host_resolver.cc",
 633     "dns/mock_host_resolver.h",
 634     "dns/mock_mdns_socket_factory.cc",
 635     "dns/mock_mdns_socket_factory.h",
 636     "http/http_transaction_test_util.cc",
 637     "http/http_transaction_test_util.h",
 638     "proxy/mock_proxy_resolver.cc",
 639     "proxy/mock_proxy_resolver.h",
 640     "proxy/mock_proxy_script_fetcher.cc",
 641     "proxy/mock_proxy_script_fetcher.h",
 642     "proxy/proxy_config_service_common_unittest.cc",
 643     "proxy/proxy_config_service_common_unittest.h",
 644     "socket/socket_test_util.cc",
 645     "socket/socket_test_util.h",
 646     "test/cert_test_util.cc",
 647     "test/cert_test_util.h",
 648     "test/cert_test_util_nss.cc",
 649     "test/ct_test_util.cc",
 650     "test/ct_test_util.h",
 651     "test/embedded_test_server/embedded_test_server.cc",
 652     "test/embedded_test_server/embedded_test_server.h",
 653     "test/embedded_test_server/http_connection.cc",
 654     "test/embedded_test_server/http_connection.h",
 655     "test/embedded_test_server/http_request.cc",
 656     "test/embedded_test_server/http_request.h",
 657     "test/embedded_test_server/http_response.cc",
 658     "test/embedded_test_server/http_response.h",
 659     "test/net_test_suite.cc",
 660     "test/net_test_suite.h",
 661     "test/python_utils.cc",
 662     "test/python_utils.h",
 663     "test/spawned_test_server/base_test_server.cc",
 664     "test/spawned_test_server/base_test_server.h",
 665     "test/spawned_test_server/local_test_server_posix.cc",
 666     "test/spawned_test_server/local_test_server_win.cc",
 667     "test/spawned_test_server/local_test_server.cc",
 668     "test/spawned_test_server/local_test_server.h",
 669     "test/spawned_test_server/remote_test_server.cc",
 670     "test/spawned_test_server/remote_test_server.h",
 671     "test/spawned_test_server/spawned_test_server.h",
 672     "test/spawned_test_server/spawner_communicator.cc",
 673     "test/spawned_test_server/spawner_communicator.h",
 674     "test/url_request/url_request_failed_job.cc",
 675     "test/url_request/url_request_failed_job.h",
 676     "test/url_request/url_request_mock_http_job.cc",
 677     "test/url_request/url_request_mock_http_job.h",
 678     "url_request/test_url_fetcher_factory.cc",
 679     "url_request/test_url_fetcher_factory.h",
 680     "url_request/test_url_request_interceptor.cc",
 681     "url_request/test_url_request_interceptor.h",
 682     "url_request/url_request_test_util.cc",
 683     "url_request/url_request_test_util.h",
 684   ]
 685
 686   configs += [ ":net_win_size_truncation" ]
 687
 688   public_deps = [
 689     "//base",
 690     "//base/test:test_support",
 691     "//crypto",
 692     "//net",
 693     "//net/tools/tld_cleanup",
 694     "//testing/gmock",
 695     "//testing/gtest",
 696     "//url",
 697   ]
 698
 699   if (!use_openssl && (use_nss_certs || is_ios)) {
 700     public_deps += ["//crypto:platform" ]
 701   }
 702
 703   if (!is_android) {
 704     sources -= [
 705       "test/spawned_test_server/remote_test_server.cc",
 706       "test/spawned_test_server/remote_test_server.h",
 707       "test/spawned_test_server/spawner_communicator.cc",
 708       "test/spawned_test_server/spawner_communicator.h",
 709     ]
 710   }
 711
 712   if (use_v8_in_net) {
 713     public_deps += [ ":net_with_v8" ]
 714   }
 715
 716   if (!enable_mdns) {
 717     sources -= [
 718       "dns/mock_mdns_socket_factory.cc",
 719       "dns/mock_mdns_socket_factory.h",
 720     ]
 721   }
 722
 723   if (!use_nss_certs) {
 724     sources -= [
 725       "test/cert_test_util_nss.cc",
 726     ]
 727   }
 728 }
 729
 730 source_set("balsa") {
 731   sources = [
 732     "tools/balsa/balsa_enums.h",
 733     "tools/balsa/balsa_frame.cc",
 734     "tools/balsa/balsa_frame.h",
 735     "tools/balsa/balsa_headers.cc",
 736     "tools/balsa/balsa_headers.h",
 737     "tools/balsa/balsa_headers_token_utils.cc",
 738     "tools/balsa/balsa_headers_token_utils.h",
 739     "tools/balsa/balsa_visitor_interface.h",
 740     "tools/balsa/http_message_constants.cc",
 741     "tools/balsa/http_message_constants.h",
 742     "tools/balsa/noop_balsa_visitor.h",
 743     "tools/balsa/simple_buffer.cc",
 744     "tools/balsa/simple_buffer.h",
 745     "tools/balsa/split.cc",
 746     "tools/balsa/split.h",
 747     "tools/balsa/string_piece_utils.h",
 748     "tools/quic/spdy_utils.cc",
 749     "tools/quic/spdy_utils.h",
 750   ]
 751   deps = [
 752     ":net",
 753     "//base",
 754     "//url",
 755   ]
 756 }
 757
 758 if (use_v8_in_net) {
 759   component("net_with_v8") {
 760     sources = [
 761       "proxy/proxy_resolver_v8.cc",
 762       "proxy/proxy_resolver_v8.h",
 763       "proxy/proxy_resolver_v8_tracing.cc",
 764       "proxy/proxy_resolver_v8_tracing.h",
 765       "proxy/proxy_service_v8.cc",
 766       "proxy/proxy_service_v8.h",
 767     ]
 768
 769     defines = [ "NET_IMPLEMENTATION" ]
 770     configs += [
 771       ":net_win_size_truncation",
 772       "//build/config/compiler:wexit_time_destructors",
 773     ]
 774
 775     public_deps = [
 776       ":net",
 777     ]
 778     deps = [
 779       "//base",
 780       "//gin",
 781       "//url",
 782       "//v8",
 783     ]
 784   }
 785 }
 786
 787 if (!is_ios && !is_android) {
 788   executable("crash_cache") {
 789     testonly = true
 790     sources = [ "tools/crash_cache/crash_cache.cc" ]
 791     configs += [ ":net_win_size_truncation" ]
 792     deps = [
 793       ":net",
 794       ":test_support",
 795       "//base",
 796     ]
 797   }
 798
 799   executable("crl_set_dump") {
 800     testonly = true
 801     sources = [ "tools/crl_set_dump/crl_set_dump.cc" ]
 802     configs += [ ":net_win_size_truncation" ]
 803     deps = [
 804       ":net",
 805       "//base",
 806     ]
 807   }
 808
 809   executable("dns_fuzz_stub") {
 810     testonly = true
 811     sources = [ "tools/dns_fuzz_stub/dns_fuzz_stub.cc" ]
 812     configs += [ ":net_win_size_truncation" ]
 813     deps = [
 814       ":net",
 815       "//base",
 816     ]
 817   }
 818
 819   executable("gdig") {
 820     testonly = true
 821     sources = [
 822       "tools/gdig/file_net_log.cc",
 823       "tools/gdig/gdig.cc",
 824     ]
 825     deps = [
 826       ":net",
 827       "//base",
 828     ]
 829   }
 830
 831   executable("get_server_time") {
 832     testonly = true
 833     sources = [ "tools/get_server_time/get_server_time.cc" ]
 834     configs += [ ":net_win_size_truncation" ]
 835     deps = [
 836       ":net",
 837       "//base",
 838       "//base:i18n",
 839       "//url",
 840     ]
 841   }
 842
 843   if (use_v8_in_net) {
 844     executable("net_watcher") {
 845       testonly = true
 846       sources = [ "tools/net_watcher/net_watcher.cc" ]
 847       deps = [
 848         ":net",
 849         ":net_with_v8",
 850         "//base",
 851       ]
 852
 853       if (is_desktop_linux) {
 854         configs += [
 855           "//build/config/linux:gconf",
 856           "//build/config/linux:glib",
 857         ]
 858         deps += [ "//build/config/linux:gio" ]
 859       }
 860     }
 861   }
 862
 863   executable("run_testserver") {
 864     testonly = true
 865     sources = [ "tools/testserver/run_testserver.cc" ]
 866     deps = [
 867       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 868                # in the GYP build, and can be removed when the bug is fixed.
 869       ":test_support",
 870       "//base",
 871       "//base/test:test_support",
 872       "//testing/gtest",
 873     ]
 874   }
 875
 876   executable("stress_cache") {
 877     testonly = true
 878     sources = [ "disk_cache/blockfile/stress_cache.cc" ]
 879     configs += [ ":net_win_size_truncation" ]
 880     deps = [
 881       ":net",
 882       ":test_support",
 883       "//base",
 884     ]
 885   }
 886
 887   executable("tld_cleanup") {
 888     sources = [ "tools/tld_cleanup/tld_cleanup.cc" ]
 889     configs += [ ":net_win_size_truncation" ]
 890     deps = [
 891       "//base",
 892       "//base:i18n",
 893       "//net/tools/tld_cleanup",
 894     ]
 895   }
 896 }
 897
 898 if (is_linux) {
 899   static_library("epoll_server") {
 900     sources = [
 901       "tools/epoll_server/epoll_server.cc",
 902       "tools/epoll_server/epoll_server.h",
 903     ]
 904     deps = [
 905       ":net",
 906       "//base",
 907     ]
 908   }
 909
 910   static_library("flip_in_mem_edsm_server_base") {
 911     testonly = true
 912     sources = [
 913       "tools/dump_cache/url_to_filename_encoder.cc",
 914       "tools/dump_cache/url_to_filename_encoder.h",
 915       "tools/dump_cache/url_utilities.h",
 916       "tools/dump_cache/url_utilities.cc",
 917       "tools/flip_server/acceptor_thread.h",
 918       "tools/flip_server/acceptor_thread.cc",
 919       "tools/flip_server/create_listener.cc",
 920       "tools/flip_server/create_listener.h",
 921       "tools/flip_server/constants.h",
 922       "tools/flip_server/flip_config.cc",
 923       "tools/flip_server/flip_config.h",
 924       "tools/flip_server/http_interface.cc",
 925       "tools/flip_server/http_interface.h",
 926       "tools/flip_server/loadtime_measurement.h",
 927       "tools/flip_server/mem_cache.h",
 928       "tools/flip_server/mem_cache.cc",
 929       "tools/flip_server/output_ordering.cc",
 930       "tools/flip_server/output_ordering.h",
 931       "tools/flip_server/ring_buffer.cc",
 932       "tools/flip_server/ring_buffer.h",
 933       "tools/flip_server/sm_connection.cc",
 934       "tools/flip_server/sm_connection.h",
 935       "tools/flip_server/sm_interface.h",
 936       "tools/flip_server/spdy_ssl.cc",
 937       "tools/flip_server/spdy_ssl.h",
 938       "tools/flip_server/spdy_interface.cc",
 939       "tools/flip_server/spdy_interface.h",
 940       "tools/flip_server/spdy_util.cc",
 941       "tools/flip_server/spdy_util.h",
 942       "tools/flip_server/streamer_interface.cc",
 943       "tools/flip_server/streamer_interface.h",
 944     ]
 945     deps = [
 946       ":balsa",
 947       ":epoll_server",
 948       ":net",
 949       "//base",
 950       "//third_party/boringssl",
 951     ]
 952   }
 953
 954   executable("flip_in_mem_edsm_server_unittests") {
 955     testonly = true
 956     sources = [
 957       "tools/flip_server/flip_test_utils.cc",
 958       "tools/flip_server/flip_test_utils.h",
 959       "tools/flip_server/http_interface_test.cc",
 960       "tools/flip_server/mem_cache_test.cc",
 961       "tools/flip_server/run_all_tests.cc",
 962       "tools/flip_server/spdy_interface_test.cc",
 963     ]
 964     deps = [
 965       ":flip_in_mem_edsm_server_base",
 966       ":net",
 967       ":test_support",
 968       "//testing/gtest",
 969       "//testing/gmock",
 970       "//third_party/boringssl",
 971     ]
 972   }
 973
 974   executable("flip_in_mem_edsm_server") {
 975     testonly = true
 976     sources = [ "tools/flip_server/flip_in_mem_edsm_server.cc" ]
 977     deps = [
 978       ":flip_in_mem_edsm_server_base",
 979       ":net",
 980       "//base",
 981     ]
 982   }
 983
 984   source_set("quic_base") {
 985     sources = [
 986       "tools/quic/quic_client.cc",
 987       "tools/quic/quic_client.h",
 988       "tools/quic/quic_client_session.cc",
 989       "tools/quic/quic_client_session.h",
 990       "tools/quic/quic_default_packet_writer.cc",
 991       "tools/quic/quic_default_packet_writer.h",
 992       "tools/quic/quic_dispatcher.h",
 993       "tools/quic/quic_dispatcher.cc",
 994       "tools/quic/quic_epoll_clock.cc",
 995       "tools/quic/quic_epoll_clock.h",
 996       "tools/quic/quic_epoll_connection_helper.cc",
 997       "tools/quic/quic_epoll_connection_helper.h",
 998       "tools/quic/quic_in_memory_cache.cc",
 999       "tools/quic/quic_in_memory_cache.h",
1000       "tools/quic/quic_packet_writer_wrapper.cc",
1001       "tools/quic/quic_packet_writer_wrapper.h",
1002       "tools/quic/quic_per_connection_packet_writer.cc",
1003       "tools/quic/quic_per_connection_packet_writer.h",
1004       "tools/quic/quic_server.cc",
1005       "tools/quic/quic_server.h",
1006       "tools/quic/quic_server_session.cc",
1007       "tools/quic/quic_server_session.h",
1008       "tools/quic/quic_socket_utils.cc",
1009       "tools/quic/quic_socket_utils.h",
1010       "tools/quic/quic_spdy_client_stream.cc",
1011       "tools/quic/quic_spdy_client_stream.h",
1012       "tools/quic/quic_spdy_server_stream.cc",
1013       "tools/quic/quic_spdy_server_stream.h",
1014       "tools/quic/quic_time_wait_list_manager.h",
1015       "tools/quic/quic_time_wait_list_manager.cc",
1016     ]
1017     deps = [
1018       ":balsa",
1019       ":epoll_server",
1020       ":net",
1021       "//base",
1022       "//base/third_party/dynamic_annotations",
1023       "//crypto",
1024       "//third_party/boringssl",
1025       "//url",
1026     ]
1027   }
1028
1029   executable("quic_client") {
1030     sources = [ "tools/quic/quic_client_bin.cc" ]
1031     deps = [
1032       ":quic_base",
1033       ":net",
1034       "//base",
1035       "//third_party/boringssl",
1036     ]
1037   }
1038 }
1039
1040 if (is_android) {
1041   generate_jni("net_jni_headers") {
1042     sources = [
1043       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1044       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1045       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1046       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1047       "android/java/src/org/chromium/net/GURLUtils.java",
1048       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1049       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1050       "android/java/src/org/chromium/net/X509Util.java",
1051     ]
1052     jni_package = "net"
1053   }
1054   generate_jni("net_test_jni_headers") {
1055     sources = [
1056       "android/javatests/src/org/chromium/net/AndroidKeyStoreTestUtil.java",
1057     ]
1058     jni_package = "net"
1059   }
1060 }
1061
1062 if (is_android || is_linux) {
1063   executable("disk_cache_memory_test") {
1064     testonly = true
1065     sources = [ "tools/disk_cache_memory_test/disk_cache_memory_test.cc" ]
1066     deps = [
1067       ":net",
1068       "//base",
1069     ]
1070   }
1071 }
1072
1073 # TODO(GYP) make this compile on Android, we need some native test deps done.
1074 # TODO(GYP) Also doesn't work on Windows; dependency on boringssl is wrong.
1075 # TODO(GYP) Also doesn't work on Mac, need to figure out why not.
1076 if (!is_android && !is_win && !is_mac) {
1077
1078 source_set("quic_tools") {
1079   sources = [
1080     "quic/quic_dispatcher.cc",
1081     "quic/quic_dispatcher.h",
1082     "quic/quic_in_memory_cache.cc",
1083     "quic/quic_in_memory_cache.h",
1084     "quic/quic_per_connection_packet_writer.cc",
1085     "quic/quic_per_connection_packet_writer.h",
1086     "quic/quic_server.cc",
1087     "quic/quic_server.h",
1088     "quic/quic_server_packet_writer.cc",
1089     "quic/quic_server_packet_writer.h",
1090     "quic/quic_server_session.cc",
1091     "quic/quic_server_session.h",
1092     "quic/quic_spdy_server_stream.cc",
1093     "quic/quic_spdy_server_stream.h",
1094     "quic/quic_time_wait_list_manager.cc",
1095     "quic/quic_time_wait_list_manager.h",
1096   ]
1097   deps = [
1098     ":net",
1099     "//base",
1100     "//base/third_party/dynamic_annotations",
1101     "//url",
1102   ]
1103 }
1104
1105 test("net_unittests") {
1106   sources = gypi_values.net_test_sources
1107
1108   configs += [ ":net_win_size_truncation" ]
1109   defines = []
1110
1111   deps = [
1112     ":extras",
1113     ":http_server",
1114     ":net",
1115     ":quic_tools",
1116     ":test_support",
1117     "//base",
1118     "//base:i18n",
1119     "//base:prefs_test_support",
1120     "//base/allocator",
1121     "//base/third_party/dynamic_annotations",
1122     "//crypto",
1123     "//crypto:platform",
1124     "//crypto:test_support",
1125     "//net/base/registry_controlled_domains",
1126     "//testing/gmock",
1127     "//testing/gtest",
1128     "//third_party/zlib",
1129     "//url",
1130   ]
1131
1132   if (is_linux) {
1133     sources += gypi_values.net_linux_test_sources
1134     deps += [
1135       ":balsa",
1136       ":epoll_server",
1137       ":flip_in_mem_edsm_server_base",
1138       ":quic_base",
1139     ]
1140   }
1141
1142   if (is_chromeos) {
1143     sources -= [
1144       "proxy/proxy_config_service_linux_unittest.cc",
1145     ]
1146   }
1147
1148   if (is_android) {
1149     sources -= [
1150       # See bug http://crbug.com/344533.
1151       "disk_cache/blockfile/index_table_v3_unittest.cc",
1152       # No res_ninit() et al on Android, so this doesn't make a lot of
1153       # sense.
1154       "dns/dns_config_service_posix_unittest.cc",
1155     ]
1156     deps += [
1157       ":net_javatests",  # FIXME(brettw)
1158       ":net_test_jni_headers",
1159     ]
1160   }
1161
1162   if (!use_nss_certs) {
1163     sources -= [
1164       "ssl/client_cert_store_nss_unittest.cc",
1165     ]
1166     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1167       sources -= [
1168         "ssl/client_cert_store_chromeos_unittest.cc",
1169       ]
1170     }
1171   }
1172
1173   if (use_openssl) {
1174     # When building for OpenSSL, we need to exclude NSS specific tests
1175     # or functionality not supported by OpenSSL yet.
1176     # TODO(bulach): Add equivalent tests when the underlying
1177     #               functionality is ported to OpenSSL.
1178     sources -= [
1179       "cert/nss_cert_database_unittest.cc",
1180       "cert/x509_util_nss_unittest.cc",
1181       "quic/test_tools/crypto_test_utils_nss.cc",
1182     ]
1183     if (is_chromeos) {
1184       # These were already removed in the non-ChromeOS case.
1185       sources -= [
1186         "cert/nss_cert_database_chromeos_unittest.cc",
1187         "cert/nss_profile_filter_chromeos_unittest.cc",
1188       ]
1189     }
1190   } else {
1191     sources -= [
1192       "cert/x509_util_openssl_unittest.cc",
1193       "quic/test_tools/crypto_test_utils_openssl.cc",
1194       "socket/ssl_client_socket_openssl_unittest.cc",
1195       "socket/ssl_session_cache_openssl_unittest.cc",
1196     ]
1197     if (!is_desktop_linux && !is_chromeos) {
1198       sources -= [ "cert/nss_cert_database_unittest.cc" ]
1199     }
1200   }
1201
1202   if (use_kerberos) {
1203     defines += [ "USE_KERBEROS" ]
1204   } else {
1205     sources -= [
1206       "http/http_auth_gssapi_posix_unittest.cc",
1207       "http/http_auth_handler_negotiate_unittest.cc",
1208       "http/mock_gssapi_library_posix.cc",
1209       "http/mock_gssapi_library_posix.h",
1210     ]
1211   }
1212
1213   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1214     # Only include this test when on Posix and using NSS for
1215     # cert verification or on iOS (which also uses NSS for certs).
1216     sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1217   }
1218
1219   if (!use_openssl_certs) {
1220     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1221   }
1222
1223   if (!enable_websockets) {
1224     sources -= [
1225       "websockets/websocket_basic_stream_test.cc",
1226       "websockets/websocket_channel_test.cc",
1227       "websockets/websocket_deflate_predictor_impl_test.cc",
1228       "websockets/websocket_deflate_stream_test.cc",
1229       "websockets/websocket_deflater_test.cc",
1230       "websockets/websocket_errors_test.cc",
1231       "websockets/websocket_extension_parser_test.cc",
1232       "websockets/websocket_frame_parser_test.cc",
1233       "websockets/websocket_frame_test.cc",
1234       "websockets/websocket_handshake_handler_spdy_test.cc",
1235       "websockets/websocket_handshake_handler_test.cc",
1236       "websockets/websocket_handshake_stream_create_helper_test.cc",
1237       "websockets/websocket_inflater_test.cc",
1238       "websockets/websocket_stream_test.cc",
1239       "websockets/websocket_test_util.cc",
1240       "websockets/websocket_test_util.h",
1241     ]
1242   }
1243
1244   if (disable_file_support) {
1245     sources -= [
1246       "base/directory_lister_unittest.cc",
1247       "url_request/url_request_file_job_unittest.cc",
1248     ]
1249   }
1250
1251   if (disable_ftp_support) {
1252     sources -= [
1253       "ftp/ftp_auth_cache_unittest.cc",
1254       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1255       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1256       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1257       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1258       "ftp/ftp_directory_listing_parser_unittest.cc",
1259       "ftp/ftp_directory_listing_parser_unittest.h",
1260       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1261       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1262       "ftp/ftp_network_transaction_unittest.cc",
1263       "ftp/ftp_util_unittest.cc",
1264       "url_request/url_request_ftp_job_unittest.cc",
1265     ]
1266   }
1267
1268   if (!enable_built_in_dns) {
1269     sources -= [
1270       "dns/address_sorter_posix_unittest.cc",
1271       "dns/address_sorter_unittest.cc",
1272     ]
1273   }
1274
1275   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1276   # net_unittest's dependency on v8 when using icu alternatives instead of
1277   # setting use_v8_in_net to 0.
1278   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1279     deps += [ ":net_with_v8" ]
1280   } else {
1281     sources -= [
1282       "proxy/proxy_resolver_v8_unittest.cc",
1283       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1284     ]
1285   }
1286
1287   if (!enable_mdns) {
1288     sources -= [
1289       "dns/mdns_cache_unittest.cc",
1290       "dns/mdns_client_unittest.cc",
1291       "dns/record_parsed_unittest.cc",
1292       "dns/record_rdata_unittest.cc",
1293     ]
1294   }
1295
1296   if (is_ios) {
1297     # TODO(GYP)
1298     #  'actions': [
1299     #    {
1300     #      'action_name': 'copy_test_data',
1301     #      'variables': {
1302     #        'test_data_files': [
1303     #          'data/ssl/certificates/',
1304     #          'data/test.html',
1305     #          'data/url_request_unittest/',
1306     #        ],
1307     #        'test_data_prefix': 'net',
1308     #      },
1309     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1310     #    },
1311     #  ],
1312     sources -= [
1313       # TODO(droger): The following tests are disabled because the
1314       # implementation is missing or incomplete.
1315       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1316       "base/keygen_handler_unittest.cc",
1317       "disk_cache/backend_unittest.cc",
1318       "disk_cache/blockfile/block_files_unittest.cc",
1319       # Need to read input data files.
1320       "filter/gzip_filter_unittest.cc",
1321       "socket/ssl_server_socket_unittest.cc",
1322       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1323       # Need TestServer.
1324       "proxy/proxy_script_fetcher_impl_unittest.cc",
1325       "socket/ssl_client_socket_unittest.cc",
1326       "url_request/url_fetcher_impl_unittest.cc",
1327       "url_request/url_request_context_builder_unittest.cc",
1328       # Needs GetAppOutput().
1329       "test/python_utils_unittest.cc",
1330
1331       # The following tests are disabled because they don't apply to
1332       # iOS.
1333       # OS is not "linux" or "freebsd" or "openbsd".
1334       "socket/unix_domain_client_socket_posix_unittest.cc",
1335       "socket/unix_domain_listen_socket_posix_unittest.cc",
1336       "socket/unix_domain_server_socket_posix_unittest.cc",
1337
1338       # See bug http://crbug.com/344533.
1339       "disk_cache/blockfile/index_table_v3_unittest.cc",
1340     ]
1341   }
1342
1343   if (is_android) {
1344     sources -= [
1345       "dns/dns_config_service_posix_unittest.cc",
1346     ]
1347     # TODO(GYP)
1348     # # TODO(mmenke):  This depends on test_support_base, which depends on
1349     # #                icu.  Figure out a way to remove that dependency.
1350     # 'dependencies': [
1351     #   '../testing/android/native_test.gyp:native_test_native_code',
1352     # ]
1353
1354     set_sources_assignment_filter([])
1355     sources += [ "base/address_tracker_linux_unittest.cc" ]
1356     set_sources_assignment_filter(sources_assignment_filter)
1357   }
1358
1359   if (use_icu_alternatives_on_android) {
1360     sources -= [
1361       "base/filename_util_unittest.cc",
1362       "base/net_util_icu_unittest.cc",
1363     ]
1364     deps -= [ "//base:i18n" ]
1365   }
1366 }
1367
1368 executable("quic_server") {
1369   sources = [ "quic/quic_server_bin.cc" ]
1370   deps = [
1371     ":quic_tools",
1372     ":net",
1373     "//base",
1374     "//third_party/boringssl",
1375   ]
1376 }
1377
1378 }  # !is_android && !is_win && !is_mac