chrome/browser/ui/cocoa/constrained_window/constrained_window_alert_unittest.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_alert.h"
   6
   7 #import "chrome/browser/ui/cocoa/cocoa_test_helper.h"
   8 #import "testing/gtest_mac.h"
   9
  10 class ConstrainedWindowAlertTest : public CocoaTest {
  11 };
  12
  13 @interface ConstrainedWindowAlertTestTarget : NSObject {
  14  @private
  15   int linkClickedCount_;
  16 }
  17 @property(nonatomic, readonly) int linkClickedCount;
  18
  19 - (void)onLinkClicked:(id)sender;
  20 @end
  21
  22 @implementation ConstrainedWindowAlertTestTarget
  23
  24 @synthesize linkClickedCount = linkClickedCount_;
  25
  26 - (void)onLinkClicked:(id)sender {
  27   ++linkClickedCount_;
  28 }
  29
  30 @end
  31
  32 // Test showing the alert.
  33 TEST_F(ConstrainedWindowAlertTest, Show) {
  34   base::scoped_nsobject<ConstrainedWindowAlert> alert(
  35       [[ConstrainedWindowAlert alloc] init]);
  36   EXPECT_TRUE([alert window]);
  37   EXPECT_TRUE([alert closeButton]);
  38
  39   [alert setMessageText:@"Message text"];
  40   [alert setInformativeText:@"Informative text"];
  41   [alert addButtonWithTitle:@"OK" keyEquivalent:@"" target:nil action:NULL];
  42   [alert addButtonWithTitle:@"Cancel" keyEquivalent:@"" target:nil action:NULL];
  43
  44   [alert layout];
  45   [[alert window] makeKeyAndOrderFront:nil];
  46 }
  47
  48 // Test showing the alert with no buttons.
  49 TEST_F(ConstrainedWindowAlertTest, NoButtons) {
  50   base::scoped_nsobject<ConstrainedWindowAlert> alert(
  51       [[ConstrainedWindowAlert alloc] init]);
  52   [alert layout];
  53   [[alert window] makeKeyAndOrderFront:nil];
  54 }
  55
  56 // Test adding an accessory view to an alert.
  57 TEST_F(ConstrainedWindowAlertTest, AccessoryView) {
  58   base::scoped_nsobject<ConstrainedWindowAlert> alert(
  59       [[ConstrainedWindowAlert alloc] init]);
  60   [alert addButtonWithTitle:@"OK" keyEquivalent:@"" target:nil action:NULL];
  61   [alert addButtonWithTitle:@"Cancel" keyEquivalent:@"" target:nil action:NULL];
  62
  63   NSRect view_rect = NSMakeRect(0, 0, 700, 300);
  64   base::scoped_nsobject<NSView> view([[NSView alloc] initWithFrame:view_rect]);
  65   EXPECT_FALSE([alert accessoryView]);
  66   [alert setAccessoryView:view];
  67   EXPECT_NSEQ([alert accessoryView], view);
  68
  69   [alert layout];
  70   NSRect window_rect = [[alert window] frame];
  71   EXPECT_GT(NSWidth(window_rect), NSWidth(view_rect));
  72   EXPECT_GT(NSHeight(window_rect), NSHeight(view_rect));
  73
  74   [[alert window] makeKeyAndOrderFront:nil];
  75 }
  76
  77 // Test adding a link to an alert.
  78 TEST_F(ConstrainedWindowAlertTest, LinkView) {
  79   base::scoped_nsobject<ConstrainedWindowAlert> alert(
  80       [[ConstrainedWindowAlert alloc] init]);
  81   base::scoped_nsobject<ConstrainedWindowAlertTestTarget> target(
  82       [[ConstrainedWindowAlertTestTarget alloc] init]);
  83
  84   [alert layout];
  85   NSRect initial_window_rect = [[alert window] frame];
  86
  87   EXPECT_EQ(nil, [alert linkView]);
  88   NSString* linkText = @"Text of the link";
  89   [alert setLinkText:linkText
  90               target:target.get()
  91               action:@selector(onLinkClicked:)];
  92   EXPECT_EQ([linkText length], [[[alert linkView] title] length]);
  93
  94   [alert layout];
  95   NSRect window_rect = [[alert window] frame];
  96
  97   EXPECT_GT(NSHeight(window_rect), NSHeight(initial_window_rect));
  98
  99   [[alert window] makeKeyAndOrderFront:nil];
 100
 101   [[alert linkView] performClick:nil];
 102   EXPECT_EQ(1, [target linkClickedCount]);
 103 }