third_party/brotli/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 config("brotli_warnings") {
   6   if (is_clang) {
   7     # IncrementalCopyFastPath in decode.c can be unused.
   8     # (The file looks very different upstream, this is probably no longer
   9     # needed after rolling brotli the next time.)
  10     cflags = [ "-Wno-unused-function" ]
  11   }
  12 }
  13
  14 source_set("brotli") {
  15   sources = [
  16     "dec/bit_reader.c",
  17     "dec/bit_reader.h",
  18     "dec/context.h",
  19     "dec/decode.c",
  20     "dec/decode.h",
  21     "dec/dictionary.h",
  22     "dec/huffman.c",
  23     "dec/huffman.h",
  24     "dec/prefix.h",
  25     "dec/safe_malloc.c",
  26     "dec/safe_malloc.h",
  27     "dec/state.c",
  28     "dec/state.h",
  29     "dec/streams.c",
  30     "dec/streams.h",
  31     "dec/transform.h",
  32     "dec/types.h",
  33   ]
  34
  35   configs -= [ "//build/config/compiler:chromium_code" ]
  36   configs += [
  37     "//build/config/compiler:no_chromium_code",
  38
  39     # Must be after no_chromium_code for warning flags to be ordered correctly.
  40     ":brotli_warnings",
  41   ]
  42
  43   # Since we are never debug brotli, freeze the optimizations to -O2.
  44   if (is_debug) {
  45     configs -= [ "//build/config/compiler:no_optimize" ]
  46   } else {
  47     configs -= [ "//build/config/compiler:optimize" ]
  48   }
  49   configs += [ "//build/config/compiler:optimize_max" ]
  50
  51   include_dirs = [ "dec" ]
  52 }