ui/gfx/ios/NSString+CrStringDrawing.mm

   1 // Copyright 2014 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "ui/gfx/ios/NSString+CrStringDrawing.h"
   6
   7 #include "base/logging.h"
   8 #include "ui/gfx/ios/uikit_util.h"
   9
  10 @implementation NSString (CrStringDrawing)
  11
  12 - (CGRect)cr_boundingRectWithSize:(CGSize)size
  13                              font:(UIFont*)font {
  14   NSDictionary* attributes = font ? @{NSFontAttributeName: font} : @{};
  15   return [self boundingRectWithSize:size
  16                             options:NSStringDrawingUsesLineFragmentOrigin
  17                          attributes:attributes
  18                             context:nil];
  19 }
  20
  21 - (CGSize)cr_boundingSizeWithSize:(CGSize)size
  22                              font:(UIFont*)font {
  23   return [self cr_boundingRectWithSize:size font:font].size;
  24 }
  25
  26 - (CGSize)cr_pixelAlignedSizeWithFont:(UIFont*)font {
  27   DCHECK(font) << "|font| can not be nil; it is used as a NSDictionary value";
  28   NSDictionary* attributes = @{ NSFontAttributeName : font };
  29   return ui::AlignSizeToUpperPixel([self sizeWithAttributes:attributes]);
  30 }
  31
  32 - (CGSize)cr_sizeWithFont:(UIFont*)font {
  33   if (!font)
  34     return CGSizeZero;
  35   NSDictionary* attributes = @{ NSFontAttributeName : font };
  36   CGSize size = [self sizeWithAttributes:attributes];
  37   return CGSizeMake(ceil(size.width), ceil(size.height));
  38 }
  39
  40 - (NSString*)cr_stringByCuttingToIndex:(NSUInteger)index {
  41   if (index == 0)
  42     return @"";
  43   if (index >= [self length])
  44     return [[self retain] autorelease];
  45   return [[self substringToIndex:(index - 1)] stringByAppendingString:@"…"];
  46 }
  47
  48 - (NSString*)cr_stringByElidingToFitSize:(CGSize)bounds {
  49   CGSize sizeForGuess = CGSizeMake(bounds.width, CGFLOAT_MAX);
  50   // Use binary search on the string's length.
  51   size_t lo = 0;
  52   size_t hi = [self length];
  53   size_t guess = 0;
  54   for (guess = (lo + hi) / 2; lo < hi; guess = (lo + hi) / 2) {
  55     NSString* tempString = [self cr_stringByCuttingToIndex:guess];
  56     UIFont* font = [UIFont systemFontOfSize:[UIFont labelFontSize]];
  57     CGSize sizeGuess =
  58         [tempString cr_boundingSizeWithSize:sizeForGuess font:font];
  59     if (sizeGuess.height > bounds.height) {
  60       hi = guess - 1;
  61       if (hi < lo)
  62         hi = lo;
  63     } else {
  64       lo = guess + 1;
  65     }
  66   }
  67   return [self cr_stringByCuttingToIndex:lo];
  68 }
  69
  70 @end