third_party/hunspell/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 config("hunspell_config") {
   6   defines = [
   7     "HUNSPELL_STATIC",
   8     "HUNSPELL_CHROME_CLIENT",
   9     "USE_HUNSPELL",
  10   ]
  11 }
  12
  13 config("hunspell_warnings") {
  14   if (is_clang) {
  15     cflags = [ "-Wno-unused-private-field" ]
  16   }
  17 }
  18
  19 source_set("hunspell") {
  20   sources = [
  21     "google/bdict.cc",
  22     "google/bdict.h",
  23     "google/bdict_reader.cc",
  24     "google/bdict_reader.h",
  25     "google/bdict_writer.cc",
  26     "google/bdict_writer.h",
  27     "src/hunspell/affentry.cxx",
  28     "src/hunspell/affentry.hxx",
  29     "src/hunspell/affixmgr.cxx",
  30     "src/hunspell/affixmgr.hxx",
  31     "src/hunspell/atypes.hxx",
  32     "src/hunspell/baseaffix.hxx",
  33     "src/hunspell/csutil.cxx",
  34     "src/hunspell/csutil.hxx",
  35     "src/hunspell/dictmgr.cxx",
  36     "src/hunspell/dictmgr.hxx",
  37     "src/hunspell/filemgr.cxx",
  38     "src/hunspell/filemgr.hxx",
  39     "src/hunspell/hashmgr.cxx",
  40     "src/hunspell/hashmgr.hxx",
  41     "src/hunspell/htypes.hxx",
  42     "src/hunspell/hunspell.cxx",
  43     "src/hunspell/hunspell.h",
  44     "src/hunspell/hunspell.hxx",
  45     "src/hunspell/hunzip.cxx",
  46     "src/hunspell/hunzip.hxx",
  47     "src/hunspell/langnum.hxx",
  48     "src/hunspell/phonet.cxx",
  49     "src/hunspell/phonet.hxx",
  50     "src/hunspell/replist.cxx",
  51     "src/hunspell/replist.hxx",
  52     "src/hunspell/suggestmgr.cxx",
  53     "src/hunspell/suggestmgr.hxx",
  54     "src/hunspell/utf_info.hxx",
  55     "src/hunspell/w_char.hxx",
  56     "src/parsers/textparser.cxx",
  57     "src/parsers/textparser.hxx",
  58   ]
  59
  60   configs -= [ "//build/config/compiler:chromium_code" ]
  61   configs += [
  62     "//build/config/compiler:no_chromium_code",
  63
  64     # Must be after no_chromium_code for warning flags to be ordered correctly.
  65     ":hunspell_warnings",
  66   ]
  67   public_configs = [ ":hunspell_config" ]
  68
  69   defines = [ "OPENOFFICEORG" ]
  70
  71   deps = [
  72     "//base",
  73     "//third_party/icu",
  74   ]
  75
  76   cflags = []
  77
  78   if (is_win) {
  79     cflags += [
  80       # TODO(jschuh): http://crbug.com/167187 size_t -> int
  81       "/wd4267",
  82     ]
  83   }
  84
  85   if (is_posix && !is_mac) {
  86     cflags += [
  87       "-Wno-unused-value",
  88       "-Wno-unused-variable",
  89       "-Wno-write-strings",
  90     ]
  91   }
  92
  93   if (is_posix && !is_mac && !is_ios) {
  94     cflags += [
  95       # affentry.hxx has NULL as default parameter for a FLAG in two
  96       # places.
  97       "-Wno-conversion-null",
  98     ]
  99   }
 100
 101   if (is_clang) {
 102     cflags += [
 103       # affentry.cxx has one `while ((p = nextchar(p)));` parsing loop.
 104       "-Wno-empty-body",
 105
 106       # affentry.hxx has NULL as default parameter for a FLAG in two
 107       # places.
 108       "-Wno-null-conversion",
 109     ]
 110   }
 111 }