net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//build/module_args/v8.gni")
   9 import("//url/config.gni")
  10 import("//testing/test.gni")
  11 import("//third_party/icu/config.gni")
  12 import("//third_party/protobuf/proto_library.gni")
  13
  14 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  15 # Currently, that file can't be imported multiple times.  Make this always
  16 # imported when http://crbug.com/393704 is fixed.
  17 if (!is_android) {
  18   import("//tools/grit/grit_rule.gni")
  19 }
  20
  21 if (is_android) {
  22   import("//build/config/android/config.gni")
  23   import("//build/config/android/rules.gni")
  24 } else if (is_mac) {
  25   import("//build/config/mac/mac_sdk.gni")
  26 }
  27
  28 # The list of net files is kept in net.gypi. Read it.
  29 gypi_values = exec_script("//build/gypi_to_gn.py",
  30                           [ rebase_path("net.gypi") ],
  31                           "scope",
  32                           [ "net.gypi" ])
  33
  34 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  35 # configuration (krb5.conf and so on).
  36 use_kerberos = !is_chromeos && !is_android && !is_ios
  37
  38 # The way the cache uses mmap() is inefficient on some Android devices. If
  39 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  40 # pretty confident that mmap-ing the index would not hurt any existing x86
  41 # android devices, but we cannot be so sure about the variety of ARM devices.
  42 # So enable it for x86 only for now.
  43 posix_avoid_mmap = is_android && current_cpu != "x86"
  44
  45 # WebSockets and socket stream code are used everywhere except iOS.
  46 enable_websockets = !is_ios
  47 use_v8_in_net = !is_ios
  48 enable_built_in_dns = !is_ios
  49 disable_ftp_support = is_ios
  50
  51 declare_args() {
  52   # Disables support for file URLs.  File URL support requires use of icu.
  53   disable_file_support = false
  54 }
  55
  56 config("net_config") {
  57   defines = []
  58   if (posix_avoid_mmap) {
  59     defines += [ "POSIX_AVOID_MMAP" ]
  60   }
  61   if (disable_file_support) {
  62     defines += [ "DISABLE_FILE_SUPPORT" ]
  63   }
  64 }
  65
  66 component("net") {
  67   sources =
  68       gypi_values.net_nacl_common_sources + gypi_values.net_non_nacl_sources
  69
  70   cflags = []
  71   defines = [
  72     # TODO(GYP) Note that the GYP file supports linux_link_kerberos (defaults to
  73     # 0) which implies that we run pkg_config on kerberos and link to that
  74     # rather than setting this define which will dynamically open it. That
  75     # doesn't seem to be set in the regular builds, so we're skipping this
  76     # capability here.
  77     "DLOPEN_KERBEROS",
  78     "NET_IMPLEMENTATION",
  79   ]
  80
  81   configs += [
  82     "//build/config:precompiled_headers",
  83
  84     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  85     "//build/config/compiler:no_size_t_to_int_warning",
  86   ]
  87   public_configs = [ ":net_config" ]
  88   include_dirs = []
  89
  90   public_deps = [
  91     ":net_quic_proto",
  92     "//crypto",
  93     "//crypto:platform",
  94     "//url",
  95   ]
  96   deps = [
  97     ":net_resources",
  98     "//base",
  99     "//base:prefs",
 100     "//base/third_party/dynamic_annotations",
 101     "//net/base/registry_controlled_domains",
 102     "//sdch",
 103     "//third_party/protobuf:protobuf_lite",
 104     "//third_party/zlib",
 105     "//url",
 106   ]
 107
 108   if (use_kerberos) {
 109     defines += [ "USE_KERBEROS" ]
 110     if (is_android) {
 111       include_dirs += [ "/usr/include/kerberosV" ]
 112     }
 113   } else {
 114     sources -= [
 115       "http/http_auth_gssapi_posix.cc",
 116       "http/http_auth_gssapi_posix.h",
 117       "http/http_auth_handler_negotiate.cc",
 118       "http/http_auth_handler_negotiate.h",
 119     ]
 120   }
 121
 122   if (is_posix) {
 123     if (posix_avoid_mmap) {
 124       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 125     } else {
 126       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 127     }
 128   }
 129
 130   if (disable_file_support) {
 131     sources -= [
 132       "base/directory_lister.cc",
 133       "base/directory_lister.h",
 134       "url_request/file_protocol_handler.cc",
 135       "url_request/file_protocol_handler.h",
 136       "url_request/url_request_file_dir_job.cc",
 137       "url_request/url_request_file_dir_job.h",
 138       "url_request/url_request_file_job.cc",
 139       "url_request/url_request_file_job.h",
 140     ]
 141   }
 142
 143   if (disable_ftp_support) {
 144     sources -= [
 145       "ftp/ftp_auth_cache.cc",
 146       "ftp/ftp_auth_cache.h",
 147       "ftp/ftp_ctrl_response_buffer.cc",
 148       "ftp/ftp_ctrl_response_buffer.h",
 149       "ftp/ftp_directory_listing_parser.cc",
 150       "ftp/ftp_directory_listing_parser.h",
 151       "ftp/ftp_directory_listing_parser_ls.cc",
 152       "ftp/ftp_directory_listing_parser_ls.h",
 153       "ftp/ftp_directory_listing_parser_netware.cc",
 154       "ftp/ftp_directory_listing_parser_netware.h",
 155       "ftp/ftp_directory_listing_parser_os2.cc",
 156       "ftp/ftp_directory_listing_parser_os2.h",
 157       "ftp/ftp_directory_listing_parser_vms.cc",
 158       "ftp/ftp_directory_listing_parser_vms.h",
 159       "ftp/ftp_directory_listing_parser_windows.cc",
 160       "ftp/ftp_directory_listing_parser_windows.h",
 161       "ftp/ftp_network_layer.cc",
 162       "ftp/ftp_network_layer.h",
 163       "ftp/ftp_network_session.cc",
 164       "ftp/ftp_network_session.h",
 165       "ftp/ftp_network_transaction.cc",
 166       "ftp/ftp_network_transaction.h",
 167       "ftp/ftp_request_info.h",
 168       "ftp/ftp_response_info.cc",
 169       "ftp/ftp_response_info.h",
 170       "ftp/ftp_server_type_histograms.cc",
 171       "ftp/ftp_server_type_histograms.h",
 172       "ftp/ftp_transaction.h",
 173       "ftp/ftp_transaction_factory.h",
 174       "ftp/ftp_util.cc",
 175       "ftp/ftp_util.h",
 176       "url_request/ftp_protocol_handler.cc",
 177       "url_request/ftp_protocol_handler.h",
 178       "url_request/url_request_ftp_job.cc",
 179       "url_request/url_request_ftp_job.h",
 180     ]
 181   }
 182
 183   if (enable_built_in_dns) {
 184     defines += [ "ENABLE_BUILT_IN_DNS" ]
 185   } else {
 186     sources -= [
 187       "dns/address_sorter_posix.cc",
 188       "dns/address_sorter_posix.h",
 189       "dns/dns_client.cc",
 190     ]
 191   }
 192
 193   if (use_openssl) {
 194     sources -= [
 195       "base/nss_memio.c",
 196       "base/nss_memio.h",
 197       "cert/ct_log_verifier_nss.cc",
 198       "cert/ct_objects_extractor_nss.cc",
 199       "cert/jwk_serializer_nss.cc",
 200       "cert/scoped_nss_types.h",
 201       "cert/x509_util_nss.cc",
 202       "quic/crypto/aead_base_decrypter_nss.cc",
 203       "quic/crypto/aead_base_encrypter_nss.cc",
 204       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 205       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 206       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 207       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 208       "quic/crypto/channel_id_nss.cc",
 209       "quic/crypto/p256_key_exchange_nss.cc",
 210       "socket/nss_ssl_util.cc",
 211       "socket/nss_ssl_util.h",
 212       "socket/ssl_client_socket_nss.cc",
 213       "socket/ssl_client_socket_nss.h",
 214       "socket/ssl_server_socket_nss.cc",
 215       "socket/ssl_server_socket_nss.h",
 216     ]
 217     if (is_ios) {
 218       # Always removed for !ios below.
 219       sources -= [
 220         "cert/cert_verify_proc_nss.cc",
 221         "cert/cert_verify_proc_nss.h",
 222       ]
 223     }
 224     if (is_win) {
 225       sources -= [ "cert/sha256_legacy_support_nss_win.cc" ]
 226     }
 227     if (!use_nss_certs && !is_ios) {
 228       sources -= [ "cert/x509_util_nss.h" ]
 229     }
 230   } else {
 231     sources -= [
 232       "cert/ct_log_verifier_openssl.cc",
 233       "cert/ct_objects_extractor_openssl.cc",
 234       "cert/jwk_serializer_openssl.cc",
 235       "cert/x509_util_openssl.cc",
 236       "cert/x509_util_openssl.h",
 237       "quic/crypto/aead_base_decrypter_openssl.cc",
 238       "quic/crypto/aead_base_encrypter_openssl.cc",
 239       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 240       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 241       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 242       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 243       "quic/crypto/channel_id_openssl.cc",
 244       "quic/crypto/p256_key_exchange_openssl.cc",
 245       "quic/crypto/scoped_evp_aead_ctx.cc",
 246       "quic/crypto/scoped_evp_aead_ctx.h",
 247       "socket/ssl_client_socket_openssl.cc",
 248       "socket/ssl_client_socket_openssl.h",
 249       "socket/ssl_server_socket_openssl.cc",
 250       "socket/ssl_server_socket_openssl.h",
 251       "ssl/openssl_ssl_util.cc",
 252       "ssl/openssl_ssl_util.h",
 253       "ssl/ssl_client_session_cache_openssl.cc",
 254       "ssl/ssl_client_session_cache_openssl.h",
 255       "ssl/ssl_platform_key.h",
 256       "ssl/threaded_ssl_private_key.cc",
 257       "ssl/threaded_ssl_private_key.h",
 258     ]
 259     if (is_mac) {
 260       sources -= [ "ssl/ssl_platform_key_mac.cc" ]
 261     }
 262     if (is_win) {
 263       sources -= [
 264         "cert/sha256_legacy_support_openssl_win.cc",
 265         "ssl/ssl_platform_key_win.cc",
 266       ]
 267     }
 268     if (use_nss_certs) {
 269       sources -= [ "ssl/ssl_platform_key_nss.cc" ]
 270     }
 271   }
 272
 273   if (!use_openssl_certs) {
 274     sources -= [
 275       "base/crypto_module_openssl.cc",
 276       "base/keygen_handler_openssl.cc",
 277       "base/openssl_private_key_store.h",
 278       "base/openssl_private_key_store_memory.cc",
 279       "cert/cert_database_openssl.cc",
 280       "cert/cert_verify_proc_openssl.cc",
 281       "cert/cert_verify_proc_openssl.h",
 282       "cert/test_root_certs_openssl.cc",
 283       "cert/x509_certificate_openssl.cc",
 284       "ssl/openssl_client_key_store.cc",
 285       "ssl/openssl_client_key_store.h",
 286     ]
 287     if (is_android) {
 288       sources -= [ "base/openssl_private_key_store_android.cc" ]
 289     }
 290   } else {
 291     if (is_android) {
 292       # Android doesn't use these even when using OpenSSL.
 293       sources -= [
 294         "base/openssl_private_key_store_memory.cc",
 295         "cert/cert_database_openssl.cc",
 296         "cert/cert_verify_proc_openssl.cc",
 297         "cert/test_root_certs_openssl.cc",
 298       ]
 299     }
 300
 301     # TODO(davidben): Remove these exclusions when use_openssl_certs builds also
 302     # use the SSLPrivateKey machinery.
 303     sources -= [
 304       "ssl/threaded_ssl_private_key.cc",
 305       "ssl/threaded_ssl_private_key.h",
 306     ]
 307   }
 308
 309   if (use_glib && !is_chromeos) {
 310     configs += [ "//build/config/linux:gconf" ]
 311     deps += [ "//build/config/linux:gio" ]
 312   }
 313
 314   if (is_linux) {
 315     configs += [ "//build/config/linux:libresolv" ]
 316   }
 317
 318   if (!use_nss_certs) {
 319     sources -= [
 320       "base/crypto_module_nss.cc",
 321       "base/keygen_handler_nss.cc",
 322       "cert/cert_database_nss.cc",
 323       "cert/nss_cert_database.cc",
 324       "cert/nss_cert_database.h",
 325       "cert/x509_certificate_nss.cc",
 326       "ssl/client_cert_store_nss.cc",
 327       "ssl/client_cert_store_nss.h",
 328       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 329       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 330       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 331       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 332       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 333       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 334     ]
 335     if (!is_ios) {
 336       # These files are part of the partial implementation of NSS on iOS so
 337       # keep them in that case (even though use_nss_certs is not set).
 338       sources -= [
 339         "cert/cert_verify_proc_nss.cc",
 340         "cert/cert_verify_proc_nss.h",
 341         "cert/test_root_certs_nss.cc",
 342         "cert/x509_util_nss_certs.cc",
 343         "cert_net/nss_ocsp.cc",
 344         "cert_net/nss_ocsp.h",
 345       ]
 346     }
 347     if (is_chromeos) {
 348       # These were already removed on non-ChromeOS.
 349       sources -= [
 350         "cert/nss_cert_database_chromeos.cc",
 351         "cert/nss_cert_database_chromeos.h",
 352         "cert/nss_profile_filter_chromeos.cc",
 353         "cert/nss_profile_filter_chromeos.h",
 354         "ssl/client_cert_store_chromeos.cc",
 355         "ssl/client_cert_store_chromeos.h",
 356       ]
 357     }
 358     sources -= [ "ssl/ssl_platform_key_nss.cc" ]
 359   } else if (use_openssl) {
 360     # client_cert_store_nss.c requires NSS_CmpCertChainWCANames from NSS's
 361     # libssl, but our bundled copy is not built in OpenSSL ports. Pull that file
 362     # in directly.
 363     sources += [ "third_party/nss/ssl/cmpcert.c" ]
 364   }
 365
 366   if (!enable_websockets) {
 367     sources -= [
 368       "websockets/websocket_basic_handshake_stream.cc",
 369       "websockets/websocket_basic_handshake_stream.h",
 370       "websockets/websocket_basic_stream.cc",
 371       "websockets/websocket_basic_stream.h",
 372       "websockets/websocket_channel.cc",
 373       "websockets/websocket_channel.h",
 374       "websockets/websocket_deflate_predictor.h",
 375       "websockets/websocket_deflate_predictor_impl.cc",
 376       "websockets/websocket_deflate_predictor_impl.h",
 377       "websockets/websocket_deflate_stream.cc",
 378       "websockets/websocket_deflate_stream.h",
 379       "websockets/websocket_deflater.cc",
 380       "websockets/websocket_deflater.h",
 381       "websockets/websocket_errors.cc",
 382       "websockets/websocket_errors.h",
 383       "websockets/websocket_extension.cc",
 384       "websockets/websocket_extension.h",
 385       "websockets/websocket_extension_parser.cc",
 386       "websockets/websocket_extension_parser.h",
 387       "websockets/websocket_frame.cc",
 388       "websockets/websocket_frame.h",
 389       "websockets/websocket_frame_parser.cc",
 390       "websockets/websocket_frame_parser.h",
 391       "websockets/websocket_handshake_challenge.cc",
 392       "websockets/websocket_handshake_challenge.h",
 393       "websockets/websocket_handshake_constants.cc",
 394       "websockets/websocket_handshake_constants.h",
 395       "websockets/websocket_handshake_request_info.cc",
 396       "websockets/websocket_handshake_request_info.h",
 397       "websockets/websocket_handshake_response_info.cc",
 398       "websockets/websocket_handshake_response_info.h",
 399       "websockets/websocket_handshake_stream_base.h",
 400       "websockets/websocket_handshake_stream_create_helper.cc",
 401       "websockets/websocket_handshake_stream_create_helper.h",
 402       "websockets/websocket_inflater.cc",
 403       "websockets/websocket_inflater.h",
 404       "websockets/websocket_mux.h",
 405       "websockets/websocket_stream.cc",
 406       "websockets/websocket_stream.h",
 407     ]
 408   }
 409
 410   if (!enable_mdns) {
 411     sources -= [
 412       "dns/mdns_cache.cc",
 413       "dns/mdns_cache.h",
 414       "dns/mdns_client.cc",
 415       "dns/mdns_client.h",
 416       "dns/mdns_client_impl.cc",
 417       "dns/mdns_client_impl.h",
 418       "dns/record_parsed.cc",
 419       "dns/record_parsed.h",
 420       "dns/record_rdata.cc",
 421       "dns/record_rdata.h",
 422     ]
 423   }
 424
 425   if (is_win) {
 426     sources -= [
 427       "http/http_auth_handler_ntlm_portable.cc",
 428       "socket/socket_libevent.cc",
 429       "socket/socket_libevent.h",
 430       "socket/tcp_socket_libevent.cc",
 431       "socket/tcp_socket_libevent.h",
 432       "udp/udp_socket_libevent.cc",
 433       "udp/udp_socket_libevent.h",
 434     ]
 435   } else {  # !is_win
 436     sources -= [
 437       "base/winsock_init.cc",
 438       "base/winsock_init.h",
 439       "base/winsock_util.cc",
 440       "base/winsock_util.h",
 441       "proxy/proxy_resolver_winhttp.cc",
 442       "proxy/proxy_resolver_winhttp.h",
 443     ]
 444   }
 445
 446   if (is_mac) {
 447     libs = [
 448       "Foundation.framework",
 449       "Security.framework",
 450       "SystemConfiguration.framework",
 451       "resolv",
 452     ]
 453   }
 454
 455   if (is_ios) {
 456     # Add back some sources that were otherwise filtered out. iOS needs some Mac
 457     # files.
 458     set_sources_assignment_filter([])
 459     sources += [
 460       "base/mac/url_conversions.h",
 461       "base/mac/url_conversions.mm",
 462       "base/network_change_notifier_mac.cc",
 463       "base/network_config_watcher_mac.cc",
 464       "base/network_interfaces_mac.cc",
 465       "base/network_interfaces_mac.h",
 466       "base/platform_mime_util_mac.mm",
 467       "proxy/proxy_resolver_mac.cc",
 468       "proxy/proxy_server_mac.cc",
 469     ]
 470     set_sources_assignment_filter(sources_assignment_filter)
 471
 472     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 473     libs = [
 474       "CFNetwork.framework",
 475       "MobileCoreServices.framework",
 476       "Security.framework",
 477       "SystemConfiguration.framework",
 478       "resolv",
 479     ]
 480   }
 481
 482   if (is_ios || is_mac) {
 483     sources += gypi_values.net_base_mac_ios_sources
 484   }
 485
 486   if (is_android) {
 487     # Add some Linux sources that were excluded by the filter, but which
 488     # are needed.
 489     set_sources_assignment_filter([])
 490     sources += [
 491       "base/address_tracker_linux.cc",
 492       "base/address_tracker_linux.h",
 493       "base/network_interfaces_linux.cc",
 494       "base/network_interfaces_linux.h",
 495       "base/platform_mime_util_linux.cc",
 496     ]
 497     set_sources_assignment_filter(sources_assignment_filter)
 498     deps += [ ":net_jni_headers" ]
 499   }
 500
 501   if (use_icu_alternatives_on_android) {
 502     sources += [
 503       "base/net_string_util_icu_alternatives_android.cc",
 504       "base/net_string_util_icu_alternatives_android.h",
 505     ]
 506   } else {
 507     deps += [
 508       "//base:i18n",
 509       "//third_party/icu",
 510     ]
 511     sources += [
 512       "base/filename_util_icu.cc",
 513       "base/net_string_util_icu.cc",
 514       "base/net_util_icu.cc",
 515     ]
 516   }
 517 }
 518
 519 grit("net_resources") {
 520   source = "base/net_resources.grd"
 521   use_qualified_include = true
 522   outputs = [
 523     "grit/net_resources.h",
 524     "net_resources.pak",
 525   ]
 526 }
 527
 528 proto_library("net_quic_proto") {
 529   visibility = [ "//net" ]  # Part of the net component.
 530
 531   sources = [
 532     "quic/proto/cached_network_parameters.proto",
 533     "quic/proto/source_address_token.proto",
 534   ]
 535   cc_generator_options = "dllexport_decl=NET_EXPORT_PRIVATE:"
 536   cc_include = "net/base/net_export.h"
 537
 538   defines = [ "NET_IMPLEMENTATION" ]
 539
 540   extra_configs = [ "//build/config/compiler:wexit_time_destructors" ]
 541 }
 542
 543 static_library("extras") {
 544   sources = gypi_values.net_extras_sources
 545   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 546   deps = [
 547     ":net",
 548     "//base",
 549     "//sql:sql",
 550   ]
 551 }
 552
 553 static_library("http_server") {
 554   sources = [
 555     "server/http_connection.cc",
 556     "server/http_connection.h",
 557     "server/http_server.cc",
 558     "server/http_server.h",
 559     "server/http_server_request_info.cc",
 560     "server/http_server_request_info.h",
 561     "server/http_server_response_info.cc",
 562     "server/http_server_response_info.h",
 563     "server/web_socket.cc",
 564     "server/web_socket.h",
 565     "server/web_socket_encoder.cc",
 566     "server/web_socket_encoder.h",
 567   ]
 568   configs += [
 569     "//build/config/compiler:no_size_t_to_int_warning",
 570     "//build/config/compiler:wexit_time_destructors",
 571   ]
 572   deps = [
 573     ":net",
 574     "//base",
 575   ]
 576 }
 577
 578 executable("dump_cache") {
 579   testonly = true
 580   sources = [
 581     "tools/dump_cache/cache_dumper.cc",
 582     "tools/dump_cache/cache_dumper.h",
 583     "tools/dump_cache/dump_cache.cc",
 584     "tools/dump_cache/dump_files.cc",
 585     "tools/dump_cache/dump_files.h",
 586     "tools/dump_cache/simple_cache_dumper.cc",
 587     "tools/dump_cache/simple_cache_dumper.h",
 588     "tools/dump_cache/url_to_filename_encoder.cc",
 589     "tools/dump_cache/url_to_filename_encoder.h",
 590     "tools/dump_cache/url_utilities.cc",
 591     "tools/dump_cache/url_utilities.h",
 592   ]
 593
 594   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 595   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 596
 597   deps = [
 598     "//base",
 599     ":net",
 600     ":test_support",
 601   ]
 602 }
 603
 604 source_set("test_support") {
 605   testonly = true
 606   sources = [
 607     "base/load_timing_info_test_util.cc",
 608     "base/load_timing_info_test_util.h",
 609     "base/mock_file_stream.cc",
 610     "base/mock_file_stream.h",
 611     "base/test_completion_callback.cc",
 612     "base/test_completion_callback.h",
 613     "base/test_data_directory.cc",
 614     "base/test_data_directory.h",
 615     "cert/mock_cert_verifier.cc",
 616     "cert/mock_cert_verifier.h",
 617     "cookies/cookie_monster_store_test.cc",
 618     "cookies/cookie_monster_store_test.h",
 619     "cookies/cookie_store_test_callbacks.cc",
 620     "cookies/cookie_store_test_callbacks.h",
 621     "cookies/cookie_store_test_helpers.cc",
 622     "cookies/cookie_store_test_helpers.h",
 623     "disk_cache/disk_cache_test_base.cc",
 624     "disk_cache/disk_cache_test_base.h",
 625     "disk_cache/disk_cache_test_util.cc",
 626     "disk_cache/disk_cache_test_util.h",
 627     "dns/dns_test_util.cc",
 628     "dns/dns_test_util.h",
 629     "dns/mock_host_resolver.cc",
 630     "dns/mock_host_resolver.h",
 631     "dns/mock_mdns_socket_factory.cc",
 632     "dns/mock_mdns_socket_factory.h",
 633     "http/http_transaction_test_util.cc",
 634     "http/http_transaction_test_util.h",
 635     "log/test_net_log.cc",
 636     "log/test_net_log.h",
 637     "log/test_net_log_entry.cc",
 638     "log/test_net_log_entry.h",
 639     "log/test_net_log_util.cc",
 640     "log/test_net_log_util.h",
 641     "proxy/mock_proxy_resolver.cc",
 642     "proxy/mock_proxy_resolver.h",
 643     "proxy/mock_proxy_script_fetcher.cc",
 644     "proxy/mock_proxy_script_fetcher.h",
 645     "proxy/proxy_config_service_common_unittest.cc",
 646     "proxy/proxy_config_service_common_unittest.h",
 647     "socket/socket_test_util.cc",
 648     "socket/socket_test_util.h",
 649     "test/cert_test_util.cc",
 650     "test/cert_test_util.h",
 651     "test/cert_test_util_nss.cc",
 652     "test/channel_id_test_util.cc",
 653     "test/channel_id_test_util.h",
 654     "test/ct_test_util.cc",
 655     "test/ct_test_util.h",
 656     "test/embedded_test_server/embedded_test_server.cc",
 657     "test/embedded_test_server/embedded_test_server.h",
 658     "test/embedded_test_server/http_connection.cc",
 659     "test/embedded_test_server/http_connection.h",
 660     "test/embedded_test_server/http_request.cc",
 661     "test/embedded_test_server/http_request.h",
 662     "test/embedded_test_server/http_response.cc",
 663     "test/embedded_test_server/http_response.h",
 664     "test/embedded_test_server/stream_listen_socket.cc",
 665     "test/embedded_test_server/stream_listen_socket.h",
 666     "test/embedded_test_server/tcp_listen_socket.cc",
 667     "test/embedded_test_server/tcp_listen_socket.h",
 668     "test/event_waiter.h",
 669     "test/net_test_suite.cc",
 670     "test/net_test_suite.h",
 671     "test/python_utils.cc",
 672     "test/python_utils.h",
 673     "test/spawned_test_server/base_test_server.cc",
 674     "test/spawned_test_server/base_test_server.h",
 675     "test/spawned_test_server/local_test_server.cc",
 676     "test/spawned_test_server/local_test_server.h",
 677     "test/spawned_test_server/local_test_server_posix.cc",
 678     "test/spawned_test_server/local_test_server_win.cc",
 679     "test/spawned_test_server/remote_test_server.cc",
 680     "test/spawned_test_server/remote_test_server.h",
 681     "test/spawned_test_server/spawned_test_server.h",
 682     "test/spawned_test_server/spawner_communicator.cc",
 683     "test/spawned_test_server/spawner_communicator.h",
 684     "test/url_request/ssl_certificate_error_job.cc",
 685     "test/url_request/ssl_certificate_error_job.h",
 686     "test/url_request/url_request_failed_job.cc",
 687     "test/url_request/url_request_failed_job.h",
 688     "test/url_request/url_request_mock_data_job.cc",
 689     "test/url_request/url_request_mock_data_job.h",
 690     "test/url_request/url_request_slow_download_job.cc",
 691     "test/url_request/url_request_slow_download_job.h",
 692     "url_request/test_url_fetcher_factory.cc",
 693     "url_request/test_url_fetcher_factory.h",
 694     "url_request/url_request_test_util.cc",
 695     "url_request/url_request_test_util.h",
 696   ]
 697
 698   configs += [
 699     "//build/config:precompiled_headers",
 700
 701     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 702     "//build/config/compiler:no_size_t_to_int_warning",
 703   ]
 704
 705   public_deps = [
 706     "//base",
 707     "//base/test:test_support",
 708     "//crypto",
 709     "//net",
 710     "//net/tools/tld_cleanup",
 711     "//testing/gmock",
 712     "//testing/gtest",
 713     "//url",
 714   ]
 715
 716   if (!is_ios) {
 717     public_deps += [ "//third_party/protobuf:py_proto" ]
 718   }
 719
 720   if (use_nss_certs || is_ios) {
 721     public_deps += [ "//crypto:platform" ]
 722   }
 723
 724   if (!is_android) {
 725     sources -= [
 726       "test/spawned_test_server/remote_test_server.cc",
 727       "test/spawned_test_server/remote_test_server.h",
 728       "test/spawned_test_server/spawner_communicator.cc",
 729       "test/spawned_test_server/spawner_communicator.h",
 730     ]
 731   }
 732
 733   if (use_v8_in_net) {
 734     public_deps += [ ":net_with_v8" ]
 735   }
 736
 737   if (!enable_mdns) {
 738     sources -= [
 739       "dns/mock_mdns_socket_factory.cc",
 740       "dns/mock_mdns_socket_factory.h",
 741     ]
 742   }
 743
 744   if (!use_nss_certs) {
 745     sources -= [ "test/cert_test_util_nss.cc" ]
 746   }
 747
 748   if (!disable_file_support) {
 749     sources += [
 750       "test/url_request/url_request_mock_http_job.cc",
 751       "test/url_request/url_request_mock_http_job.h",
 752       "url_request/test_url_request_interceptor.cc",
 753       "url_request/test_url_request_interceptor.h",
 754     ]
 755   }
 756 }
 757
 758 source_set("balsa") {
 759   sources = [
 760     "tools/balsa/balsa_enums.h",
 761     "tools/balsa/balsa_frame.cc",
 762     "tools/balsa/balsa_frame.h",
 763     "tools/balsa/balsa_headers.cc",
 764     "tools/balsa/balsa_headers.h",
 765     "tools/balsa/balsa_headers_token_utils.cc",
 766     "tools/balsa/balsa_headers_token_utils.h",
 767     "tools/balsa/balsa_visitor_interface.h",
 768     "tools/balsa/http_message_constants.cc",
 769     "tools/balsa/http_message_constants.h",
 770     "tools/balsa/noop_balsa_visitor.h",
 771     "tools/balsa/simple_buffer.cc",
 772     "tools/balsa/simple_buffer.h",
 773     "tools/balsa/split.cc",
 774     "tools/balsa/split.h",
 775     "tools/balsa/string_piece_utils.h",
 776     "tools/quic/spdy_balsa_utils.cc",
 777     "tools/quic/spdy_balsa_utils.h",
 778   ]
 779   deps = [
 780     ":net",
 781     "//base",
 782     "//url",
 783   ]
 784 }
 785
 786 if (use_v8_in_net) {
 787   component("net_with_v8") {
 788     sources = [
 789       "proxy/proxy_resolver_v8.cc",
 790       "proxy/proxy_resolver_v8.h",
 791       "proxy/proxy_resolver_v8_tracing.cc",
 792       "proxy/proxy_resolver_v8_tracing.h",
 793       "proxy/proxy_resolver_v8_tracing_wrapper.cc",
 794       "proxy/proxy_resolver_v8_tracing_wrapper.h",
 795       "proxy/proxy_service_v8.cc",
 796       "proxy/proxy_service_v8.h",
 797     ]
 798
 799     defines = [ "NET_IMPLEMENTATION" ]
 800     configs += [
 801       "//build/config/compiler:no_size_t_to_int_warning",
 802       "//build/config/compiler:wexit_time_destructors",
 803     ]
 804
 805     public_deps = [
 806       ":net",
 807     ]
 808     deps = [
 809       "//base",
 810       "//gin",
 811       "//url",
 812       "//v8",
 813     ]
 814   }
 815 }
 816
 817 if (use_v8_in_net && !is_android) {
 818   source_set("net_browser_services") {
 819     sources = [
 820       "dns/mojo_host_resolver_impl.cc",
 821       "dns/mojo_host_resolver_impl.h",
 822       "proxy/in_process_mojo_proxy_resolver_factory.cc",
 823       "proxy/in_process_mojo_proxy_resolver_factory.h",
 824       "proxy/mojo_proxy_resolver_factory.h",
 825       "proxy/proxy_resolver_factory_mojo.cc",
 826       "proxy/proxy_resolver_factory_mojo.h",
 827       "proxy/proxy_service_mojo.cc",
 828       "proxy/proxy_service_mojo.h",
 829     ]
 830
 831     public_deps = [
 832       ":mojo_type_converters",
 833       ":net",
 834       "//base",
 835       "//mojo/common",
 836       "//net/interfaces",
 837       "//third_party/mojo/src/mojo/public/cpp/bindings",
 838
 839       # NOTE(amistry): As long as we support in-process Mojo v8 PAC, we need
 840       # this dependency since in_process_mojo_proxy_resolver_factory creates
 841       # the utility process side Mojo services in the browser process.
 842       # Ultimately, this will go away when we only support out-of-process.
 843       ":net_utility_services",
 844     ]
 845   }
 846
 847   source_set("mojo_type_converters") {
 848     sources = [
 849       "dns/mojo_host_type_converters.cc",
 850       "dns/mojo_host_type_converters.h",
 851       "proxy/mojo_proxy_type_converters.cc",
 852       "proxy/mojo_proxy_type_converters.h",
 853     ]
 854
 855     public_deps = [
 856       ":net",
 857       "//net/interfaces",
 858       "//third_party/mojo/src/mojo/public/cpp/bindings",
 859     ]
 860   }
 861
 862   source_set("net_utility_services") {
 863     sources = [
 864       "dns/host_resolver_mojo.cc",
 865       "dns/host_resolver_mojo.h",
 866       "proxy/mojo_proxy_resolver_factory_impl.cc",
 867       "proxy/mojo_proxy_resolver_factory_impl.h",
 868       "proxy/mojo_proxy_resolver_impl.cc",
 869       "proxy/mojo_proxy_resolver_impl.h",
 870       "proxy/mojo_proxy_resolver_v8_tracing_bindings.h",
 871     ]
 872
 873     deps = [
 874       ":net_with_v8",
 875     ]
 876
 877     public_deps = [
 878       ":mojo_type_converters",
 879       ":net",
 880       "//mojo/common",
 881       "//net/interfaces",
 882       "//third_party/mojo/src/mojo/public/cpp/bindings",
 883     ]
 884   }
 885 }
 886
 887 if (!is_ios && !is_android) {
 888   executable("crash_cache") {
 889     testonly = true
 890     sources = [
 891       "tools/crash_cache/crash_cache.cc",
 892     ]
 893
 894     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 895     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 896     deps = [
 897       ":net",
 898       ":test_support",
 899       "//base",
 900     ]
 901   }
 902
 903   executable("crl_set_dump") {
 904     testonly = true
 905     sources = [
 906       "tools/crl_set_dump/crl_set_dump.cc",
 907     ]
 908
 909     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 910     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 911     deps = [
 912       ":net",
 913       "//base",
 914     ]
 915   }
 916
 917   executable("dns_fuzz_stub") {
 918     testonly = true
 919     sources = [
 920       "tools/dns_fuzz_stub/dns_fuzz_stub.cc",
 921     ]
 922
 923     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 924     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 925     deps = [
 926       ":net",
 927       "//base",
 928     ]
 929   }
 930
 931   executable("gdig") {
 932     testonly = true
 933     sources = [
 934       "tools/gdig/file_net_log.cc",
 935       "tools/gdig/gdig.cc",
 936     ]
 937     deps = [
 938       ":net",
 939       "//base",
 940     ]
 941   }
 942
 943   executable("get_server_time") {
 944     testonly = true
 945     sources = [
 946       "tools/get_server_time/get_server_time.cc",
 947     ]
 948
 949     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 950     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 951     deps = [
 952       ":net",
 953       "//base",
 954       "//base:i18n",
 955       "//url",
 956     ]
 957   }
 958
 959   executable("hpack_example_generator") {
 960     testonly = true
 961     sources = [
 962       "spdy/fuzzing/hpack_example_generator.cc",
 963     ]
 964
 965     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 966     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 967     deps = [
 968       "//base",
 969       ":net",
 970     ]
 971   }
 972
 973   executable("hpack_fuzz_mutator") {
 974     testonly = true
 975     sources = [
 976       "spdy/fuzzing/hpack_fuzz_mutator.cc",
 977     ]
 978
 979     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 980     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 981     deps = [
 982       "//base",
 983       ":net",
 984     ]
 985   }
 986
 987   executable("hpack_fuzz_wrapper") {
 988     testonly = true
 989     sources = [
 990       "spdy/fuzzing/hpack_fuzz_wrapper.cc",
 991     ]
 992
 993     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 994     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 995     deps = [
 996       "//base",
 997       ":net",
 998     ]
 999   }
1000
1001   if (use_v8_in_net) {
1002     executable("net_watcher") {
1003       testonly = true
1004       sources = [
1005         "tools/net_watcher/net_watcher.cc",
1006       ]
1007       deps = [
1008         ":net",
1009         ":net_with_v8",
1010         "//base",
1011       ]
1012
1013       if (is_desktop_linux) {
1014         configs += [
1015           "//build/config/linux:gconf",
1016           "//build/config/linux:glib",
1017         ]
1018         deps += [ "//build/config/linux:gio" ]
1019       }
1020     }
1021   }
1022
1023   executable("run_testserver") {
1024     testonly = true
1025     sources = [
1026       "tools/testserver/run_testserver.cc",
1027     ]
1028     deps = [
1029       ":test_support",
1030       "//base",
1031       "//base/test:test_support",
1032       "//testing/gtest",
1033     ]
1034   }
1035
1036   executable("stress_cache") {
1037     testonly = true
1038     sources = [
1039       "tools/stress_cache/stress_cache.cc",
1040     ]
1041
1042     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1043     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
1044     deps = [
1045       ":net",
1046       ":test_support",
1047       "//base",
1048     ]
1049   }
1050
1051   executable("tld_cleanup") {
1052     sources = [
1053       "tools/tld_cleanup/tld_cleanup.cc",
1054     ]
1055
1056     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1057     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
1058     deps = [
1059       "//base",
1060       "//base:i18n",
1061       "//net/tools/tld_cleanup",
1062     ]
1063   }
1064 }
1065
1066 if (is_linux) {
1067   static_library("epoll_server") {
1068     sources = [
1069       "tools/epoll_server/epoll_server.cc",
1070       "tools/epoll_server/epoll_server.h",
1071     ]
1072     deps = [
1073       ":net",
1074       "//base",
1075     ]
1076   }
1077
1078   static_library("flip_in_mem_edsm_server_base") {
1079     testonly = true
1080     sources = [
1081       "tools/dump_cache/url_to_filename_encoder.cc",
1082       "tools/dump_cache/url_to_filename_encoder.h",
1083       "tools/dump_cache/url_utilities.cc",
1084       "tools/dump_cache/url_utilities.h",
1085       "tools/flip_server/acceptor_thread.cc",
1086       "tools/flip_server/acceptor_thread.h",
1087       "tools/flip_server/constants.h",
1088       "tools/flip_server/create_listener.cc",
1089       "tools/flip_server/create_listener.h",
1090       "tools/flip_server/flip_config.cc",
1091       "tools/flip_server/flip_config.h",
1092       "tools/flip_server/http_interface.cc",
1093       "tools/flip_server/http_interface.h",
1094       "tools/flip_server/loadtime_measurement.h",
1095       "tools/flip_server/mem_cache.cc",
1096       "tools/flip_server/mem_cache.h",
1097       "tools/flip_server/output_ordering.cc",
1098       "tools/flip_server/output_ordering.h",
1099       "tools/flip_server/ring_buffer.cc",
1100       "tools/flip_server/ring_buffer.h",
1101       "tools/flip_server/sm_connection.cc",
1102       "tools/flip_server/sm_connection.h",
1103       "tools/flip_server/sm_interface.h",
1104       "tools/flip_server/spdy_interface.cc",
1105       "tools/flip_server/spdy_interface.h",
1106       "tools/flip_server/spdy_ssl.cc",
1107       "tools/flip_server/spdy_ssl.h",
1108       "tools/flip_server/spdy_util.cc",
1109       "tools/flip_server/spdy_util.h",
1110       "tools/flip_server/streamer_interface.cc",
1111       "tools/flip_server/streamer_interface.h",
1112     ]
1113     deps = [
1114       ":balsa",
1115       ":epoll_server",
1116       ":net",
1117       "//base",
1118       "//third_party/boringssl",
1119     ]
1120   }
1121
1122   executable("flip_in_mem_edsm_server_unittests") {
1123     testonly = true
1124     sources = [
1125       "tools/flip_server/flip_test_utils.cc",
1126       "tools/flip_server/flip_test_utils.h",
1127       "tools/flip_server/http_interface_test.cc",
1128       "tools/flip_server/mem_cache_test.cc",
1129       "tools/flip_server/run_all_tests.cc",
1130       "tools/flip_server/spdy_interface_test.cc",
1131     ]
1132     deps = [
1133       ":balsa",
1134       ":flip_in_mem_edsm_server_base",
1135       ":net",
1136       ":test_support",
1137       "//testing/gtest",
1138       "//testing/gmock",
1139       "//third_party/boringssl",
1140     ]
1141   }
1142
1143   executable("flip_in_mem_edsm_server") {
1144     testonly = true
1145     sources = [
1146       "tools/flip_server/flip_in_mem_edsm_server.cc",
1147     ]
1148     deps = [
1149       ":balsa",
1150       ":flip_in_mem_edsm_server_base",
1151       ":net",
1152       "//base",
1153     ]
1154   }
1155
1156   source_set("epoll_quic_tools") {
1157     sources = [
1158       "tools/quic/quic_client.cc",
1159       "tools/quic/quic_client.h",
1160       "tools/quic/quic_default_packet_writer.cc",
1161       "tools/quic/quic_default_packet_writer.h",
1162       "tools/quic/quic_epoll_clock.cc",
1163       "tools/quic/quic_epoll_clock.h",
1164       "tools/quic/quic_epoll_connection_helper.cc",
1165       "tools/quic/quic_epoll_connection_helper.h",
1166       "tools/quic/quic_packet_reader.cc",
1167       "tools/quic/quic_packet_reader.h",
1168       "tools/quic/quic_packet_writer_wrapper.cc",
1169       "tools/quic/quic_packet_writer_wrapper.h",
1170       "tools/quic/quic_server.cc",
1171       "tools/quic/quic_server.h",
1172       "tools/quic/quic_socket_utils.cc",
1173       "tools/quic/quic_socket_utils.h",
1174     ]
1175     deps = [
1176       ":balsa",
1177       ":epoll_server",
1178       ":net",
1179       "//base",
1180       "//base/third_party/dynamic_annotations",
1181       "//crypto",
1182       "//third_party/boringssl",
1183       "//url",
1184     ]
1185   }
1186
1187   executable("epoll_quic_client") {
1188     sources = [
1189       "tools/quic/quic_client_bin.cc",
1190     ]
1191     deps = [
1192       ":balsa",
1193       ":epoll_server",
1194       ":epoll_quic_tools",
1195       ":net",
1196       ":simple_quic_tools",
1197       "//base",
1198       "//third_party/boringssl",
1199     ]
1200   }
1201
1202   executable("epoll_quic_server") {
1203     sources = [
1204       "tools/quic/quic_server_bin.cc",
1205     ]
1206     deps = [
1207       ":balsa",
1208       ":epoll_server",
1209       ":epoll_quic_tools",
1210       ":net",
1211       ":simple_quic_tools",
1212       "//base",
1213       "//third_party/boringssl",
1214     ]
1215   }
1216 }
1217
1218 if (is_android) {
1219   generate_jni("net_jni_headers") {
1220     sources = [
1221       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1222       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1223       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1224       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1225       "android/java/src/org/chromium/net/GURLUtils.java",
1226       "android/java/src/org/chromium/net/HttpNegotiateAuthenticator.java",
1227       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1228       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1229       "android/java/src/org/chromium/net/X509Util.java",
1230     ]
1231     jni_package = "net"
1232   }
1233   generate_jni("net_test_jni_headers") {
1234     sources = [
1235       "android/javatests/src/org/chromium/net/AndroidKeyStoreTestUtil.java",
1236       "test/android/javatests/src/org/chromium/net/test/DummySpnegoAuthenticator.java",
1237     ]
1238     jni_package = "net/test"
1239   }
1240 }
1241
1242 if (is_android || is_linux) {
1243   executable("disk_cache_memory_test") {
1244     testonly = true
1245     sources = [
1246       "tools/disk_cache_memory_test/disk_cache_memory_test.cc",
1247     ]
1248     deps = [
1249       ":net",
1250       "//base",
1251     ]
1252   }
1253 }
1254
1255 source_set("simple_quic_tools") {
1256   sources = [
1257     "tools/quic/quic_client_session.cc",
1258     "tools/quic/quic_client_session.h",
1259     "tools/quic/quic_dispatcher.cc",
1260     "tools/quic/quic_dispatcher.h",
1261     "tools/quic/quic_in_memory_cache.cc",
1262     "tools/quic/quic_in_memory_cache.h",
1263     "tools/quic/quic_per_connection_packet_writer.cc",
1264     "tools/quic/quic_per_connection_packet_writer.h",
1265     "tools/quic/quic_server_session.cc",
1266     "tools/quic/quic_server_session.h",
1267     "tools/quic/quic_simple_client.cc",
1268     "tools/quic/quic_simple_client.h",
1269     "tools/quic/quic_simple_per_connection_packet_writer.cc",
1270     "tools/quic/quic_simple_per_connection_packet_writer.h",
1271     "tools/quic/quic_simple_server.cc",
1272     "tools/quic/quic_simple_server.h",
1273     "tools/quic/quic_simple_server_packet_writer.cc",
1274     "tools/quic/quic_simple_server_packet_writer.h",
1275     "tools/quic/quic_spdy_client_stream.cc",
1276     "tools/quic/quic_spdy_client_stream.h",
1277     "tools/quic/quic_spdy_server_stream.cc",
1278     "tools/quic/quic_spdy_server_stream.h",
1279     "tools/quic/quic_time_wait_list_manager.cc",
1280     "tools/quic/quic_time_wait_list_manager.h",
1281     "tools/quic/synchronous_host_resolver.cc",
1282     "tools/quic/synchronous_host_resolver.h",
1283   ]
1284   deps = [
1285     ":net",
1286     "//base",
1287     "//base/third_party/dynamic_annotations",
1288     "//url",
1289   ]
1290 }
1291
1292 if (!is_ios) {
1293   executable("quic_client") {
1294     sources = [
1295       "tools/quic/quic_simple_client_bin.cc",
1296     ]
1297     deps = [
1298       ":net",
1299       ":simple_quic_tools",
1300       "//base",
1301       "//url",
1302     ]
1303   }
1304   executable("quic_server") {
1305     sources = [
1306       "tools/quic/quic_simple_server_bin.cc",
1307     ]
1308     deps = [
1309       ":net",
1310       ":simple_quic_tools",
1311       "//base",
1312       "//third_party/boringssl",
1313       "//third_party/protobuf:protobuf_lite",
1314     ]
1315   }
1316 }
1317
1318 # TODO(GYP): Delete this after we've converted everything to GN.
1319 # The _run targets exist only for compatibility w/ GYP.
1320 group("net_unittests_run") {
1321   testonly = true
1322   deps = [
1323     ":net_unittests",
1324   ]
1325 }
1326
1327 test("net_unittests") {
1328   sources = gypi_values.net_test_sources
1329
1330   if (is_ios) {
1331     sources -= [
1332       "websockets/websocket_stream_cookie_test.cc",
1333       "websockets/websocket_stream_create_test_base.cc",
1334       "websockets/websocket_stream_create_test_base.h",
1335     ]
1336   }
1337
1338   configs += [
1339     "//build/config:precompiled_headers",
1340
1341     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1342     "//build/config/compiler:no_size_t_to_int_warning",
1343   ]
1344   defines = []
1345
1346   deps = [
1347     ":balsa",
1348     ":extras",
1349     ":http_server",
1350     ":net",
1351     ":simple_quic_tools",
1352     ":test_support",
1353     "//base",
1354     "//base:i18n",
1355     "//base:prefs_test_support",
1356     "//base/allocator",
1357     "//base/third_party/dynamic_annotations",
1358     "//crypto",
1359     "//crypto:platform",
1360     "//crypto:test_support",
1361     "//gin",
1362     "//net/base/registry_controlled_domains",
1363     "//sql",
1364     "//testing/gmock",
1365     "//testing/gtest",
1366     "//third_party/zlib",
1367     "//url",
1368   ]
1369
1370   data = [
1371     "data/",
1372   ]
1373
1374   if (is_linux || is_mac || is_win) {
1375     deps += [
1376       "//third_party/pyftpdlib/",
1377       "//third_party/pywebsocket/",
1378       "//third_party/tlslite/",
1379     ]
1380     data_deps = [
1381       "//third_party/pyftpdlib/",
1382       "//third_party/pywebsocket/",
1383       "//third_party/tlslite/",
1384     ]
1385     data += [
1386       "tools/testserver/",
1387       "//third_party/pyftpdlib/",
1388       "//third_party/pywebsocket/",
1389       "//third_party/tlslite/",
1390       "$root_out_dir/pyproto/google/",
1391     ]
1392   }
1393
1394   if (is_desktop_linux) {
1395     deps += [ ":epoll_quic_tools" ]
1396   }
1397   if (is_linux) {
1398     sources += gypi_values.net_linux_test_sources
1399     deps += [
1400       ":epoll_quic_tools",
1401       ":epoll_server",
1402       ":flip_in_mem_edsm_server_base",
1403     ]
1404   }
1405
1406   if (is_mac || is_ios) {
1407     sources += gypi_values.net_base_test_mac_ios_sources
1408   }
1409
1410   if (is_chromeos) {
1411     sources -= [ "proxy/proxy_config_service_linux_unittest.cc" ]
1412   }
1413
1414   if (v8_use_external_startup_data) {
1415     deps += [ "//gin" ]
1416   }
1417
1418   if (!use_nss_certs) {
1419     sources -= [
1420       "cert/nss_cert_database_unittest.cc",
1421       "ssl/client_cert_store_nss_unittest.cc",
1422     ]
1423     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1424       sources -= [
1425         "cert/nss_cert_database_chromeos_unittest.cc",
1426         "cert/nss_profile_filter_chromeos_unittest.cc",
1427         "ssl/client_cert_store_chromeos_unittest.cc",
1428       ]
1429     }
1430   }
1431
1432   if (use_openssl) {
1433     # When building for OpenSSL, we need to exclude NSS specific tests
1434     # or functionality not supported by OpenSSL yet.
1435     # TODO(bulach): Add equivalent tests when the underlying
1436     #               functionality is ported to OpenSSL.
1437     sources -= [ "quic/test_tools/crypto_test_utils_nss.cc" ]
1438   } else {
1439     sources -= [
1440       "cert/x509_util_openssl_unittest.cc",
1441       "quic/test_tools/crypto_test_utils_openssl.cc",
1442       "socket/ssl_client_socket_openssl_unittest.cc",
1443       "ssl/ssl_client_session_cache_openssl_unittest.cc",
1444     ]
1445   }
1446
1447   if (use_kerberos) {
1448     defines += [ "USE_KERBEROS" ]
1449   }
1450
1451   # These are excluded on Android, because the actual Kerberos support, which
1452   # these test, is in a separate app on Android.
1453   if (!use_kerberos || is_android) {
1454     sources -= [
1455       "http/http_auth_gssapi_posix_unittest.cc",
1456       "http/mock_gssapi_library_posix.cc",
1457       "http/mock_gssapi_library_posix.h",
1458     ]
1459   }
1460   if (!use_kerberos) {
1461     sources -= [ "http/http_auth_handler_negotiate_unittest.cc" ]
1462   }
1463
1464   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1465     # Only include this test when on Posix and using NSS for
1466     # cert verification or on iOS (which also uses NSS for certs).
1467     sources -= [ "cert_net/nss_ocsp_unittest.cc" ]
1468   }
1469
1470   if (!use_openssl_certs) {
1471     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1472   }
1473
1474   if (!enable_websockets) {
1475     sources -= [
1476       "server/http_connection_unittest.cc",
1477       "server/http_server_response_info_unittest.cc",
1478       "server/http_server_unittest.cc",
1479       "server/web_socket_encoder_unittest.cc",
1480       "websockets/websocket_basic_stream_test.cc",
1481       "websockets/websocket_channel_test.cc",
1482       "websockets/websocket_deflate_predictor_impl_test.cc",
1483       "websockets/websocket_deflate_stream_test.cc",
1484       "websockets/websocket_deflater_test.cc",
1485       "websockets/websocket_end_to_end_test.cc",
1486       "websockets/websocket_errors_test.cc",
1487       "websockets/websocket_extension_parser_test.cc",
1488       "websockets/websocket_frame_parser_test.cc",
1489       "websockets/websocket_frame_test.cc",
1490       "websockets/websocket_handshake_challenge_test.cc",
1491       "websockets/websocket_handshake_stream_create_helper_test.cc",
1492       "websockets/websocket_inflater_test.cc",
1493       "websockets/websocket_stream_test.cc",
1494       "websockets/websocket_test_util.cc",
1495       "websockets/websocket_test_util.h",
1496     ]
1497     deps -= [ ":http_server" ]
1498   }
1499
1500   if (disable_file_support) {
1501     sources -= [
1502       "base/directory_lister_unittest.cc",
1503       "url_request/url_request_file_job_unittest.cc",
1504     ]
1505   }
1506
1507   if (disable_ftp_support) {
1508     sources -= [
1509       "ftp/ftp_auth_cache_unittest.cc",
1510       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1511       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1512       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1513       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1514       "ftp/ftp_directory_listing_parser_unittest.cc",
1515       "ftp/ftp_directory_listing_parser_unittest.h",
1516       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1517       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1518       "ftp/ftp_network_transaction_unittest.cc",
1519       "ftp/ftp_util_unittest.cc",
1520       "url_request/url_request_ftp_job_unittest.cc",
1521     ]
1522   }
1523
1524   if (!enable_built_in_dns) {
1525     sources -= [
1526       "dns/address_sorter_posix_unittest.cc",
1527       "dns/address_sorter_unittest.cc",
1528     ]
1529   }
1530
1531   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1532   # net_unittest's dependency on v8 when using icu alternatives instead of
1533   # setting use_v8_in_net to 0.
1534   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1535     deps += [ ":net_with_v8" ]
1536   } else {
1537     sources -= [
1538       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1539       "proxy/proxy_resolver_v8_tracing_wrapper_unittest.cc",
1540       "proxy/proxy_resolver_v8_unittest.cc",
1541     ]
1542   }
1543
1544   if (use_v8_in_net && !is_android) {
1545     deps += [
1546       ":net_browser_services",
1547       ":net_utility_services",
1548       "//mojo/environment:chromium",
1549       "//third_party/mojo/src/mojo/edk/system",
1550     ]
1551   } else {
1552     sources -= [
1553       "dns/host_resolver_mojo_unittest.cc",
1554       "dns/mojo_host_resolver_impl_unittest.cc",
1555       "proxy/mojo_proxy_resolver_factory_impl_unittest.cc",
1556       "proxy/mojo_proxy_resolver_impl_unittest.cc",
1557       "proxy/mojo_proxy_resolver_v8_tracing_bindings_unittest.cc",
1558       "proxy/proxy_resolver_factory_mojo_unittest.cc",
1559       "proxy/proxy_service_mojo_unittest.cc",
1560     ]
1561   }
1562
1563   if (!enable_mdns) {
1564     sources -= [
1565       "dns/mdns_cache_unittest.cc",
1566       "dns/mdns_client_unittest.cc",
1567       "dns/record_parsed_unittest.cc",
1568       "dns/record_rdata_unittest.cc",
1569     ]
1570   }
1571
1572   if (is_ios) {
1573     # TODO(GYP)
1574     #  'actions': [
1575     #    {
1576     #      'action_name': 'copy_test_data',
1577     #      'variables': {
1578     #        'test_data_files': [
1579     #          'data/ssl/certificates/',
1580     #          'data/test.html',
1581     #          'data/url_request_unittest/',
1582     #          'data/verify_name_match_unittest/names/',
1583     #        ],
1584     #        'test_data_prefix': 'net',
1585     #      },
1586     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1587     #    },
1588     #  ],
1589     sources -= [
1590       # TODO(droger): The following tests are disabled because the
1591       # implementation is missing or incomplete.
1592       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1593       "base/keygen_handler_unittest.cc",
1594       "disk_cache/backend_unittest.cc",
1595       "disk_cache/blockfile/block_files_unittest.cc",
1596
1597       # Need to read input data files.
1598       "filter/gzip_filter_unittest.cc",
1599       "socket/ssl_server_socket_unittest.cc",
1600       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1601
1602       # Need TestServer.
1603       "cert_net/cert_net_fetcher_impl_unittest.cc",
1604       "proxy/proxy_script_fetcher_impl_unittest.cc",
1605       "socket/ssl_client_socket_unittest.cc",
1606       "url_request/url_fetcher_impl_unittest.cc",
1607       "url_request/url_request_context_builder_unittest.cc",
1608
1609       # Needs GetAppOutput().
1610       "test/python_utils_unittest.cc",
1611
1612       # The following tests are disabled because they don't apply to
1613       # iOS.
1614       # OS is not "linux" or "freebsd" or "openbsd".
1615       "socket/unix_domain_client_socket_posix_unittest.cc",
1616       "socket/unix_domain_server_socket_posix_unittest.cc",
1617
1618       # See bug http://crbug.com/344533.
1619       "disk_cache/blockfile/index_table_v3_unittest.cc",
1620     ]
1621   }
1622
1623   if (is_android) {
1624     sources -= [
1625       # See bug http://crbug.com/344533.
1626       "disk_cache/blockfile/index_table_v3_unittest.cc",
1627       "dns/dns_config_service_posix_unittest.cc",
1628     ]
1629     deps += [
1630       ":net_test_jni_headers",
1631
1632       # TODO(mmenke):  This depends on test_support_base, which depends on
1633       #                icu.  Figure out a way to remove that dependency.
1634       "//testing/android/native_test:native_test_native_code",
1635     ]
1636     set_sources_assignment_filter([])
1637     sources += [ "base/address_tracker_linux_unittest.cc" ]
1638     set_sources_assignment_filter(sources_assignment_filter)
1639     isolate_file = "net_unittests.isolate"
1640   }
1641
1642   if (use_icu_alternatives_on_android) {
1643     sources -= [
1644       "base/filename_util_unittest.cc",
1645       "base/net_util_icu_unittest.cc",
1646     ]
1647     deps -= [ "//base:i18n" ]
1648   }
1649
1650   # Symbols for crashes when running tests on swarming.
1651   if (symbol_level > 0) {
1652     if (is_win) {
1653       data += [ "$root_out_dir/net_unittests.exe.pdb" ]
1654     } else if (is_mac) {
1655       data += [ "$root_out_dir/net_unittests.dSYM/" ]
1656     }
1657   }
1658 }
1659
1660 # !is_android && !is_win && !is_mac
1661
1662 executable("net_perftests") {
1663   testonly = true
1664   sources = [
1665     "base/mime_sniffer_perftest.cc",
1666     "cookies/cookie_monster_perftest.cc",
1667     "disk_cache/blockfile/disk_cache_perftest.cc",
1668     "extras/sqlite/sqlite_persistent_cookie_store_perftest.cc",
1669     "proxy/proxy_resolver_perftest.cc",
1670     "udp/udp_socket_perftest.cc",
1671   ]
1672
1673   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
1674   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
1675   deps = [
1676     ":extras",
1677     ":net",
1678     ":test_support",
1679     "//base",
1680     "//base:i18n",
1681     "//base/test:test_support_perf",
1682     "//testing/gtest",
1683     "//url",
1684   ]
1685
1686   if (enable_websockets) {
1687     sources += [ "websockets/websocket_frame_perftest.cc" ]
1688   }
1689
1690   if (use_v8_in_net) {
1691     deps += [ ":net_with_v8" ]
1692   } else {
1693     sources -= [ "proxy/proxy_resolver_perftest.cc" ]
1694   }
1695 }