chrome/chrome_repack_locales.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//tools/grit/repack.gni")
   8
   9 # Arguments:
  10 #
  11 #   locale
  12 #       Internal name of locale. e.g. "pt-BR"
  13 #
  14 #   output
  15 #       Output file name.
  16 #
  17 #   visibility
  18 #       Normal meaning.
  19 template("_repack_one_locale") {
  20   locale = invoker.locale
  21
  22   repack(target_name) {
  23     visibility = invoker.visibility
  24
  25     # Each input pak file should also have a deps line for completeness.
  26     sources = [
  27       "${root_gen_dir}/chrome/platform_locale_settings_${locale}.pak",
  28       "${root_gen_dir}/chrome/generated_resources_${locale}.pak",
  29       "${root_gen_dir}/chrome/locale_settings_${locale}.pak",
  30       "${root_gen_dir}/components/strings/components_strings_${locale}.pak",
  31     ]
  32     deps = [
  33       "//chrome/app/resources:platform_locale_settings",
  34       "//chrome/app:generated_resources",
  35       "//chrome/app/resources:locale_settings",
  36       "//components/strings",
  37     ]
  38
  39     if (use_ash) {
  40       sources += [
  41         "${root_gen_dir}/ash/strings/ash_strings_${locale}.pak",
  42       ]
  43       deps += [
  44         "//ash/strings",
  45       ]
  46     }
  47     if (is_chromeos) {
  48       sources += [
  49         "${root_gen_dir}/ui/chromeos/strings/ui_chromeos_strings_${locale}.pak",
  50         "${root_gen_dir}/remoting/resources/${locale}.pak",
  51       ]
  52       deps += [
  53         "//remoting/resources",
  54         "//ui/chromeos/strings",
  55       ]
  56     }
  57     if (!is_ios) {
  58       sources += [
  59         "${root_gen_dir}/content/app/strings/content_strings_${locale}.pak",
  60         "${root_gen_dir}/ui/strings/ui_strings_${locale}.pak",
  61         "${root_gen_dir}/ui/strings/app_locale_settings_${locale}.pak",
  62       ]
  63       deps += [
  64         "//content/app/strings",
  65         "//ui/strings:ui_strings",
  66         "//ui/strings:app_locale_settings",
  67       ]
  68     }
  69     if (enable_autofill_dialog && !is_ios && !is_android) {
  70       sources += [
  71         "${root_gen_dir}/third_party/libaddressinput/address_input_strings_${locale}.pak",
  72       ]
  73       deps += [
  74         "//third_party/libaddressinput:strings",
  75       ]
  76     }
  77     if (enable_extensions) {
  78       sources += [
  79         "${root_gen_dir}/device/bluetooth/device_bluetooth_strings_${locale}.pak",
  80         # TODO(jamescook): When Android stops building extensions code move
  81         # this to the OS != 'ios' and OS != 'android' section.
  82         "${root_gen_dir}/extensions/strings/extensions_strings_${locale}.pak",
  83       ]
  84       deps += [
  85         "//device/bluetooth:strings",
  86         "//extensions/strings",
  87       ]
  88     }
  89
  90     if (is_chrome_branded) {
  91       sources += [
  92         "${root_gen_dir}/chrome/google_chrome_strings_${locale}.pak",
  93       ]
  94       deps += [
  95         "//chrome/app:google_chrome_strings",
  96       ]
  97     } else {
  98       sources += [
  99         "${root_gen_dir}/chrome/chromium_strings_${locale}.pak",
 100       ]
 101       deps += [
 102         "//chrome/app:chromium_strings",
 103       ]
 104     }
 105
 106     output = invoker.output
 107   }
 108 }
 109
 110 # Creates an action to call the repack_locales script.
 111 #
 112 # The GYP version generates the locales in the "gen" directory and then copies
 113 # it to the root build directory. This isn't easy to express in a GN copy
 114 # rule since the files on Mac have a complex structure. So we generate the
 115 # files into the final place and skip the "gen" directory.
 116 #
 117 # This template uses GN's looping constructs to avoid the complex call to
 118 # chrome/tools/build/repack_locales.py which wraps the repack commands in the
 119 # GYP build.
 120 #
 121 # Arguments
 122 #
 123 #   input_locales
 124 #       List of locale names to use as inputs.
 125 #
 126 #   output_locales
 127 #       A list containing the corresponding output names for each of the
 128 #       input names. Mac uses different names in some cases.
 129 #
 130 #   visibility
 131 template("chrome_repack_locales") {
 132   # This is the name of the group below that will collect all the invidual
 133   # locale targets. External targets will depend on this.
 134   group_target_name = target_name
 135
 136   # GN's subscript is too stupid to do invoker.output_locales[foo] so we need
 137   # to make a copy and do output_locales[foo].
 138   output_locales = invoker.output_locales
 139
 140   # Collects all targets the loop generates.
 141   locale_targets = []
 142
 143   # This loop iterates over the input locales and also keeps a counter so it
 144   # can simultaneously iterate over the output locales (using GN's very
 145   # limited looping capabilities).
 146   current_index = 0
 147   foreach(input_locale, invoker.input_locales) {
 148     output_locale = output_locales[current_index]
 149
 150     # Compute the name of the target for the current file. Save it for the deps.
 151     current_name = "${target_name}_${input_locale}"
 152     locale_targets += [ ":$current_name" ]
 153
 154     _repack_one_locale(current_name) {
 155       visibility = [ ":$group_target_name" ]
 156       locale = input_locale
 157
 158       # Compute the output name. Mac uses a different location.
 159       if (is_mac || is_ios) {
 160         output = "${root_gen_dir}/repack/${output_locale}.lproj/locale.pak"
 161       } else {
 162         output = "${root_out_dir}/locales/${output_locale}.pak"
 163       }
 164     }
 165
 166     current_index = current_index + 1
 167   }
 168
 169   # The group that external targets depend on which collects all deps.
 170   group(group_target_name) {
 171     if (defined(invoker.visibility)) {
 172       visibility = invoker.visibility
 173     }
 174     deps = locale_targets
 175   }
 176 }