build/config/mac/mac_sdk.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6
   7 declare_args() {
   8   # Minimum supported version of the Mac SDK.
   9   mac_sdk_min = "10.10"
  10
  11   # Minimum supported version of OSX.
  12   mac_deployment_target = "10.6"
  13
  14   # Path to a specific version of the Mac SDK, not including a backslash at
  15   # the end. If empty, the path to the lowest version greater than or equal to
  16   # mac_sdk_min is used.
  17   mac_sdk_path = ""
  18 }
  19
  20 find_sdk_args = [ "--print_sdk_path" ]
  21 if (is_chrome_branded && is_official_build) {
  22   find_sdk_args += [
  23     "--verify",
  24     mac_sdk_min,
  25     "--sdk_path=" + mac_sdk_path,
  26   ]
  27 } else {
  28   find_sdk_args += [ mac_sdk_min ]
  29 }
  30
  31 # The tool will print the SDK path on the first line, and the version on the
  32 # second line.
  33 find_sdk_lines =
  34     exec_script("//build/mac/find_sdk.py", find_sdk_args, "list lines")
  35 mac_sdk_version = find_sdk_lines[1]
  36 if (mac_sdk_path == "") {
  37   # TODO(brettw) http://crbug.com/335325  when everybody moves to XCode 5 we
  38   # can remove the --print_sdk_path argument to find_sdk and instead just use
  39   # the following two lines to get the path. Although it looks longer here, it
  40   # saves forking a process in find_sdk.py so will be faster.
  41   #mac_sdk_root = "/Applications/Xcode.app/Contents/Developer/Platforms/MacOSX.platform/Developer/SDKs/MacOSX"
  42   #mac_sdk_path = mac_sdk_root + mac_sdk_version + ".sdk"
  43   mac_sdk_path = find_sdk_lines[0]
  44 }