build/config/sysroot.gni

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This header file defines the "sysroot" variable which is the absolute path
   6 # of the sysroot. If no sysroot applies, the variable will be an empty string.
   7
   8 import("//build/config/chrome_build.gni")
   9
  10 declare_args() {
  11   # The absolute path of the sysroot that is applied when compiling using
  12   # the target toolchain.
  13   target_sysroot = ""
  14 }
  15
  16 if (current_toolchain == default_toolchain && target_sysroot != "") {
  17   sysroot = target_sysroot
  18 } else if (is_android) {
  19   import("//build/config/android/config.gni")
  20   if (current_cpu == "x86") {
  21     sysroot = rebase_path("$android_ndk_root/$x86_android_sysroot_subdir")
  22   } else if (current_cpu == "arm") {
  23     sysroot = rebase_path("$android_ndk_root/$arm_android_sysroot_subdir")
  24   } else if (current_cpu == "mipsel") {
  25     sysroot = rebase_path("$android_ndk_root/$mips_android_sysroot_subdir")
  26   } else if (current_cpu == "x64") {
  27     sysroot = rebase_path("$android_ndk_root/$x86_64_android_sysroot_subdir")
  28   } else if (current_cpu == "arm64") {
  29     sysroot = rebase_path("$android_ndk_root/$arm64_android_sysroot_subdir")
  30   } else if (current_cpu == "mips64") {
  31     sysroot = rebase_path("$android_ndk_root/$mips64_android_sysroot_subdir")
  32   } else {
  33     sysroot = ""
  34   }
  35 } else if (is_linux && is_chrome_branded && is_official_build && !is_chromeos) {
  36   # For official builds, use the sysroot checked into the internal source repo
  37   # so that the builds work on older versions of Linux.
  38   if (current_cpu == "x64") {
  39     sysroot =
  40         rebase_path("//chrome/installer/linux/debian_wheezy_amd64-sysroot")
  41   } else if (current_cpu == "x86") {
  42     sysroot = rebase_path("//chrome/installer/linux/debian_wheezy_i386-sysroot")
  43   } else {
  44     # Any other builds don't use a sysroot.
  45     sysroot = ""
  46   }
  47 } else if (is_linux && !is_chromeos) {
  48   if (current_cpu == "mipsel") {
  49     sysroot = rebase_path("//mipsel-sysroot/sysroot")
  50   } else {
  51     sysroot = ""
  52   }
  53 } else if (is_mac) {
  54   import("//build/config/mac/mac_sdk.gni")
  55
  56   sysroot = mac_sdk_path
  57 } else if (is_ios) {
  58   import("//build/config/ios/ios_sdk.gni")
  59   sysroot = ios_sdk_path
  60 } else {
  61   sysroot = ""
  62 }