content/renderer/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//content/renderer/renderer.gni")
   8 import("//media/media_options.gni")
   9
  10 source_set("renderer") {
  11   # Only the public target should depend on this. All other targets (even
  12   # internal content ones) should depend on the public one.
  13   visibility = [ "//content/public/renderer:renderer_sources" ]
  14
  15   sources = rebase_path(content_renderer_gypi_values.private_renderer_sources,
  16                         ".",
  17                         "//content")
  18
  19   configs += [
  20     "//content:content_implementation",
  21     "//build/config/compiler:no_size_t_to_int_warning",
  22   ]
  23
  24   deps = [
  25     # TODO(GYP) bug 376846 remove this. This should be inherited from //net but
  26     # those don't cross component boundaries.
  27     "//crypto:platform",
  28     "//base/allocator",
  29     "//cc",
  30     "//cc/blink",
  31     "//components/scheduler:scheduler",
  32     "//content:resources",
  33     "//content/common:mojo_bindings",
  34     "//content/public/child:child_sources",
  35     "//content/public/common:common_sources",
  36     "//content/public/common:mojo_bindings",
  37     "//device/battery:mojo_bindings",
  38     "//device/vibration:mojo_bindings",
  39     "//gin",
  40     "//gpu",
  41     "//gpu/command_buffer/client:gles2_interface",
  42     "//jingle:jingle_glue",
  43     "//media",
  44     "//media/blink",
  45     "//mojo/application/public/interfaces",
  46     "//mojo/environment:chromium",
  47     "//net",
  48     "//skia",
  49     "//storage/common",
  50     "//third_party/icu",
  51     "//third_party/libjingle",
  52     "//third_party/mojo/src/mojo/edk/js",
  53     "//third_party/mojo/src/mojo/public/js",
  54     "//third_party/npapi",
  55     "//third_party/WebKit/public:blink",
  56     "//third_party/widevine/cdm:version_h",
  57     "//ui/accessibility",
  58     "//ui/base",
  59     "//ui/events:events_base",
  60     "//ui/events:dom_keycode_converter",
  61     "//ui/gl",
  62     "//ui/native_theme",
  63     "//ui/surface",
  64     "//v8",
  65   ]
  66
  67   if (is_mac) {
  68     sources -= [
  69       "webscrollbarbehavior_impl_gtkoraura.cc",
  70       "webscrollbarbehavior_impl_gtkoraura.h",
  71     ]
  72     sources += [
  73       "external_popup_menu.cc",
  74       "external_popup_menu.h",
  75     ]
  76   }
  77
  78   if (is_android) {
  79     sources -= [ "media/audio_decoder.cc" ]
  80     sources += [
  81       "external_popup_menu.cc",
  82       "external_popup_menu.h",
  83     ]
  84
  85     # Add back the Linux file which Android shares.
  86     set_sources_assignment_filter([])
  87     sources += [ "render_view_linux.cc" ]
  88
  89     deps += [
  90       "//third_party/android_tools:cpu_features",
  91       "//third_party/libphonenumber",
  92     ]
  93   } else {
  94     sources -= [
  95       "java/gin_java_bridge_dispatcher.cc",
  96       "java/gin_java_bridge_dispatcher.h",
  97       "java/gin_java_bridge_object.cc",
  98       "java/gin_java_bridge_object.h",
  99       "java/gin_java_bridge_value_converter.cc",
 100       "java/gin_java_bridge_value_converter.h",
 101       "java/gin_java_function_invocation_helper.cc",
 102       "java/gin_java_function_invocation_helper.h",
 103     ]
 104   }
 105
 106   # TODO(jrg): remove the OS=="android" section?
 107   # http://crbug.com/113172
 108   # Understand better how media_stream_ is tied into Chromium.
 109   if (!enable_webrtc && is_android) {
 110     sources -= [
 111       "media/media_stream_audio_level_calculator.cc",
 112       "media/media_stream_audio_level_calculator.h",
 113       "media/media_stream_center.h",
 114       "media/media_stream_constraints_util.cc",
 115       "media/media_stream_constraints_util.h",
 116       "media/media_stream_dispatcher.h",
 117       "media/media_stream_dispatcher_eventhandler.h",
 118       "media/media_stream_track.cc",
 119       "media/media_stream_track.h",
 120     ]
 121   }
 122
 123   if (enable_webrtc) {
 124     sources += rebase_path(
 125             content_renderer_gypi_values.private_renderer_webrtc_sources,
 126             ".",
 127             "//content")
 128     deps += [
 129       "//crypto",
 130       "//third_party/libyuv",
 131       "//third_party/webrtc/modules/audio_device",
 132       "//third_party/webrtc/modules/audio_processing",
 133       "//third_party/libjingle:libjingle_webrtc",
 134       "//third_party/libjingle:libpeerconnection",
 135     ]
 136   } else {
 137     sources += [
 138       "media/webrtc_logging.h",
 139       "media/webrtc_logging_noop.cc",
 140     ]
 141   }
 142
 143   if (enable_plugins) {
 144     sources += rebase_path(
 145             content_renderer_gypi_values.private_renderer_plugin_sources,
 146             ".",
 147             "//content")
 148     deps += [
 149       "//ppapi/host",
 150       "//ppapi/proxy",
 151       "//ppapi/shared_impl",
 152       "//third_party/libvpx",
 153       "//third_party/libyuv",
 154     ]
 155   } else {
 156     # These files are in the WebRTC list, but also require plugins.
 157     if (enable_webrtc) {
 158       sources -= [
 159         "media/webrtc/video_destination_handler.cc",
 160         "media/webrtc/video_destination_handler.h",
 161       ]
 162     }
 163   }
 164
 165   if (enable_plugins && enable_webrtc) {
 166     sources += rebase_path(
 167             content_renderer_gypi_values.private_renderer_plugin_webrtc_sources,
 168             ".",
 169             "//content")
 170   }
 171
 172   if (!enable_pepper_cdms) {
 173     sources -= [
 174       "media/crypto/pepper_cdm_wrapper.h",
 175       "media/crypto/pepper_cdm_wrapper_impl.cc",
 176       "media/crypto/pepper_cdm_wrapper_impl.h",
 177       "media/crypto/ppapi_decryptor.cc",
 178       "media/crypto/ppapi_decryptor.h",
 179     ]
 180   }
 181
 182   if (enable_print_preview) {
 183     deps += [ "//printing" ]
 184   }
 185
 186   if (enable_browser_cdms) {
 187     sources += [
 188       "media/crypto/proxy_media_keys.cc",
 189       "media/crypto/proxy_media_keys.h",
 190       "media/crypto/renderer_cdm_manager.cc",
 191       "media/crypto/renderer_cdm_manager.h",
 192     ]
 193   }
 194
 195   if (enable_media_mojo_renderer) {
 196     sources += [
 197       "media/content_media_service_provider.cc",
 198       "media/content_media_service_provider.h",
 199     ]
 200     deps += [ "//media/mojo/services:proxy" ]
 201   }
 202 }