components/sessions/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 if (is_android) {
   6   import("//build/config/android/config.gni")
   7 }
   8
   9 # TODO(rohitrao): sessions_core is defined as a source_set because it declares a
  10 # static function that it does not define.  This prevents it from linking as a
  11 # shared_library.  It also cannot be a static_library because it will be linked
  12 # into multiple shared libraries.  Revisit this setup if necessary.
  13 source_set("sessions_core") {
  14   sources = [
  15     "base_session_service.cc",
  16     "base_session_service.h",
  17     "base_session_service_commands.cc",
  18     "base_session_service_commands.h",
  19     "base_session_service_delegate.h",
  20     "core/serialized_navigation_driver.h",
  21     "serialized_navigation_entry.cc",
  22     "serialized_navigation_entry.h",
  23     "session_backend.cc",
  24     "session_backend.h",
  25     "session_command.cc",
  26     "session_command.h",
  27     "session_id.cc",
  28     "session_id.h",
  29     "session_service_commands.cc",
  30     "session_service_commands.h",
  31     "session_types.cc",
  32     "session_types.h",
  33   ]
  34
  35   defines = [ "SESSIONS_IMPLEMENTATION" ]
  36
  37   deps = [
  38     "//base",
  39     "//skia",
  40     "//sync",
  41     "//third_party/protobuf:protobuf_lite",
  42     "//ui/base",
  43     "//ui/gfx",
  44     "//url",
  45   ]
  46 }
  47
  48 source_set("test_support") {
  49   testonly = true
  50   sources = [
  51     "serialized_navigation_entry_test_helper.cc",
  52     "serialized_navigation_entry_test_helper.h",
  53   ]
  54
  55   deps = [
  56     ":sessions_core",
  57     "//skia",
  58     "//sync",
  59     "//testing/gtest",
  60   ]
  61
  62   if (!is_android && !is_ios) {
  63     sources += [
  64       "base_session_service_test_helper.cc",
  65       "base_session_service_test_helper.h",
  66     ]
  67   }
  68 }
  69
  70 if (!is_ios) {
  71   component("sessions_content") {
  72     sources = [
  73       "content/content_serialized_navigation_builder.cc",
  74       "content/content_serialized_navigation_builder.h",
  75       "content/content_serialized_navigation_driver.cc",
  76       "content/content_serialized_navigation_driver.h",
  77     ]
  78
  79     defines = [ "SESSIONS_IMPLEMENTATION" ]
  80
  81     deps = [
  82       ":sessions_core",
  83       "//base",
  84       "//base/third_party/dynamic_annotations",
  85       "//content/public/browser",
  86       "//ui/base",
  87       "//url",
  88     ]
  89   }
  90 }
  91
  92 if (!is_ios && !is_android) {
  93   source_set("unit_tests") {
  94     testonly = true
  95     sources = [
  96       "session_backend_unittest.cc",
  97       "session_types_unittest.cc",
  98     ]
  99     deps = [
 100       ":sessions_content",
 101       "//base/test:test_support",
 102       "//testing/gtest",
 103       "//third_party/protobuf:protobuf_lite",
 104     ]
 105   }
 106 }