content/renderer/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//content/renderer/renderer.gni")
   8 import("//media/media_options.gni")
   9
  10 source_set("renderer") {
  11   # Only the public target should depend on this. All other targets (even
  12   # internal content ones) should depend on the public one.
  13   visibility = [ "//content/public/renderer:renderer_sources" ]
  14
  15   sources = rebase_path(content_renderer_gypi_values.private_renderer_sources,
  16                         ".", "//content")
  17
  18   configs += [
  19     "//content:content_implementation",
  20   ]
  21
  22   deps = [
  23     # TODO(GYP) bug 376846 remove this. This should be inherited from //net but
  24     # those don't cross component boundaries.
  25     "//crypto:platform",
  26
  27     "//base/allocator",
  28     "//cc",
  29     "//cc/blink",
  30     "//content:resources",
  31     "//content/common:mojo_bindings",
  32     "//content/public/child:child_sources",
  33     "//content/public/common:common_sources",
  34     "//gin",
  35     "//gpu",
  36     "//gpu/command_buffer/client:gles2_interface",
  37     "//jingle:jingle_glue",
  38     "//media",
  39     "//media/blink",
  40     "//mojo/bindings/js",
  41     "//mojo/environment:chromium",
  42     "//mojo/public/js/bindings",
  43     "//mojo/public/interfaces/application",
  44     "//net",
  45     "//skia",
  46     "//storage/common",
  47     "//third_party/icu",
  48     "//third_party/libjingle",
  49     "//third_party/npapi",
  50     "//third_party/WebKit/public:blink",
  51     "//third_party/widevine/cdm:version_h",
  52     "//ui/accessibility",
  53     "//ui/base",
  54     "//ui/events:events_base",
  55     "//ui/events:dom4_keycode_converter",
  56     "//ui/gl",
  57     "//ui/native_theme",
  58     "//ui/surface",
  59     "//v8",
  60     "//webkit/common/gpu",
  61   ]
  62
  63   if (!enable_notifications) {
  64     sources -= [
  65       "notification_provider.cc",
  66       "active_notification_tracker.cc",
  67     ]
  68   }
  69
  70   if (is_mac) {
  71     sources -= [
  72       "webscrollbarbehavior_impl_gtkoraura.cc",
  73       "webscrollbarbehavior_impl_gtkoraura.h",
  74     ]
  75     sources += [
  76       "external_popup_menu.cc",
  77       "external_popup_menu.h",
  78     ]
  79   }
  80
  81   if (is_android) {
  82     sources -= [
  83       "media/audio_decoder.cc",
  84       "media/crypto/encrypted_media_player_support_impl.cc",
  85     ]
  86     sources += [
  87       "external_popup_menu.cc",
  88       "external_popup_menu.h",
  89     ]
  90
  91     # Add back the Linux file which Android shares.
  92     set_sources_assignment_filter([])
  93     sources += [
  94       "render_view_linux.cc",
  95     ]
  96
  97     deps += [
  98       "//third_party/android_tools:cpu_features",
  99       "//third_party/libphonenumber",
 100     ]
 101   } else {
 102     sources -= [
 103       "java/gin_java_bridge_dispatcher.cc",
 104       "java/gin_java_bridge_dispatcher.h",
 105       "java/gin_java_bridge_object.cc",
 106       "java/gin_java_bridge_object.h",
 107       "java/gin_java_bridge_value_converter.cc",
 108       "java/gin_java_bridge_value_converter.h",
 109     ]
 110   }
 111
 112   # TODO(jrg): remove the OS=="android" section?
 113   # http://crbug.com/113172
 114   # Understand better how media_stream_ is tied into Chromium.
 115   if (!enable_webrtc && is_android) {
 116     sources -= [
 117       "media/media_stream_audio_level_calculator.cc",
 118       "media/media_stream_audio_level_calculator.h",
 119       "media/media_stream_audio_renderer.cc",
 120       "media/media_stream_audio_renderer.h",
 121       "media/media_stream_center.h",
 122       "media/media_stream_constraints_util.cc",
 123       "media/media_stream_constraints_util.h",
 124       "media/media_stream_dispatcher.h",
 125       "media/media_stream_dispatcher_eventhandler.h",
 126       "media/media_stream_track.cc",
 127       "media/media_stream_track.h",
 128     ]
 129   }
 130
 131   if (enable_webrtc) {
 132     sources += rebase_path(
 133         content_renderer_gypi_values.private_renderer_webrtc_sources,
 134         ".", "//content")
 135     deps += [
 136       "//crypto",
 137       "//third_party/libyuv",
 138       "//third_party/webrtc/modules/audio_device",
 139       "//third_party/webrtc/modules/audio_processing",
 140       "//third_party/libjingle:libjingle_webrtc",
 141       "//third_party/libjingle:libpeerconnection",
 142     ]
 143   } else {
 144     sources += [
 145       "media/webrtc_logging_noop.cc",
 146       "media/webrtc_logging.h",
 147     ]
 148   }
 149
 150   if (enable_plugins) {
 151     sources += rebase_path(
 152         content_renderer_gypi_values.private_renderer_plugin_sources,
 153         ".", "//content")
 154     deps += [
 155       "//ppapi:ppapi_host",
 156       "//ppapi:ppapi_proxy",
 157       "//ppapi:ppapi_shared",
 158       "//third_party/libyuv",
 159     ]
 160   } else {
 161     # These files are in the WebRTC list, but also require plugins.
 162     if (enable_webrtc) {
 163       sources -= [
 164         "media/webrtc/video_destination_handler.cc",
 165         "media/webrtc/video_destination_handler.h",
 166       ]
 167     }
 168   }
 169
 170   if (enable_plugins && enable_webrtc) {
 171     sources += rebase_path(
 172         content_renderer_gypi_values.private_renderer_plugin_webrtc_sources,
 173         ".", "//content")
 174   }
 175
 176   if (!enable_pepper_cdms) {
 177     sources -= [
 178       "media/crypto/pepper_cdm_wrapper.h",
 179       "media/crypto/pepper_cdm_wrapper_impl.cc",
 180       "media/crypto/pepper_cdm_wrapper_impl.h",
 181       "media/crypto/ppapi_decryptor.cc",
 182       "media/crypto/ppapi_decryptor.h",
 183     ]
 184   }
 185
 186   if (printing_mode == 1) {
 187     deps += [ "//printing" ]
 188   }
 189
 190   if (enable_browser_cdms) {
 191     sources += [
 192       "media/crypto/proxy_media_keys.cc",
 193       "media/crypto/proxy_media_keys.h",
 194       "media/crypto/renderer_cdm_manager.cc",
 195       "media/crypto/renderer_cdm_manager.h",
 196     ]
 197   }
 198 }