ui/gfx/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 if (is_android) {
   9   import("//build/config/android/config.gni")
  10   import("//build/config/android/rules.gni")
  11 }
  12
  13 # Several targets want to include this header file, and some of them are
  14 # child dependencies of "gfx". Therefore, we separate it out here so multiple
  15 # targets can all have a dependency for header checking purposes without
  16 # creating circular dependencies.
  17 source_set("gfx_export") {
  18   sources = [
  19     "gfx_export.h",
  20   ]
  21 }
  22
  23 component("gfx") {
  24   sources = [
  25     "android/device_display_info.cc",
  26     "android/device_display_info.h",
  27     "android/gfx_jni_registrar.cc",
  28     "android/gfx_jni_registrar.h",
  29     "android/java_bitmap.cc",
  30     "android/java_bitmap.h",
  31     "android/shared_device_display_info.cc",
  32     "android/shared_device_display_info.h",
  33     "android/view_configuration.cc",
  34     "android/view_configuration.h",
  35     "animation/animation.cc",
  36     "animation/animation.h",
  37     "animation/animation_container.cc",
  38     "animation/animation_container.h",
  39     "animation/animation_container_element.h",
  40     "animation/animation_container_observer.h",
  41     "animation/animation_delegate.h",
  42     "animation/linear_animation.cc",
  43     "animation/linear_animation.h",
  44     "animation/multi_animation.cc",
  45     "animation/multi_animation.h",
  46     "animation/slide_animation.cc",
  47     "animation/slide_animation.h",
  48     "animation/throb_animation.cc",
  49     "animation/throb_animation.h",
  50     "animation/tween.cc",
  51     "animation/tween.h",
  52     "blit.cc",
  53     "blit.h",
  54     "break_list.h",
  55     "canvas.cc",
  56     "canvas.h",
  57     "canvas_notimplemented.cc",
  58     "canvas_paint_mac.h",
  59     "canvas_paint_mac.mm",
  60     "canvas_skia.cc",
  61     "canvas_skia_paint.h",
  62     "codec/jpeg_codec.cc",
  63     "codec/jpeg_codec.h",
  64     "codec/png_codec.cc",
  65     "codec/png_codec.h",
  66     "color_analysis.cc",
  67     "color_analysis.h",
  68     "color_profile.cc",
  69     "color_profile.h",
  70     "color_profile_mac.mm",
  71     "color_profile_win.cc",
  72     "color_utils.cc",
  73     "color_utils.h",
  74     "display.cc",
  75     "display.h",
  76     "display_change_notifier.cc",
  77     "display_change_notifier.h",
  78     "display_observer.cc",
  79     "display_observer.h",
  80     "favicon_size.cc",
  81     "favicon_size.h",
  82     "font.cc",
  83     "font.h",
  84     "font_fallback.h",
  85     "font_fallback_linux.cc",
  86     "font_fallback_mac.mm",
  87     "font_fallback_win.cc",
  88     "font_fallback_win.h",
  89     "font_list.cc",
  90     "font_list.h",
  91     "font_list_impl.cc",
  92     "font_list_impl.h",
  93     "font_render_params.cc",
  94     "font_render_params.h",
  95     "font_render_params_android.cc",
  96     "font_render_params_linux.cc",
  97     "font_render_params_mac.cc",
  98     "font_render_params_win.cc",
  99     "frame_time.h",
 100     "gdi_util.cc",
 101     "gdi_util.h",
 102     "gfx_paths.cc",
 103     "gfx_paths.h",
 104     "gpu_memory_buffer.cc",
 105     "gpu_memory_buffer.h",
 106     "hud_font.cc",
 107     "hud_font.h",
 108     "icon_util.cc",
 109     "icon_util.h",
 110     "image/canvas_image_source.cc",
 111     "image/canvas_image_source.h",
 112     "image/image.cc",
 113     "image/image.h",
 114     "image/image_family.cc",
 115     "image/image_family.h",
 116     "image/image_ios.mm",
 117     "image/image_mac.mm",
 118     "image/image_png_rep.cc",
 119     "image/image_png_rep.h",
 120     "image/image_skia.cc",
 121     "image/image_skia.h",
 122     "image/image_skia_operations.cc",
 123     "image/image_skia_operations.h",
 124     "image/image_skia_rep.cc",
 125     "image/image_skia_rep.h",
 126     "image/image_skia_source.h",
 127     "image/image_skia_util_ios.h",
 128     "image/image_skia_util_ios.mm",
 129     "image/image_skia_util_mac.h",
 130     "image/image_skia_util_mac.mm",
 131     "image/image_util.cc",
 132     "image/image_util.h",
 133     "image/image_util_ios.mm",
 134     "interpolated_transform.cc",
 135     "interpolated_transform.h",
 136     "linux_font_delegate.cc",
 137     "linux_font_delegate.h",
 138     "mac/coordinate_conversion.h",
 139     "mac/coordinate_conversion.mm",
 140     "mac/nswindow_frame_controls.h",
 141     "mac/nswindow_frame_controls.mm",
 142     "mac/scoped_ns_disable_screen_updates.h",
 143     "native_widget_types.h",
 144     "nine_image_painter.cc",
 145     "nine_image_painter.h",
 146     "paint_throbber.cc",
 147     "paint_throbber.h",
 148     "path.cc",
 149     "path.h",
 150     "path_aura.cc",
 151     "path_win.cc",
 152     "path_win.h",
 153     "path_x11.cc",
 154     "path_x11.h",
 155     "platform_font.h",
 156     "platform_font_android.cc",
 157     "platform_font_ios.h",
 158     "platform_font_ios.mm",
 159     "platform_font_linux.cc",
 160     "platform_font_linux.h",
 161     "platform_font_mac.h",
 162     "platform_font_mac.mm",
 163     "platform_font_win.cc",
 164     "platform_font_win.h",
 165     "range/range.cc",
 166     "range/range.h",
 167     "range/range_f.cc",
 168     "range/range_f.h",
 169     "range/range_mac.mm",
 170     "range/range_win.cc",
 171     "scoped_canvas.h",
 172     "scoped_cg_context_save_gstate_mac.h",
 173     "scoped_ns_graphics_context_save_gstate_mac.h",
 174     "scoped_ns_graphics_context_save_gstate_mac.mm",
 175     "scoped_ui_graphics_push_context_ios.h",
 176     "scoped_ui_graphics_push_context_ios.mm",
 177     "screen.cc",
 178     "screen.h",
 179     "screen_android.cc",
 180     "screen_aura.cc",
 181     "screen_ios.mm",
 182     "screen_mac.mm",
 183     "screen_win.cc",
 184     "screen_win.h",
 185     "scrollbar_size.cc",
 186     "scrollbar_size.h",
 187     "selection_model.cc",
 188     "selection_model.h",
 189     "sequential_id_generator.cc",
 190     "sequential_id_generator.h",
 191     "shadow_value.cc",
 192     "shadow_value.h",
 193     "skbitmap_operations.cc",
 194     "skbitmap_operations.h",
 195     "skia_util.cc",
 196     "skia_util.h",
 197     "switches.cc",
 198     "switches.h",
 199     "sys_color_change_listener.cc",
 200     "sys_color_change_listener.h",
 201     "text_constants.h",
 202     "text_elider.cc",
 203     "text_elider.h",
 204     "text_utils.cc",
 205     "text_utils.h",
 206     "text_utils_android.cc",
 207     "text_utils_ios.mm",
 208     "transform.cc",
 209     "transform.h",
 210     "transform_util.cc",
 211     "transform_util.h",
 212     "ui_gfx_exports.cc",
 213     "utf16_indexing.cc",
 214     "utf16_indexing.h",
 215     "vsync_provider.h",
 216     "win/direct_write.cc",
 217     "win/direct_write.h",
 218     "win/dpi.cc",
 219     "win/dpi.h",
 220     "win/hwnd_util.cc",
 221     "win/hwnd_util.h",
 222     "win/scoped_set_map_mode.h",
 223     "win/singleton_hwnd.cc",
 224     "win/singleton_hwnd.h",
 225     "win/singleton_hwnd_observer.cc",
 226     "win/singleton_hwnd_observer.h",
 227     "win/window_impl.cc",
 228     "win/window_impl.h",
 229   ]
 230
 231   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 232   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 233
 234   defines = [ "GFX_IMPLEMENTATION" ]
 235
 236   deps = [
 237     ":gfx_export",
 238     "//base",
 239     "//base:i18n",
 240     "//base:base_static",
 241     "//base/third_party/dynamic_annotations",
 242     "//skia",
 243     "//third_party/harfbuzz-ng",
 244     "//third_party/libpng",
 245     "//third_party/zlib",
 246     "//ui/gfx/geometry",
 247   ]
 248   public_deps = [
 249     "//base",
 250     "//skia",
 251     "//third_party/icu",
 252   ]
 253
 254   # Text rendering conditions (complicated so separated out).
 255   if (is_android || is_ios) {
 256     # We don't support RenderText on these platforms.
 257   } else {
 258     # Mac doesn't use RenderTextHarfBuzz by default yet.
 259     sources += [
 260       "harfbuzz_font_skia.cc",
 261       "harfbuzz_font_skia.h",
 262       "render_text.cc",
 263       "render_text.h",
 264       "render_text_harfbuzz.cc",
 265       "render_text_harfbuzz.h",
 266       "render_text_mac.cc",
 267       "render_text_mac.h",
 268       "text_utils_skia.cc",
 269     ]
 270   }
 271
 272   # iOS.
 273   if (is_ios) {
 274     sources -= [
 275       "codec/jpeg_codec.cc",
 276       "codec/jpeg_codec.h",
 277     ]
 278   } else {
 279     deps += [ "//third_party:jpeg" ]
 280   }
 281
 282   # Android.
 283   if (is_android) {
 284     sources -= [
 285       "animation/throb_animation.cc",
 286       "canvas_skia.cc",
 287       "selection_model.cc",
 288     ]
 289
 290     if (use_aura) {
 291       sources -= [ "screen_android.cc" ]
 292     } else {
 293       sources -= [ "path.cc" ]
 294     }
 295
 296     if (!is_debug) {
 297       configs -= [ "//build/config/compiler:optimize" ]
 298       configs += [ "//build/config/compiler:optimize_max" ]
 299     }
 300
 301     deps += [
 302       ":gfx_jni_headers",
 303       "//base:base_java",
 304     ]
 305     libs = [
 306       "android",
 307       "jnigraphics",
 308     ]
 309   } else {
 310     sources -= [ "canvas_notimplemented.cc" ]
 311   }
 312
 313   # Windows.
 314   if (is_win) {
 315     cflags = [ "/wd4324" ]  # Structure was padded due to __declspec(align()), which is
 316                             # uninteresting.
 317   } else {
 318     sources -= [
 319       "gdi_util.cc",
 320       "gdi_util.h",
 321       "icon_util.cc",
 322       "icon_util.h",
 323     ]
 324   }
 325
 326   # Linux.
 327   if (is_linux) {
 328     configs += [ "//build/config/linux:fontconfig" ]
 329   }
 330
 331   # Chrome OS
 332   if (is_chromeos) {
 333     # Robust JPEG decoding for the login screen.
 334     sources += [
 335       "chromeos/codec/jpeg_codec_robust_slow.cc",
 336       "chromeos/codec/jpeg_codec_robust_slow.h",
 337     ]
 338     deps += [ "//third_party/libjpeg" ]
 339   }
 340
 341   if (!use_aura) {
 342     sources -= [
 343       "path_aura.cc",
 344       "screen_aura.cc",
 345     ]
 346     if (!toolkit_views) {
 347       sources -= [
 348         "nine_image_painter.cc",
 349         "nine_image_painter.h",
 350       ]
 351     }
 352   }
 353
 354   if (use_x11) {
 355     deps += [ "//ui/gfx/x" ]
 356     configs += [ "//build/config/linux:x11" ]
 357   } else {
 358     sources -= [ "path_x11.cc" ]
 359   }
 360
 361   if (use_cairo) {
 362     configs += [ "//build/config/linux:pangocairo" ]
 363   }
 364 }
 365
 366 # Looking for gfx_geometry? It's //ui/gfx/geometry:geometry
 367
 368 source_set("test_support") {
 369   testonly = true
 370   sources = [
 371     "image/image_unittest_util.cc",
 372     "image/image_unittest_util.h",
 373     "image/image_unittest_util_ios.mm",
 374     "image/image_unittest_util_mac.mm",
 375     "test/fontconfig_util_linux.cc",
 376     "test/fontconfig_util_linux.h",
 377     "test/gfx_util.cc",
 378     "test/gfx_util.h",
 379     "test/ui_cocoa_test_helper.h",
 380     "test/ui_cocoa_test_helper.mm",
 381   ]
 382
 383   public_deps = [
 384     ":gfx",
 385   ]
 386
 387   deps = [
 388     "//base",
 389     "//base/test:test_support",
 390     "//skia",
 391     "//testing/gtest",
 392     "//ui/gfx/geometry",
 393   ]
 394
 395   if (is_ios) {
 396     # The cocoa files don't apply to iOS.
 397     sources -= [
 398       "test/ui_cocoa_test_helper.h",
 399       "test/ui_cocoa_test_helper.mm",
 400     ]
 401   }
 402   if (is_linux) {
 403     configs += [ "//build/config/linux:fontconfig" ]
 404   }
 405 }
 406
 407 test("gfx_unittests") {
 408   sources = [
 409     "font_render_params_linux_unittest.cc",
 410     "font_unittest.cc",
 411     "image/image_family_unittest.cc",
 412     "image/image_ios_unittest.mm",
 413     "image/image_skia_unittest.cc",
 414     "image/image_unittest.cc",
 415     "platform_font_linux_unittest.cc",
 416     "screen_unittest.cc",
 417     "test/run_all_unittests.cc",
 418     "text_elider_unittest.cc",
 419     "text_utils_unittest.cc",
 420   ]
 421
 422   if (!is_ios) {
 423     sources += [
 424       "animation/animation_container_unittest.cc",
 425       "animation/animation_unittest.cc",
 426       "animation/multi_animation_unittest.cc",
 427       "animation/slide_animation_unittest.cc",
 428       "animation/tween_unittest.cc",
 429       "blit_unittest.cc",
 430       "break_list_unittest.cc",
 431       "canvas_unittest.cc",
 432       "canvas_unittest_mac.mm",
 433       "codec/jpeg_codec_unittest.cc",
 434       "codec/png_codec_unittest.cc",
 435       "color_analysis_unittest.cc",
 436       "color_profile_mac_unittest.mm",
 437       "color_utils_unittest.cc",
 438       "display_change_notifier_unittest.cc",
 439       "display_unittest.cc",
 440       "font_fallback_mac_unittest.cc",
 441       "font_list_unittest.cc",
 442       "geometry/box_unittest.cc",
 443       "geometry/cubic_bezier_unittest.cc",
 444       "geometry/insets_unittest.cc",
 445       "geometry/matrix3_unittest.cc",
 446       "geometry/point3_unittest.cc",
 447       "geometry/point_unittest.cc",
 448       "geometry/quad_unittest.cc",
 449       "geometry/rect_unittest.cc",
 450       "geometry/safe_integer_conversions_unittest.cc",
 451       "geometry/scroll_offset_unittest.cc",
 452       "geometry/size_unittest.cc",
 453       "geometry/vector2d_unittest.cc",
 454       "geometry/vector3d_unittest.cc",
 455       "image/image_mac_unittest.mm",
 456       "image/image_util_unittest.cc",
 457       "mac/coordinate_conversion_unittest.mm",
 458       "nine_image_painter_unittest.cc",
 459       "platform_font_mac_unittest.mm",
 460       "range/range_mac_unittest.mm",
 461       "range/range_unittest.cc",
 462       "range/range_win_unittest.cc",
 463       "render_text_unittest.cc",
 464       "sequential_id_generator_unittest.cc",
 465       "shadow_value_unittest.cc",
 466       "skbitmap_operations_unittest.cc",
 467       "skrect_conversion_unittest.cc",
 468       "transform_util_unittest.cc",
 469       "utf16_indexing_unittest.cc",
 470     ]
 471   }
 472
 473   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 474   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 475
 476   deps = [
 477     ":gfx",
 478     ":test_support",
 479     "//base",
 480     "//base/test:test_support",
 481     "//skia",
 482     "//third_party/icu:icuuc",
 483     "//third_party/libpng",
 484     "//third_party/zlib",
 485     "//testing/gtest",
 486     "//ui/base",
 487     "//ui/gfx/geometry",
 488     "//ui/resources:ui_test_pak",
 489   ]
 490
 491   if (!is_mac && !is_ios) {
 492     sources += [
 493       "interpolated_transform_unittest.cc",
 494       "transform_unittest.cc",
 495     ]
 496   }
 497
 498   if (is_android) {
 499     sources -= [
 500       # Do not run display_change_notifier_unittest.cc on Android because it
 501       # does not compile display_observer.cc
 502       "display_change_notifier_unittest.cc",
 503     ]
 504   }
 505
 506   if (is_android || is_ios) {
 507     sources -= [ "render_text_unittest.cc" ]
 508   }
 509
 510   if (use_aura) {
 511     sources -= [ "screen_unittest.cc" ]
 512   } else {
 513     sources -= [ "nine_image_painter_unittest.cc" ]
 514   }
 515
 516   if (is_chromeos) {
 517     sources += [ "chromeos/codec/jpeg_codec_robust_slow_unittest.cc" ]
 518   }
 519
 520   if (is_win) {
 521     sources += [
 522       "color_profile_win_unittest.cc",
 523       "font_fallback_win_unittest.cc",
 524       "icon_util_unittest.cc",
 525       "icon_util_unittests.rc",
 526       "path_win_unittest.cc",
 527       "platform_font_win_unittest.cc",
 528     ]
 529
 530     ldflags = [
 531       "/DELAYLOAD:d2d1.dll",
 532       "/DELAYLOAD:d3d10_1.dll",
 533     ]
 534
 535     libs = [
 536       "d2d1.lib",
 537       "d3d10_1.lib",
 538       "imm32.lib",
 539       "oleacc.lib",
 540     ]
 541   }
 542 }
 543
 544 if (is_android) {
 545   generate_jni("gfx_jni_headers") {
 546     sources = [
 547       "../android/java/src/org/chromium/ui/gfx/BitmapHelper.java",
 548       "../android/java/src/org/chromium/ui/gfx/DeviceDisplayInfo.java",
 549       "../android/java/src/org/chromium/ui/gfx/ViewConfigurationHelper.java",
 550     ]
 551     jni_package = "gfx"
 552   }
 553 }