mandoline/app/android/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(is_android)
   6
   7 import("//build/config/android/config.gni")
   8 import("//build/config/android/rules.gni")
   9 import("//mojo/generate_mojo_shell_assets_list.gni")
  10
  11 mandoline_assets_dir = "$root_build_dir/mandoline_assets"
  12
  13 group("android") {
  14   deps = [
  15     ":mandoline_apk",
  16   ]
  17 }
  18
  19 executable("mandoline_runner") {
  20   deps = [
  21     ":jni_headers",
  22     "//base",
  23     "//build/config/sanitizers:deps",
  24     "//mandoline/ui/desktop_ui/public/interfaces",
  25     "//mojo/common",
  26     "//mojo/environment:chromium",
  27     "//mojo/runner:lib",
  28     "//mojo/runner:mojo_runner_lib",
  29   ]
  30
  31   sources = [
  32     "../core_services_initialization.cc",
  33     "mandoline_activity.cc",
  34     "mandoline_context_init.cc",
  35   ]
  36
  37   # On android, the executable is also the native library used by the apk.
  38   # It means dynamic symbols must be preserved and exported.
  39   ldflags = [ "-Wl,--export-dynamic" ]
  40 }
  41
  42 copy("copy_mandoline_runner") {
  43   deps = [
  44     ":mandoline_runner",
  45   ]
  46   sources = [
  47     "$root_out_dir/mandoline_runner",
  48   ]
  49   outputs = [
  50     "$root_shlib_dir/${shlib_prefix}mandoline_runner$shlib_extension",
  51   ]
  52 }
  53
  54 copy_ex("copy_mandoline_assets") {
  55   clear_dir = true
  56   dest = mandoline_assets_dir
  57   deps = [
  58     "//components/devtools_service",
  59     "//components/html_viewer",
  60     "//components/resource_provider",
  61     "//mandoline/services/core_services",
  62     "//mojo/runner:bootstrap",
  63     "//mojo/runner:bootstrap_java",
  64     "//mojo/services/network",
  65   ]
  66   sources = [
  67     "$root_out_dir/obj/mojo/runner/bootstrap_java.dex.jar",
  68     "$root_shlib_dir/${shlib_prefix}bootstrap$shlib_extension",
  69   ]
  70
  71   # Directories can't be specified as sources so pass manually to the script.
  72   args = [
  73     "--files=" + rebase_path("$root_out_dir/core_services", root_build_dir),
  74     "--files=" + rebase_path("$root_out_dir/network_service", root_build_dir),
  75     "--files=" + rebase_path("$root_out_dir/resource_provider", root_build_dir),
  76     "--files=" + rebase_path("$root_out_dir/devtools_service", root_build_dir),
  77     "--files=" + rebase_path("$root_out_dir/html_viewer", root_build_dir),
  78   ]
  79
  80   if (use_aura) {
  81     deps += [ "//mandoline/ui" ]
  82
  83     args += [
  84       "--files=" + rebase_path("$root_out_dir/omnibox", root_build_dir),
  85       "--files=" + rebase_path("$root_out_dir/phone_ui", root_build_dir),
  86     ]
  87   }
  88 }
  89
  90 generate_mojo_shell_assets_list("build_mandoline_assets") {
  91   deps = [
  92     ":copy_mandoline_assets",
  93   ]
  94   dir = mandoline_assets_dir
  95 }
  96
  97 android_library("java") {
  98   java_files = [ "apk/src/org/chromium/mandoline/MandolineActivity.java" ]
  99
 100   deps = [
 101     "//mojo/runner:java",
 102     "//base:base_java",
 103   ]
 104 }
 105
 106 generate_jni("jni_headers") {
 107   sources = [
 108     "apk/src/org/chromium/mandoline/MandolineActivity.java",
 109   ]
 110   jni_package = "mandoline"
 111 }
 112
 113 android_resources("mandoline_apk_resources") {
 114   custom_package = "org.chromium.mandoline"
 115   resource_dirs = [ "apk/res" ]
 116 }
 117
 118 android_apk("mandoline_apk") {
 119   apk_name = "Mandoline"
 120
 121   android_manifest = "apk/AndroidManifest.xml"
 122
 123   native_libs = [ "${shlib_prefix}mandoline_runner$shlib_extension" ]
 124
 125   asset_location = mandoline_assets_dir
 126
 127   deps = [
 128     ":build_mandoline_assets",
 129     ":copy_mandoline_runner",
 130     ":java",
 131     ":mandoline_apk_resources",
 132     "//mojo/runner:java",
 133     "//mojo/runner:resources",
 134     "//base:base_java",
 135     "//ui/platform_window/android:platform_window_java",
 136     google_play_services_resources,
 137   ]
 138 }