chrome/browser/ui/cocoa/toolbar/back_forward_menu_controller.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/toolbar/back_forward_menu_controller.h"
   6
   7 #include "base/logging.h"
   8 #include "base/memory/scoped_ptr.h"
   9 #include "base/strings/sys_string_conversions.h"
  10 #import "chrome/browser/ui/cocoa/menu_button.h"
  11 #include "chrome/browser/ui/toolbar/back_forward_menu_model.h"
  12 #import "ui/events/event_utils.h"
  13 #include "ui/gfx/image/image.h"
  14
  15 using base::SysUTF16ToNSString;
  16
  17 @implementation BackForwardMenuController
  18
  19 // Accessors and mutators:
  20
  21 @synthesize type = type_;
  22
  23 // Own methods:
  24
  25 - (id)initWithBrowser:(Browser*)browser
  26             modelType:(BackForwardMenuType)type
  27                button:(MenuButton*)button {
  28   if ((self = [super init])) {
  29     type_ = type;
  30     button_ = button;
  31     model_.reset(new BackForwardMenuModel(browser, type_));
  32     DCHECK(model_.get());
  33     backForwardMenu_.reset([[NSMenu alloc] initWithTitle:@""]);
  34     DCHECK(backForwardMenu_.get());
  35     [backForwardMenu_ setDelegate:self];
  36
  37     [button_ setAttachedMenu:backForwardMenu_];
  38     [button_ setOpenMenuOnClick:NO];
  39   }
  40   return self;
  41 }
  42
  43 - (void)browserWillBeDestroyed {
  44   [button_ setAttachedMenu:nil];
  45   [backForwardMenu_ setDelegate:nil];
  46   backForwardMenu_.reset();
  47   model_.reset();
  48 }
  49
  50 // Methods as delegate:
  51
  52 // Called by backForwardMenu_ just before tracking begins.
  53 //TODO(viettrungluu): should we do anything for chapter stops (see model)?
  54 - (void)menuNeedsUpdate:(NSMenu*)menu {
  55   DCHECK(menu == backForwardMenu_);
  56
  57   // Remove old menu items (backwards order is as good as any).
  58   for (NSInteger i = [menu numberOfItems]; i > 0; i--)
  59     [menu removeItemAtIndex:(i - 1)];
  60
  61   // 0-th item must be blank. (This is because we use a pulldown list, for which
  62   // Cocoa uses the 0-th item as "title" in the button.)
  63   [menu insertItemWithTitle:@""
  64                      action:nil
  65               keyEquivalent:@""
  66                     atIndex:0];
  67   for (int menuID = 0; menuID < model_->GetItemCount(); menuID++) {
  68     if (model_->IsSeparator(menuID)) {
  69       [menu insertItem:[NSMenuItem separatorItem]
  70                atIndex:(menuID + 1)];
  71     } else {
  72       // Create a menu item with the right label.
  73       NSMenuItem* menuItem = [[NSMenuItem alloc]
  74               initWithTitle:SysUTF16ToNSString(model_->GetLabelAt(menuID))
  75                      action:nil
  76               keyEquivalent:@""];
  77       [menuItem autorelease];
  78
  79       gfx::Image icon;
  80       // Icon (if it has one).
  81       if (model_->GetIconAt(menuID, &icon))
  82         [menuItem setImage:icon.ToNSImage()];
  83
  84       // This will make it call our |-executeMenuItem:| method. We store the
  85       // |menuID| (or |menu_id|) in the tag.
  86       [menuItem setTag:menuID];
  87       [menuItem setTarget:self];
  88       [menuItem setAction:@selector(executeMenuItem:)];
  89
  90       // Put it in the menu!
  91       [menu insertItem:menuItem
  92                atIndex:(menuID + 1)];
  93     }
  94   }
  95 }
  96
  97 // Action methods:
  98
  99 - (void)executeMenuItem:(id)sender {
 100   DCHECK([sender isKindOfClass:[NSMenuItem class]]);
 101   int menuID = [sender tag];
 102   int event_flags = ui::EventFlagsFromNative([NSApp currentEvent]);
 103   model_->ActivatedAt(menuID, event_flags);
 104 }
 105
 106 @end  // @implementation BackForwardMenuController