chrome/browser/ui/cocoa/applescript/bookmark_item_applescript.mm

   1 // Copyright (c) 2011 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/applescript/bookmark_item_applescript.h"
   6
   7 #include "base/strings/sys_string_conversions.h"
   8 #include "chrome/browser/profiles/profile_manager.h"
   9 #import "chrome/browser/ui/cocoa/applescript/error_applescript.h"
  10 #include "components/bookmarks/browser/bookmark_model.h"
  11
  12 using bookmarks::BookmarkModel;
  13 using bookmarks::BookmarkNode;
  14
  15 @interface BookmarkItemAppleScript()
  16 @property (nonatomic, copy) NSString* tempURL;
  17 @end
  18
  19 @implementation BookmarkItemAppleScript
  20
  21 @synthesize tempURL = tempURL_;
  22
  23 - (id)init {
  24   if ((self = [super init])) {
  25     [self setTempURL:@""];
  26   }
  27   return self;
  28 }
  29
  30 - (void)dealloc {
  31   [tempURL_ release];
  32   [super dealloc];
  33 }
  34
  35 - (void)setBookmarkNode:(const BookmarkNode*)aBookmarkNode {
  36   [super setBookmarkNode:aBookmarkNode];
  37   [self setURL:[self tempURL]];
  38 }
  39
  40 - (NSString*)URL {
  41   if (!bookmarkNode_)
  42     return tempURL_;
  43
  44   return base::SysUTF8ToNSString(bookmarkNode_->url().spec());
  45 }
  46
  47 - (void)setURL:(NSString*)aURL {
  48   // If a scripter sets a URL before the node is added, URL is saved at a
  49   // temporary location.
  50   if (!bookmarkNode_) {
  51     [self setTempURL:aURL];
  52     return;
  53   }
  54
  55   BookmarkModel* model = [self bookmarkModel];
  56   if (!model)
  57     return;
  58
  59   GURL url(base::SysNSStringToUTF8(aURL));
  60   if (!url.is_valid()) {
  61     AppleScript::SetError(AppleScript::errInvalidURL);
  62     return;
  63   }
  64
  65   model->SetURL(bookmarkNode_, url);
  66 }
  67
  68 @end