media/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/arm.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/linux/pkg_config.gni")
   9 import("//build/config/ui.gni")
  10 import("//media/media_options.gni")
  11 import("//testing/test.gni")
  12
  13 # Common configuration for targets in the media directory.
  14 # NOT for exporting.
  15 config("media_config") {
  16   defines = [ "MEDIA_IMPLEMENTATION" ]
  17   if (!media_use_libvpx) {
  18     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  19   }
  20   if (!media_use_ffmpeg) {
  21     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  22   }
  23   if (current_cpu == "arm" && arm_use_neon) {
  24     defines += [ "USE_NEON" ]
  25   }
  26   if (use_pulseaudio) {
  27     defines += [ "USE_PULSEAUDIO" ]
  28     if (!link_pulseaudio) {
  29       defines += [ "DLOPEN_PULSEAUDIO" ]
  30     }
  31   }
  32   if (use_cras) {
  33     defines += [ "USE_CRAS" ]
  34   }
  35   if (use_alsa) {
  36     defines += [ "USE_ALSA" ]
  37   }
  38 }
  39
  40 config("media_dependent_config") {
  41   defines = []
  42   if (!media_use_libvpx) {
  43     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  44   }
  45   if (!media_use_ffmpeg) {
  46     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  47   }
  48   if (is_win) {
  49     ldflags = [
  50       "/DELAYLOAD:mf.dll",
  51       "/DELAYLOAD:mfplat.dll",
  52       "/DELAYLOAD:mfreadwrite.dll",
  53     ]
  54   }
  55 }
  56
  57 if (use_ozone) {
  58   action("generate_ozone_constructor_list") {
  59     # Ozone platform objects are auto-generated using similar
  60     # patterns for naming and classes constructors. Here we build the
  61     # object MediaOzonePlatform.
  62     script = "../ui/ozone/generate_constructor_list.py"
  63
  64     platform_list_txt_file = "$target_gen_dir/../ui/ozone/platform_list.txt"
  65     constructor_list_cc_file =
  66         "$target_gen_dir/../media/ozone/constructor_list.cc"
  67
  68     sources = [
  69       platform_list_txt_file,
  70     ]
  71     outputs = [
  72       constructor_list_cc_file,
  73     ]
  74     args = [
  75       "--platform_list=" + rebase_path(platform_list_txt_file, root_build_dir),
  76       "--output_cc=" + rebase_path(constructor_list_cc_file, root_build_dir),
  77       "--namespace=media",
  78       "--typename=MediaOzonePlatform",
  79       "--include=\"media/ozone/media_ozone_platform.h\"",
  80     ]
  81   }
  82 }
  83
  84 component("media") {
  85   sources = [
  86     "blink/skcanvas_video_renderer.cc",
  87     "blink/skcanvas_video_renderer.h",
  88     "cdm/aes_decryptor.cc",
  89     "cdm/aes_decryptor.h",
  90     "cdm/cenc_utils.cc",
  91     "cdm/cenc_utils.h",
  92     "cdm/default_cdm_factory.cc",
  93     "cdm/default_cdm_factory.h",
  94     "cdm/json_web_key.cc",
  95     "cdm/json_web_key.h",
  96     "cdm/key_system_names.cc",
  97     "cdm/key_system_names.h",
  98     "cdm/player_tracker_impl.cc",
  99     "cdm/player_tracker_impl.h",
 100     "cdm/proxy_decryptor.cc",
 101     "cdm/proxy_decyrptor.h",
 102     "ffmpeg/ffmpeg_deleters.h",
 103     "filters/audio_clock.cc",
 104     "filters/audio_clock.h",
 105     "filters/audio_renderer_algorithm.cc",
 106     "filters/audio_renderer_algorithm.h",
 107     "filters/chunk_demuxer.cc",
 108     "filters/chunk_demuxer.h",
 109     "filters/context_3d.h",
 110     "filters/decoder_selector.cc",
 111     "filters/decoder_selector.h",
 112     "filters/decoder_stream.cc",
 113     "filters/decoder_stream.h",
 114     "filters/decoder_stream_traits.cc",
 115     "filters/decoder_stream_traits.h",
 116     "filters/decrypting_audio_decoder.cc",
 117     "filters/decrypting_audio_decoder.h",
 118     "filters/decrypting_demuxer_stream.cc",
 119     "filters/decrypting_demuxer_stream.h",
 120     "filters/decrypting_video_decoder.cc",
 121     "filters/decrypting_video_decoder.h",
 122     "filters/default_media_permission.cc",
 123     "filters/default_media_permission.h",
 124     "filters/file_data_source.cc",
 125     "filters/file_data_source.h",
 126     "filters/frame_processor.cc",
 127     "filters/frame_processor.h",
 128     "filters/gpu_video_decoder.cc",
 129     "filters/gpu_video_decoder.h",
 130     "filters/h264_bit_reader.cc",
 131     "filters/h264_bit_reader.h",
 132     "filters/h264_parser.cc",
 133     "filters/h264_parser.h",
 134     "filters/jpeg_parser.cc",
 135     "filters/jpeg_parser.h",
 136     "filters/source_buffer_platform.cc",
 137     "filters/source_buffer_platform.h",
 138     "filters/source_buffer_range.cc",
 139     "filters/source_buffer_range.h",
 140     "filters/source_buffer_stream.cc",
 141     "filters/source_buffer_stream.h",
 142     "filters/stream_parser_factory.cc",
 143     "filters/stream_parser_factory.h",
 144     "filters/video_frame_scheduler.h",
 145     "filters/video_frame_scheduler_impl.cc",
 146     "filters/video_frame_scheduler_impl.h",
 147     "filters/video_frame_scheduler_proxy.cc",
 148     "filters/video_frame_scheduler_proxy.h",
 149     "filters/vp8_bool_decoder.cc",
 150     "filters/vp8_bool_decoder.h",
 151     "filters/vp8_parser.cc",
 152     "filters/vp8_parser.h",
 153     "filters/webvtt_util.h",
 154     "filters/wsola_internals.cc",
 155     "filters/wsola_internals.h",
 156     "formats/common/offset_byte_queue.cc",
 157     "formats/common/offset_byte_queue.h",
 158     "formats/webm/webm_audio_client.cc",
 159     "formats/webm/webm_audio_client.h",
 160     "formats/webm/webm_cluster_parser.cc",
 161     "formats/webm/webm_cluster_parser.h",
 162     "formats/webm/webm_constants.cc",
 163     "formats/webm/webm_constants.h",
 164     "formats/webm/webm_content_encodings.cc",
 165     "formats/webm/webm_content_encodings.h",
 166     "formats/webm/webm_content_encodings_client.cc",
 167     "formats/webm/webm_content_encodings_client.h",
 168     "formats/webm/webm_crypto_helpers.cc",
 169     "formats/webm/webm_crypto_helpers.h",
 170     "formats/webm/webm_info_parser.cc",
 171     "formats/webm/webm_info_parser.h",
 172     "formats/webm/webm_parser.cc",
 173     "formats/webm/webm_parser.h",
 174     "formats/webm/webm_stream_parser.cc",
 175     "formats/webm/webm_stream_parser.h",
 176     "formats/webm/webm_tracks_parser.cc",
 177     "formats/webm/webm_tracks_parser.h",
 178     "formats/webm/webm_video_client.cc",
 179     "formats/webm/webm_video_client.h",
 180     "formats/webm/webm_webvtt_parser.cc",
 181     "formats/webm/webm_webvtt_parser.h",
 182     "midi/midi_manager.cc",
 183     "midi/midi_manager.h",
 184     "midi/midi_manager_mac.cc",
 185     "midi/midi_manager_mac.h",
 186     "midi/midi_manager_usb.cc",
 187     "midi/midi_manager_usb.h",
 188     "midi/midi_manager_win.cc",
 189     "midi/midi_manager_win.h",
 190     "midi/midi_message_queue.cc",
 191     "midi/midi_message_queue.h",
 192     "midi/midi_message_util.cc",
 193     "midi/midi_message_util.h",
 194     "midi/midi_port_info.cc",
 195     "midi/midi_port_info.h",
 196     "midi/midi_scheduler.cc",
 197     "midi/midi_scheduler.h",
 198     "midi/usb_midi_descriptor_parser.cc",
 199     "midi/usb_midi_descriptor_parser.h",
 200     "midi/usb_midi_device.h",
 201     "midi/usb_midi_input_stream.cc",
 202     "midi/usb_midi_input_stream.h",
 203     "midi/usb_midi_jack.h",
 204     "midi/usb_midi_output_stream.cc",
 205     "midi/usb_midi_output_stream.h",
 206     "renderers/audio_renderer_impl.cc",
 207     "renderers/audio_renderer_impl.h",
 208     "renderers/gpu_video_accelerator_factories.h",
 209     "renderers/renderer_impl.cc",
 210     "renderers/renderer_impl.h",
 211     "renderers/video_renderer_impl.cc",
 212     "renderers/video_renderer_impl.h",
 213     "video/capture/file_video_capture_device.cc",
 214     "video/capture/file_video_capture_device.h",
 215     "video/capture/linux/v4l2_capture_delegate.cc",
 216     "video/capture/linux/v4l2_capture_delegate.h",
 217     "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 218     "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 219     "video/capture/linux/v4l2_capture_delegate_single_plane.cc",
 220     "video/capture/linux/v4l2_capture_delegate_single_plane.h",
 221     "video/capture/linux/video_capture_device_chromeos.cc",
 222     "video/capture/linux/video_capture_device_chromeos.h",
 223     "video/capture/linux/video_capture_device_linux.cc",
 224     "video/capture/linux/video_capture_device_linux.h",
 225     "video/capture/mac/platform_video_capturing_mac.h",
 226     "video/capture/mac/video_capture_device_avfoundation_mac.h",
 227     "video/capture/mac/video_capture_device_avfoundation_mac.mm",
 228     "video/capture/mac/video_capture_device_decklink_mac.h",
 229     "video/capture/mac/video_capture_device_decklink_mac.mm",
 230     "video/capture/mac/video_capture_device_factory_mac.h",
 231     "video/capture/mac/video_capture_device_factory_mac.mm",
 232     "video/capture/mac/video_capture_device_mac.h",
 233     "video/capture/mac/video_capture_device_mac.mm",
 234     "video/capture/mac/video_capture_device_qtkit_mac.h",
 235     "video/capture/mac/video_capture_device_qtkit_mac.mm",
 236     "video/capture/video_capture_device.cc",
 237     "video/capture/video_capture_device.h",
 238     "video/capture/video_capture_device_info.cc",
 239     "video/capture/video_capture_device_info.h",
 240     "video/capture/win/capability_list_win.cc",
 241     "video/capture/win/capability_list_win.h",
 242     "video/capture/win/filter_base_win.cc",
 243     "video/capture/win/filter_base_win.h",
 244     "video/capture/win/pin_base_win.cc",
 245     "video/capture/win/pin_base_win.h",
 246     "video/capture/win/sink_filter_observer_win.h",
 247     "video/capture/win/sink_filter_win.cc",
 248     "video/capture/win/sink_filter_win.h",
 249     "video/capture/win/sink_input_pin_win.cc",
 250     "video/capture/win/sink_input_pin_win.h",
 251     "video/capture/win/video_capture_device_factory_win.cc",
 252     "video/capture/win/video_capture_device_factory_win.h",
 253     "video/capture/win/video_capture_device_mf_win.cc",
 254     "video/capture/win/video_capture_device_mf_win.h",
 255     "video/capture/win/video_capture_device_win.cc",
 256     "video/capture/win/video_capture_device_win.h",
 257     "video/fake_video_encode_accelerator.cc",
 258     "video/fake_video_encode_accelerator.h",
 259     "video/h264_poc.cc",
 260     "video/h264_poc.h",
 261     "video/picture.cc",
 262     "video/picture.h",
 263     "video/video_decode_accelerator.cc",
 264     "video/video_decode_accelerator.h",
 265     "video/video_encode_accelerator.cc",
 266     "video/video_encode_accelerator.h",
 267   ]
 268
 269   configs += [
 270     ":media_config",
 271
 272     # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 273     # See http://crbug.com/171009
 274     "//build/config/compiler:no_size_t_to_int_warning",
 275   ]
 276   all_dependent_configs = [ ":media_dependent_config" ]
 277
 278   cflags = []
 279   libs = []
 280   defines = []
 281   deps = []
 282
 283   include_dirs = [ "." ]
 284   if (media_use_ffmpeg) {
 285     deps += [ "//third_party/ffmpeg" ]
 286     sources += [
 287       "ffmpeg/ffmpeg_common.cc",
 288       "ffmpeg/ffmpeg_common.h",
 289       "filters/audio_file_reader.cc",
 290       "filters/audio_file_reader.h",
 291       "filters/blocking_url_protocol.cc",
 292       "filters/blocking_url_protocol.h",
 293       "filters/ffmpeg_audio_decoder.cc",
 294       "filters/ffmpeg_audio_decoder.h",
 295       "filters/ffmpeg_bitstream_converter.h",
 296       "filters/ffmpeg_demuxer.cc",
 297       "filters/ffmpeg_demuxer.h",
 298       "filters/ffmpeg_glue.cc",
 299       "filters/ffmpeg_glue.h",
 300       "filters/ffmpeg_video_decoder.cc",
 301       "filters/ffmpeg_video_decoder.h",
 302       "filters/in_memory_url_protocol.cc",
 303       "filters/in_memory_url_protocol.h",
 304     ]
 305     if (proprietary_codecs) {
 306       sources += [
 307         "filters/ffmpeg_aac_bitstream_converter.cc",
 308         "filters/ffmpeg_aac_bitstream_converter.h",
 309         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.cc",
 310         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.h",
 311       ]
 312     }
 313   }
 314
 315   if (current_cpu == "arm" && arm_use_neon) {
 316     defines += [ "USE_NEON" ]
 317   }
 318
 319   if (media_use_libvpx) {
 320     sources += [
 321       "filters/vpx_video_decoder.cc",
 322       "filters/vpx_video_decoder.h",
 323     ]
 324     deps += [ "//third_party/libvpx" ]
 325   }
 326
 327   if (!is_android) {
 328     sources += [
 329       "filters/opus_audio_decoder.cc",
 330       "filters/opus_audio_decoder.h",
 331       "renderers/default_renderer_factory.cc",
 332       "renderers/default_renderer_factory.h",
 333     ]
 334   } else {
 335     sources += [
 336       "midi/midi_manager_android.cc",
 337       "midi/usb_midi_device_android.cc",
 338       "midi/usb_midi_device_android.h",
 339       "midi/usb_midi_device_factory_android.cc",
 340       "midi/usb_midi_device_factory_android.h",
 341       "video/capture/android/video_capture_device_android.cc",
 342       "video/capture/android/video_capture_device_android.h",
 343       "video/capture/android/video_capture_device_factory_android.cc",
 344       "video/capture/android/video_capture_device_factory_android.h",
 345     ]
 346     deps += [
 347       "//media/base/android",
 348       "//media/base/android:media_jni_headers",
 349       "//media/base/android:video_capture_jni_headers",
 350     ]
 351     if (!is_android_webview_build) {
 352       deps += [ "//media/base/android:media_java" ]
 353     }
 354   }
 355
 356   if (current_cpu != "arm" && is_chromeos) {
 357     sources += [
 358       "filters/h264_bitstream_buffer.cc",
 359       "filters/h264_bitstream_buffer.h",
 360     ]
 361   }
 362
 363   if (use_alsa) {
 364     libs += [ "asound" ]
 365     sources += [
 366       "midi/midi_manager_alsa.cc",
 367       "midi/midi_manager_alsa.h",
 368     ]
 369   }
 370
 371   if (use_udev) {
 372     deps += [ "//device/udev_linux" ]
 373   }
 374
 375   # A simple WebM encoder for animated avatars on ChromeOS.
 376
 377   if (use_ozone) {
 378     # Used for the generated listing header (ui/ozone/platform_list.h)
 379     include_dirs += [ target_gen_dir ]
 380
 381     sources += [
 382                  "ozone/media_ozone_platform.cc",
 383                  "ozone/media_ozone_platform.h",
 384                ] + get_target_outputs(":generate_ozone_constructor_list")
 385
 386     deps += [
 387       ":generate_ozone_constructor_list",
 388       "//ui/ozone",
 389     ]
 390   }
 391
 392   if (is_mac) {
 393     deps += [
 394       "//media/base/mac",
 395       "//third_party/decklink",
 396     ]
 397     libs += [
 398       "CoreMIDI.framework",
 399       "CoreVideo.framework",
 400       "OpenGL.framework",
 401       "QTKit.framework",
 402     ]
 403   }
 404
 405   if (is_openbsd) {
 406     sources -= [
 407       "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 408       "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 409     ]
 410   }
 411
 412   if (is_ios) {
 413     deps += [ "//media/base/mac" ]
 414   }
 415
 416   if (is_win) {
 417     deps += [ "//device/usb" ]
 418
 419     libs += [
 420       "mf.lib",
 421       "mfplat.lib",
 422       "mfreadwrite.lib",
 423       "mfuuid.lib",
 424     ]
 425   }
 426
 427   if (proprietary_codecs) {
 428     sources += [
 429       "filters/h264_to_annex_b_bitstream_converter.cc",
 430       "filters/h264_to_annex_b_bitstream_converter.h",
 431       "formats/mp2t/es_adapter_video.cc",
 432       "formats/mp2t/es_adapter_video.h",
 433       "formats/mp2t/es_parser.cc",
 434       "formats/mp2t/es_parser.h",
 435       "formats/mp2t/es_parser_adts.cc",
 436       "formats/mp2t/es_parser_adts.h",
 437       "formats/mp2t/es_parser_h264.cc",
 438       "formats/mp2t/es_parser_h264.h",
 439       "formats/mp2t/es_parser_mpeg1audio.cc",
 440       "formats/mp2t/es_parser_mpeg1audio.h",
 441       "formats/mp2t/mp2t_common.h",
 442       "formats/mp2t/mp2t_stream_parser.cc",
 443       "formats/mp2t/mp2t_stream_parser.h",
 444       "formats/mp2t/timestamp_unroller.cc",
 445       "formats/mp2t/timestamp_unroller.h",
 446       "formats/mp2t/ts_packet.cc",
 447       "formats/mp2t/ts_packet.h",
 448       "formats/mp2t/ts_section.h",
 449       "formats/mp2t/ts_section_pat.cc",
 450       "formats/mp2t/ts_section_pat.h",
 451       "formats/mp2t/ts_section_pes.cc",
 452       "formats/mp2t/ts_section_pes.h",
 453       "formats/mp2t/ts_section_pmt.cc",
 454       "formats/mp2t/ts_section_pmt.h",
 455       "formats/mp2t/ts_section_psi.cc",
 456       "formats/mp2t/ts_section_psi.h",
 457       "formats/mp4/aac.cc",
 458       "formats/mp4/aac.h",
 459       "formats/mp4/avc.cc",
 460       "formats/mp4/avc.h",
 461       "formats/mp4/box_definitions.cc",
 462       "formats/mp4/box_definitions.h",
 463       "formats/mp4/box_reader.cc",
 464       "formats/mp4/box_reader.h",
 465       "formats/mp4/cenc.cc",
 466       "formats/mp4/cenc.h",
 467       "formats/mp4/es_descriptor.cc",
 468       "formats/mp4/es_descriptor.h",
 469       "formats/mp4/mp4_stream_parser.cc",
 470       "formats/mp4/mp4_stream_parser.h",
 471       "formats/mp4/sample_to_group_iterator.cc",
 472       "formats/mp4/sample_to_group_iterator.h",
 473       "formats/mp4/track_run_iterator.cc",
 474       "formats/mp4/track_run_iterator.h",
 475       "formats/mpeg/adts_constants.cc",
 476       "formats/mpeg/adts_constants.h",
 477       "formats/mpeg/adts_stream_parser.cc",
 478       "formats/mpeg/adts_stream_parser.h",
 479       "formats/mpeg/mpeg1_audio_stream_parser.cc",
 480       "formats/mpeg/mpeg1_audio_stream_parser.h",
 481       "formats/mpeg/mpeg_audio_stream_parser_base.cc",
 482       "formats/mpeg/mpeg_audio_stream_parser_base.h",
 483     ]
 484   }
 485
 486   public_deps = [
 487     "//media/base",
 488     "//media/audio",
 489   ]
 490
 491   deps += [
 492     ":shared_memory_support",
 493     "//base",
 494     "//base:i18n",
 495     "//base/third_party/dynamic_annotations",
 496     "//crypto",
 497     "//crypto:platform",  # TODO(ajwong): This used to be provided by crypto.gyp via export_dependent_settings
 498     "//gpu/command_buffer/common",
 499     "//skia",
 500     "//third_party/libyuv",
 501     "//third_party/opus",
 502     "//ui/gfx/geometry",
 503     "//url",
 504   ]
 505
 506   # Add the sources and dependencies that need the X11 or fontconfig libraries.
 507   if (!is_ensemble) {
 508     sources += [
 509       "video/capture/fake_video_capture_device.cc",
 510       "video/capture/fake_video_capture_device.h",
 511       "video/capture/fake_video_capture_device_factory.cc",
 512       "video/capture/fake_video_capture_device_factory.h",
 513       "video/capture/file_video_capture_device_factory.cc",
 514       "video/capture/file_video_capture_device_factory.h",
 515       "video/capture/linux/video_capture_device_factory_linux.cc",
 516       "video/capture/linux/video_capture_device_factory_linux.h",
 517       "video/capture/video_capture_device_factory.cc",
 518       "video/capture/video_capture_device_factory.h",
 519     ]
 520
 521     deps += [
 522       "//ui/events:events_base",
 523       "//ui/gfx",
 524     ]
 525   }
 526 }
 527
 528 # Minimal media component for media/cast on iOS.
 529 if (is_ios) {
 530   component("media_for_cast_ios") {
 531     configs += [ ":media_config" ]
 532     all_dependent_configs = [ ":media_dependent_config" ]
 533     include_dirs = [ "." ]
 534     libs = [ "CoreVideo.framework" ]
 535
 536     deps = [
 537       ":shared_memory_support",
 538       "//base",
 539       "//media/base:base_for_cast_ios",
 540       "//media/base/mac",
 541       "//ui/gfx/geometry",
 542     ]
 543   }
 544 }
 545
 546 test("media_unittests") {
 547   sources = [
 548     "blink/skcanvas_video_renderer_unittest.cc",
 549     "cdm/aes_decryptor_unittest.cc",
 550     "cdm/cenc_utils_unittest.cc",
 551     "cdm/json_web_key_unittest.cc",
 552     "filters/audio_clock_unittest.cc",
 553     "filters/audio_decoder_selector_unittest.cc",
 554     "filters/audio_renderer_algorithm_unittest.cc",
 555     "filters/chunk_demuxer_unittest.cc",
 556     "filters/decrypting_audio_decoder_unittest.cc",
 557     "filters/decrypting_demuxer_stream_unittest.cc",
 558     "filters/decrypting_video_decoder_unittest.cc",
 559     "filters/fake_demuxer_stream.cc",
 560     "filters/fake_demuxer_stream.h",
 561     "filters/fake_demuxer_stream_unittest.cc",
 562     "filters/fake_video_decoder.cc",
 563     "filters/fake_video_decoder.h",
 564     "filters/fake_video_decoder_unittest.cc",
 565     "filters/file_data_source_unittest.cc",
 566     "filters/frame_processor_unittest.cc",
 567     "filters/h264_bit_reader_unittest.cc",
 568     "filters/h264_parser_unittest.cc",
 569     "filters/jpeg_parser_unittest.cc",
 570     "filters/source_buffer_stream_unittest.cc",
 571     "filters/video_decoder_selector_unittest.cc",
 572     "filters/video_frame_scheduler_impl_unittest.cc",
 573     "filters/video_frame_scheduler_unittest.cc",
 574     "filters/video_frame_stream_unittest.cc",
 575     "filters/vp8_bool_decoder_unittest.cc",
 576     "filters/vp8_parser_unittest.cc",
 577     "formats/common/offset_byte_queue_unittest.cc",
 578     "formats/webm/cluster_builder.cc",
 579     "formats/webm/cluster_builder.h",
 580     "formats/webm/opus_packet_builder.cc",
 581     "formats/webm/opus_packet_builder.h",
 582     "formats/webm/tracks_builder.cc",
 583     "formats/webm/tracks_builder.h",
 584     "formats/webm/webm_cluster_parser_unittest.cc",
 585     "formats/webm/webm_content_encodings_client_unittest.cc",
 586     "formats/webm/webm_parser_unittest.cc",
 587     "formats/webm/webm_tracks_parser_unittest.cc",
 588     "formats/webm/webm_webvtt_parser_unittest.cc",
 589     "midi/midi_manager_unittest.cc",
 590     "midi/midi_manager_usb_unittest.cc",
 591     "midi/midi_message_queue_unittest.cc",
 592     "midi/midi_message_util_unittest.cc",
 593     "midi/usb_midi_descriptor_parser_unittest.cc",
 594     "midi/usb_midi_input_stream_unittest.cc",
 595     "midi/usb_midi_output_stream_unittest.cc",
 596     "renderers/audio_renderer_impl_unittest.cc",
 597     "renderers/renderer_impl_unittest.cc",
 598     "renderers/video_renderer_impl_unittest.cc",
 599     "video/capture/fake_video_capture_device_unittest.cc",
 600     "video/capture/video_capture_device_unittest.cc",
 601     "video/h264_poc_unittest.cc",
 602   ]
 603
 604   # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 605   # See http://crbug.com/171009
 606   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 607
 608   deps = [
 609     ":media",
 610     ":test_support",
 611     "//base/allocator",
 612     "//base/test:test_support",
 613     "//media/audio:unittests",
 614     "//media/audio:test_support",
 615     "//media/base:unittests",
 616     "//media/base:test_support",
 617     "//media/test:pipeline_integration_tests",
 618     "//skia",  # Direct dependency required to inherit config.
 619     "//testing/gmock",
 620     "//testing/gtest",
 621     "//third_party/widevine/cdm:version_h",
 622     "//ui/gfx:test_support",
 623     "//url",
 624   ]
 625
 626   if (is_android) {
 627     deps += [
 628       "//media/base/android",
 629       # TODO(GYP)
 630       #"//testing/android:native_test_native_code"
 631     ]
 632   }
 633
 634   if (media_use_ffmpeg) {
 635     sources += [
 636       "ffmpeg/ffmpeg_common_unittest.cc",
 637       "filters/audio_decoder_unittest.cc",
 638       "filters/audio_file_reader_unittest.cc",
 639       "filters/blocking_url_protocol_unittest.cc",
 640       "filters/ffmpeg_demuxer_unittest.cc",
 641       "filters/ffmpeg_glue_unittest.cc",
 642       "filters/ffmpeg_video_decoder_unittest.cc",
 643       "filters/in_memory_url_protocol_unittest.cc",
 644     ]
 645   }
 646
 647   if (current_cpu != "arm" && is_chromeos) {
 648     sources += [ "filters/h264_bitstream_buffer_unittest.cc" ]
 649   }
 650
 651   if (proprietary_codecs) {
 652     sources += [
 653       "filters/ffmpeg_aac_bitstream_converter_unittest.cc",
 654       "filters/ffmpeg_h264_to_annex_b_bitstream_converter_unittest.cc",
 655       "filters/h264_to_annex_b_bitstream_converter_unittest.cc",
 656       "formats/common/stream_parser_test_base.cc",
 657       "formats/common/stream_parser_test_base.h",
 658       "formats/mp2t/es_adapter_video_unittest.cc",
 659       "formats/mp2t/es_parser_adts_unittest.cc",
 660       "formats/mp2t/es_parser_h264_unittest.cc",
 661       "formats/mp2t/es_parser_mpeg1audio_unittest.cc",
 662       "formats/mp2t/es_parser_test_base.cc",
 663       "formats/mp2t/es_parser_test_base.h",
 664       "formats/mp2t/mp2t_stream_parser_unittest.cc",
 665       "formats/mp2t/timestamp_unroller_unittest.cc",
 666       "formats/mp4/aac_unittest.cc",
 667       "formats/mp4/avc_unittest.cc",
 668       "formats/mp4/box_reader_unittest.cc",
 669       "formats/mp4/es_descriptor_unittest.cc",
 670       "formats/mp4/mp4_stream_parser_unittest.cc",
 671       "formats/mp4/sample_to_group_iterator_unittest.cc",
 672       "formats/mp4/track_run_iterator_unittest.cc",
 673       "formats/mpeg/adts_stream_parser_unittest.cc",
 674       "formats/mpeg/mpeg1_audio_stream_parser_unittest.cc",
 675     ]
 676   }
 677
 678   if (is_mac || is_ios) {
 679     deps += [ "//media/base/mac" ]
 680   }
 681
 682   if (is_mac) {
 683     sources += [
 684       "midi/midi_manager_mac_unittest.cc",
 685       "video/capture/mac/video_capture_device_factory_mac_unittest.mm",
 686     ]
 687   }
 688
 689   if (use_alsa) {
 690     sources += [ "midi/midi_manager_alsa_unittest.cc" ]
 691   }
 692
 693   #      include_dirs += [
 694   #        # Needed by media_drm_bridge.cc.
 695   #        target_gen_dir,
 696   #      ],
 697
 698   configs += [ ":media_config" ]
 699
 700   if (media_use_ffmpeg) {
 701     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 702   }
 703 }
 704
 705 test("media_perftests") {
 706   configs += [ ":media_config" ]
 707   deps = [
 708     ":media",
 709     ":shared_memory_support",
 710     ":test_support",
 711     "//base/test:test_support",
 712     "//media/audio:test_support",
 713     "//media/base:perftests",
 714     "//media/base:test_support",
 715     "//media/test:pipeline_integration_perftests",
 716     "//testing/gmock",
 717     "//testing/gtest",
 718     "//testing/perf",
 719     "//third_party/widevine/cdm:version_h",
 720     "//ui/gfx:test_support",
 721   ]
 722   if (is_android) {
 723     deps += [ "//ui/gl" ]
 724   }
 725   if (media_use_ffmpeg) {
 726     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 727   }
 728 }
 729
 730 source_set("test_support") {
 731   testonly = true
 732   sources = [
 733     "filters/clockless_video_frame_scheduler.cc",
 734     "filters/clockless_video_frame_scheduler.h",
 735     "filters/test_video_frame_scheduler.cc",
 736     "filters/test_video_frame_scheduler.h",
 737     "renderers/mock_gpu_video_accelerator_factories.cc",
 738     "renderers/mock_gpu_video_accelerator_factories.h",
 739     "video/mock_video_decode_accelerator.cc",
 740     "video/mock_video_decode_accelerator.h",
 741   ]
 742   deps = [
 743     ":media",
 744     ":shared_memory_support",
 745     "//base",
 746     "//skia",
 747     "//testing/gmock",
 748     "//testing/gtest",
 749   ]
 750 }
 751
 752 # TODO(dalecurtis): How to split this across audio/base directories??
 753 component("shared_memory_support") {
 754   sources = [
 755     "audio/audio_parameters.cc",
 756     "audio/audio_parameters.h",
 757     "base/audio_bus.cc",
 758     "base/audio_bus.h",
 759     "base/channel_layout.cc",
 760     "base/channel_layout.h",
 761     "base/limits.h",
 762     "base/media_export.h",
 763     "base/vector_math.cc",
 764     "base/vector_math.h",
 765   ]
 766   configs += [ ":media_config" ]
 767   defines = [ "MEDIA_IMPLEMENTATION" ]
 768   deps = [
 769     "//base",
 770   ]
 771 }
 772
 773 if (media_use_ffmpeg) {
 774   test("ffmpeg_regression_tests") {
 775     sources = [
 776       "base/run_all_unittests.cc",
 777       "ffmpeg/ffmpeg_regression_tests.cc",
 778     ]
 779
 780     configs += [ "//media:media_config" ]
 781
 782     deps = [
 783       "//base/test:test_support",
 784       "//media",
 785       "//media:test_support",
 786       "//media/audio:test_support",
 787       "//media/base:test_support",
 788       "//media/test:pipeline_integration_tests",
 789       "//testing/gmock",
 790       "//testing/gtest",
 791       "//third_party/ffmpeg",
 792       "//ui/gfx/geometry",
 793       "//ui/gfx:test_support",
 794     ]
 795   }
 796 }
 797
 798 if (use_x11) {
 799   executable("player_x11") {
 800     sources = [
 801       "tools/player_x11/data_source_logger.cc",
 802       "tools/player_x11/data_source_logger.h",
 803       "tools/player_x11/gl_video_renderer.cc",
 804       "tools/player_x11/gl_video_renderer.h",
 805       "tools/player_x11/player_x11.cc",
 806       "tools/player_x11/x11_video_renderer.cc",
 807       "tools/player_x11/x11_video_renderer.h",
 808     ]
 809     configs += [
 810       ":media_config",
 811       "//build/config/linux:x11",
 812       "//build/config/linux:xext",
 813
 814       # TODO(ajwong): Why does xext get a separate thing in //build/config/linux:BUILD.gn
 815       #  "//build/config/linux:xrender",
 816     ]
 817     deps = [
 818       ":media",
 819       ":shared_memory_support",
 820       "//base",
 821       "//tools/xdisplaycheck",
 822       "//ui/gl",
 823       "//ui/gfx",
 824       "//ui/gfx/geometry",
 825     ]
 826   }
 827 }