remoting/base/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//remoting/remoting_srcs.gni")
   6
   7 source_set("base") {
   8   sources = rebase_path(remoting_srcs_gypi_values.remoting_base_sources,
   9                         ".",
  10                         "//remoting")
  11
  12   configs += [ "//build/config/compiler:wexit_time_destructors" ]
  13
  14   public_deps = [
  15     "//base",
  16     "//net",
  17     "//remoting/proto",
  18     "//third_party/protobuf:protobuf_lite",
  19   ]
  20   deps = [
  21     "//base/third_party/dynamic_annotations",
  22     "//third_party/libvpx",
  23     "//third_party/libyuv",
  24     "//third_party/webrtc/modules/desktop_capture:primitives",
  25   ]
  26   if (is_nacl) {
  27     sources -= [ "url_request_context_getter.cc" ]
  28   }
  29 }
  30
  31 source_set("breakpad") {
  32   sources = [
  33     "breakpad.h",
  34     "breakpad_linux.cc",
  35     "breakpad_mac.mm",
  36     "breakpad_win.cc",
  37   ]
  38
  39   configs += [ "//build/config/compiler:wexit_time_destructors" ]
  40
  41   deps = [
  42     "//base",
  43   ]
  44
  45   if (is_mac) {
  46     deps += [ "//breakpad" ]
  47   } else if (is_win) {
  48     deps += [ "//breakpad:breakpad_handler" ]
  49   }
  50 }
  51
  52 source_set("unit_tests") {
  53   testonly = true
  54
  55   sources = [
  56     "auto_thread_task_runner_unittest.cc",
  57     "auto_thread_unittest.cc",
  58     "breakpad_win_unittest.cc",
  59     "buffered_socket_writer_unittest.cc",
  60     "capabilities_unittest.cc",
  61     "compound_buffer_unittest.cc",
  62     "rate_counter_unittest.cc",
  63     "rsa_key_pair_unittest.cc",
  64     "run_all_unittests.cc",
  65     "running_average_unittest.cc",
  66     "test_rsa_key_pair.h",
  67     "typed_buffer_unittest.cc",
  68     "util_unittest.cc",
  69   ]
  70
  71   deps = [
  72     ":base",
  73     ":breakpad",
  74     "//base",
  75     "//net:test_support",
  76     "//testing/gmock",
  77     "//testing/gtest",
  78     "//third_party/libyuv",
  79     "//third_party/webrtc/modules/desktop_capture:primitives",
  80   ]
  81
  82   if (is_win || is_mac || is_chromeos) {
  83     deps += [ "//breakpad:client" ]
  84   }
  85
  86   if (is_win) {
  87     libs = [ "rpcrt4.lib" ]  # For UuidCreate in breakpad_win_unittest.cc.
  88   }
  89 }