content/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//tools/grit/grit_rule.gni")
   6
   7 # Applied by targets internal to content.
   8 config("content_implementation") {
   9   defines = [ "CONTENT_IMPLEMENTATION" ]
  10 }
  11
  12 # When targets depend on, e.g. //content/public/browser, what happens? To
  13 # facilitate the complexity here, the "public" targets are groups that forward
  14 # to the right thing depending on the build mode. Say for additional
  15 # illustration, the public browser sources also depend on the public common
  16 # ones.
  17 #
  18 # The non-component build is easy:
  19 # foo ->
  20 #   //content/public/browser (group) ->
  21 #     //content/public/browser:browser_sources (source set) ->
  22 #       //content/browser (source set, this is the non-public browser target)
  23 #       //content/public/common:common_sources (source set)
  24 #
  25 # The component build is more complicated because we want everybody to depend on
  26 # one content shared library regardless of which public target they depend on:
  27 # foo ->
  28 #   //content/public/browser (group) ->
  29 #     //content (shared library) ->
  30 #       //content/public/browser:browser_sources (source set) ->
  31 #         //content/browser (source set; this is the non-public browser target)
  32 #         //content/public/common:common_sources (source set)
  33 #
  34 # That the internal content dependencies must depend on the *_sources targets
  35 # to avoid dependency cycles, and external dependencies must depend on the
  36 # //content/public/browser and similar targets to avoid double-linking (these
  37 # targets make sure the dependency goes through the content shared library
  38 # when doing a component build).
  39
  40 content_shared_components = [
  41   "//content/gpu:gpu_sources",
  42   "//content/public/browser:browser_sources",
  43   "//content/public/child:child_sources",
  44   "//content/public/common:common_sources",
  45   "//content/public/plugin:plugin_sources",
  46   "//content/public/renderer:renderer_sources",
  47   "//content/public/utility:utility_sources",
  48 ]
  49
  50 if (enable_plugins) {
  51   content_shared_components += [ "//content/ppapi_plugin:ppapi_plugin_sources" ]
  52 }
  53
  54 if (is_component_build) {
  55   shared_library("content") {
  56     public_deps =
  57         content_shared_components + [ "//content/public/app:both_sources" ]
  58   }
  59 } else {
  60   group("content") {
  61     deps = content_shared_components
  62   }
  63 }
  64
  65 grit("resources") {
  66   source = "content_resources.grd"
  67   use_qualified_include = true
  68   outputs = [
  69     "grit/content_resources.h",
  70     "content_resources.pak",
  71     "content_resources.rc",
  72   ]
  73 }
  74
  75 # This target exists to "hold" the content_export header so we can do proper
  76 # inclusion testing of it.
  77 source_set("export") {
  78   visibility = [ "//content/*" ]
  79   sources = [
  80     "content/common/content_export.h",
  81   ]
  82 }
  83
  84 # In the GYP build, this file is listed in several targets. In GN just have
  85 # those targets depend on this one. This can be depended on for any
  86 # platform for simplicity, and is a no-op on non-Windows.
  87 source_set("startup_helper_win") {
  88   if (is_win) {
  89     sources = [
  90       "app/startup_helper_win.cc",
  91       "public/app/startup_helper_win.h",
  92     ]
  93
  94     deps = [
  95       "//base",
  96       "//base:i18n",
  97       "//sandbox",
  98     ]
  99   }
 100 }