chrome/utility/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7
   8 gypi_values = exec_script(
   9     "//build/gypi_to_gn.py",
  10     [ rebase_path("../chrome_utility.gypi") ],
  11     "scope",
  12     [ "../chrome_utility.gypi" ])
  13
  14 static_library("utility") {
  15   sources = rebase_path(gypi_values.chrome_utility_sources, ".", "..")
  16   defines = []
  17
  18   public_deps = []
  19   deps = [
  20     "//base",
  21     "//components/strings",
  22     "//components/url_fixer",
  23     "//content/public/common",
  24     "//content/public/utility",
  25     "//media",
  26     "//skia",
  27     "//third_party/libxml",
  28     "//chrome:resources",
  29     "//chrome:strings",
  30     "//chrome/common",
  31   ]
  32
  33   if (!is_android) {
  34     sources += rebase_path(gypi_values.chrome_utility_importer_sources,
  35                            ".", "..")
  36   }
  37
  38   if (enable_extensions) {
  39     deps += [
  40       "//chrome/common/extensions/api",
  41       "//extensions/utility",
  42       #"//third_party/libexif",  TODO(GYP)
  43     ]
  44
  45     public_deps += [
  46       "//chrome/common/extensions/api",
  47     ]
  48
  49     sources += rebase_path(gypi_values.chrome_utility_extensions_sources,
  50                            ".", "..")
  51     sources += rebase_path(gypi_values.chrome_utility_shared_media_sources,
  52                            ".", "..")
  53
  54     if (is_win || is_mac) {
  55       sources += rebase_path(
  56           gypi_values.chrome_utility_win_mac_media_gallery_sources, ".", "..")
  57       deps += [ "//components/wifi" ]
  58     } else {
  59       sources += [ "image_writer/image_writer_stub.cc" ]
  60     }
  61
  62     if (is_mac) {
  63       sources += rebase_path(gypi_values.chrome_utility_mac_media_gallery_sources,
  64                              ".", "..")
  65     }
  66   }
  67
  68   if (use_openssl) {
  69     if (!is_win && !is_mac && !is_android) {
  70       sources -= [ "importer/nss_decryptor.cc" ]
  71     }
  72   } else {  # !use_openssl
  73     if (!is_win && !is_mac) {
  74       sources += [
  75         "importer/nss_decryptor_system_nss.cc",
  76         "importer/nss_decryptor_system_nss.h",
  77       ]
  78       deps += [
  79         "//crypto",
  80         "//crypto:platform",
  81       ]
  82     }
  83   }
  84
  85   if (!enable_print_preview) {
  86     sources -= [
  87       "printing_handler.cc",
  88       "printing_handler.h",
  89     ]
  90   }
  91
  92   if (!enable_mdns) {
  93     sources -= [
  94       "local_discovery/service_discovery_message_handler.cc",
  95       "local_discovery/service_discovery_message_handler.h",
  96     ]
  97   }
  98
  99   if (safe_browsing_mode == 1) {
 100     defines += [ "FULL_SAFE_BROWSING" ]
 101   }
 102 }