chrome/browser/chromeos/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//components/nacl/nacl_defines.gni")
   8 import("//media/media_options.gni")
   9 import("//third_party/protobuf/proto_library.gni")
  10
  11 gypi_values = exec_script("//build/gypi_to_gn.py",
  12                           [ rebase_path("../../chrome_browser_chromeos.gypi") ],
  13                           "scope",
  14                           [ "chrome_browser_chromeos.gypi" ])
  15
  16 source_set("chromeos") {
  17   assert(enable_extensions, "ChromeOS Chrome has to be built with extensions")
  18
  19   configs += [
  20     "//build/config/compiler:wexit_time_destructors",
  21     "//build/config/linux:fontconfig",
  22   ]
  23
  24   public_deps = [
  25     "//ash/resources",
  26     "//ash/strings",
  27     "//chrome/app/resources:platform_locale_settings",
  28     "//chrome/app/theme:theme_resources",
  29     "//chrome:extra_resources",
  30     "//chrome:resources",
  31     "//chrome:strings",
  32     "//content/app/resources",
  33     "//ui/chromeos/resources",
  34     "//ui/chromeos/strings",
  35     "//ui/resources",
  36     "//ui/strings",
  37   ]
  38
  39   deps = [
  40     # TODO(tbarzic): Cleanup this list.
  41     "//ash",
  42     "//ash:ash_with_content",
  43     "//breakpad:client",
  44     "//components/login",
  45     "//components/session_manager/core",
  46     "//components/user_manager",
  47     "//components/wallpaper",
  48     "//chrome/browser/devtools",
  49     "//chrome/browser/extensions",
  50     "//chrome/browser/history:in_memory_url_index_cache_proto",
  51     "//chrome/browser/net:cert_logger_proto",
  52     "//chrome/browser/safe_browsing:chunk_proto",
  53     "//chrome/browser/safe_browsing:metadata_proto",
  54     "//chrome/browser/safe_browsing:report_proto",
  55     "//chrome/common",
  56     "//chrome/common/extensions/api",
  57     "//chrome/common/extensions/api:api_registration",
  58     "//chrome/common/net",
  59     "//chrome/installer/util",
  60     "//chromeos",
  61     "//chromeos/ime:gencode",
  62     "//chromeos:cryptohome_proto",
  63     "//chromeos:cryptohome_signkey_proto",
  64     "//chromeos:power_manager_proto",
  65     "//components/onc",
  66     "//components/ownership",
  67     "//components/pairing",
  68     "//components/policy",
  69
  70     # This depends directly on the variations target, rather than just
  71     # transitively via the common target because the proto sources need to
  72     # be generated before code in this target can start building.
  73     "//components/strings",
  74     "//components/variations",
  75     "//content/public/browser",
  76     "//content/public/common",
  77     "//crypto",
  78     "//dbus",
  79     "//device/bluetooth",
  80     "//device/hid",
  81     "//media",
  82     "//net",
  83     "//ppapi:ppapi_ipc",  # For PpapiMsg_LoadPlugin
  84
  85     # TODO: care about enable_basic_printing and enable_print_preview.
  86     "//printing",
  87     "//skia",
  88     "//storage/browser",
  89     "//storage/common",
  90     "//sync",
  91     "//third_party/adobe/flash:flapper_version_h",
  92     "//third_party/cacheinvalidation",
  93     "//third_party/expat",
  94     "//third_party/hunspell",
  95     "//third_party/icu",
  96     "//third_party/leveldatabase",
  97     "//third_party/libevent",
  98     "//third_party/libjingle",
  99     "//third_party/libusb",
 100     "//third_party/libxml",
 101     "//third_party/npapi",
 102     "//third_party/protobuf:protobuf_lite",
 103     "//third_party/protobuf:protoc($host_toolchain)",
 104     "//third_party/re2",
 105     "//third_party/zlib",
 106     "//ui/app_list",
 107     "//ui/aura",
 108     "//ui/base",
 109     "//ui/chromeos:ui_chromeos",
 110     "//ui/compositor",
 111     "//ui/display",
 112     "//ui/events/platform",
 113     "//ui/events:dom4_keycode_converter",
 114     "//ui/file_manager",
 115     "//ui/message_center",
 116     "//ui/surface",
 117     "//ui/views",
 118     "//ui/views/controls/webview",
 119     "//ui/web_dialogs",
 120     "//url",
 121     "//v8",
 122     ":attestation_proto",
 123     ":device_policy_proto",
 124     ":drive_proto",
 125   ]
 126
 127   defines = nacl_defines
 128
 129   sources = rebase_path(gypi_values.browser_chromeos_sources, ".", "//chrome") +
 130             rebase_path(gypi_values.browser_chromeos_extension_sources,
 131                         ".",
 132                         "//chrome")
 133   if (use_athena) {
 134     defines += [ "USE_ATHENA=1" ]
 135   } else {
 136     sources +=
 137         rebase_path(gypi_values.browser_chromeos_non_athena_sources,
 138                     ".",
 139                     "//chrome") +
 140         rebase_path(gypi_values.browser_chromeos_extension_non_athena_sources,
 141                     ".",
 142                     "//chrome")
 143   }
 144
 145   if (use_x11) {
 146     configs += [ "//build/config/linux:x11" ]
 147     deps += [ "//ui/events/devices" ]
 148     sources -= [ "system/input_device_settings_impl_ozone.cc" ]
 149   } else {
 150     assert(use_ozone, "Either use_x11 or use_ozone has to be specified.")
 151     deps += [ "//ui/ozone" ]
 152     sources -= [
 153       "device_uma.cc",
 154       "device_uma.h",
 155       "events/system_key_event_listener.cc",
 156       "events/system_key_event_listener.h",
 157       "events/xinput_hierarchy_changed_event_listener.cc",
 158       "events/xinput_hierarchy_changed_event_listener.h",
 159       "system/input_device_settings_impl_x11.cc",
 160     ]
 161   }
 162
 163   if (use_cras) {
 164     defines += [ "USE_CRAS" ]
 165   }
 166
 167   if (ui_compositor_image_transport) {
 168     deps += [ "//ui/gl" ]
 169   }
 170 }
 171
 172 proto_library("drive_proto") {
 173   sources = [
 174     "drive/drive.proto",
 175   ]
 176 }
 177
 178 proto_library("device_policy_proto") {
 179   sources = [
 180     "policy/proto/chrome_device_policy.proto",
 181     "policy/proto/install_attributes.proto",
 182   ]
 183 }
 184
 185 proto_library("attestation_proto") {
 186   sources = [
 187     "attestation/attestation_key_payload.proto",
 188     "attestation/attestation_signed_data.proto",
 189   ]
 190 }