ui/ozone/platform/egltest/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//tools/generate_library_loader/generate_library_loader.gni")
   6 import("//ui/ozone/ozone.gni")
   7
   8 source_set("egltest") {
   9   sources = [
  10     "client_native_pixmap_factory_egltest.cc",
  11     "client_native_pixmap_factory_egltest.h",
  12     "ozone_platform_egltest.cc",
  13     "ozone_platform_egltest.h",
  14   ]
  15
  16   deps = [
  17     ":eglplatform_shim",
  18     "//base",
  19     "//ui/events/devices",
  20     "//ui/events/ozone:events_ozone_evdev",
  21     "//ui/events/ozone:events_ozone_layout",
  22     "//ui/events/platform",
  23     "//ui/gfx",
  24   ]
  25 }
  26
  27 generate_library_loader("eglplatform_shim") {
  28   name = "LibeglplatformShimLoader"
  29   output_h = "libeglplatform_shim.h"
  30   output_cc = "libeglplatform_shim_loader.cc"
  31   header = "\"ui/ozone/platform/egltest/eglplatform_shim.h\""
  32
  33   functions = [
  34     "ShimQueryString",
  35     "ShimInitialize",
  36     "ShimTerminate",
  37     "ShimCreateWindow",
  38     "ShimQueryWindow",
  39     "ShimDestroyWindow",
  40     "ShimGetNativeDisplay",
  41     "ShimGetNativeWindow",
  42     "ShimReleaseNativeWindow",
  43   ]
  44 }
  45
  46 # TODO(spang): eglplatform_shim_x11 should become a loadable_module once
  47 # support lands: http://crbug.com/380327. Until then, it is not valid on
  48 # platforms other than Linux.
  49
  50 # GYP version: "ui/ozone/platform/egltest/egltest.gypi:eglplatform_shim_x11"
  51 if (is_linux && ozone_platform_ozonex) {
  52   shared_library("eglplatform_shim_x11") {
  53     output_name = "libeglplatform_shim"
  54
  55     output_extension = "so.1"
  56
  57     sources = [
  58       "eglplatform_shim.h",
  59       "eglplatform_shim_xeleven.cc",
  60     ]
  61
  62     configs += [ "//build/config/linux:x11" ]
  63
  64     deps = [
  65       "//build/config/sanitizers:deps",
  66     ]
  67   }
  68 }