extensions/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//extensions/extensions.gni")
   8
   9 # GYP version: extensions/extensions.gyp:extensions_browser
  10 source_set("browser") {
  11   sources = []
  12
  13   deps = [
  14     "//components/keyed_service/content",
  15     "//components/keyed_service/core",
  16     "//components/pref_registry",
  17     "//components/sessions:sessions_content",
  18     "//components/ui/zoom:ui_zoom",
  19     "//components/web_cache/browser",
  20     "//components/web_modal",
  21     "//content/public/browser",
  22     "//crypto:platform",
  23     "//extensions/common",
  24     "//extensions/common/api",
  25     "//extensions/common/api:api_registration",
  26     "//extensions/strings",
  27     "//google_apis",
  28     "//skia",
  29     "//third_party/leveldatabase",
  30     "//third_party/re2",
  31   ]
  32
  33   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  34   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  35
  36   if (enable_extensions) {
  37     # Includes all API implementations and the ExtensionsApiClient
  38     # interface. Moving an API from src/chrome to src/extensions implies
  39     # it can be cleanly disabled with enable_extensions=false.
  40     # TODO: Eventually the entire extensions module should not be built
  41     # when enable_extensions=false.
  42     sources = rebase_path(extensions_gypi_values.extensions_browser_sources,
  43                           ".",
  44                           "//extensions")
  45
  46     deps += [
  47       "//components/browsing_data",
  48       "//components/onc",
  49       "//components/storage_monitor",
  50       "//components/update_client",
  51       "//components/variations",
  52       "//crypto:platform",
  53       "//device/bluetooth",
  54       "//device/core",
  55       "//device/hid",
  56       "//device/serial",
  57       "//device/usb",
  58       "//extensions/common/api/cast_channel:cast_channel_proto",
  59     ]
  60
  61     if (is_chromeos) {
  62       deps += [ "//chromeos" ]
  63     }
  64
  65     if (is_chromeos) {
  66       chromeos_sources = rebase_path(
  67               extensions_gypi_values.extensions_browser_sources_chromeos,
  68               ".",
  69               "//extensions")
  70       sources += chromeos_sources
  71     } else {
  72       nonchromeos_sources = rebase_path(
  73               extensions_gypi_values.extensions_browser_sources_nonchromeos,
  74               ".",
  75               "//extensions")
  76       sources += nonchromeos_sources
  77
  78       if (is_linux) {
  79         configs += [ "//build/config/linux:dbus" ]
  80         deps += [ "//dbus" ]
  81         linux_sources = rebase_path(
  82                 extensions_gypi_values.extensions_browser_sources_linux_nonchromeos,
  83                 ".",
  84                 "//extensions")
  85         sources += linux_sources
  86       } else {
  87         if (is_win || is_mac) {
  88           deps += [ "//components/wifi" ]
  89
  90           win_or_mac_sources = rebase_path(
  91                   extensions_gypi_values.extensions_browser_sources_win_or_mac,
  92                   ".",
  93                   "//extensions")
  94           sources += win_or_mac_sources
  95         }
  96       }
  97     }
  98   }
  99 }