remoting/host/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//remoting/remoting_version.gni")
   8
   9 static_library("host") {
  10   gypi_values = exec_script(
  11       "//build/gypi_to_gn.py",
  12       [ rebase_path("../remoting_host_srcs.gypi")],
  13       "scope",
  14       [ "../remoting_host_srcs.gypi" ])
  15
  16   sources = rebase_path(
  17       gypi_values.remoting_host_sources, ".", "//remoting")
  18
  19   libs = []
  20
  21   configs += [ "//build/config/compiler:wexit_time_destructors" ]
  22
  23   defines = [ "WEBRTC_CHROMIUM_BUILD" ]
  24
  25   deps = [
  26     "//base:i18n",
  27     "//crypto",
  28     "//google_apis",
  29     "//ipc",
  30     "//remoting/base",
  31     "//remoting/protocol",
  32     "//remoting/resources",
  33     "//ui/events/platform",
  34     "//ui/events:dom4_keycode_converter",
  35   ]
  36
  37   if (is_linux) {
  38     libs += [ "pam" ]
  39   }
  40
  41   if (use_x11) {
  42     configs += [
  43       #TODO : (kelvinp) Add GTK to the configs.
  44       "//build/config/linux:x11",
  45     ]
  46   } else {
  47     sources -= [
  48       "clipboard_x11.cc",
  49       "linux/x_server_clipboard.cc",
  50       "linux/x_server_clipboard.h",
  51     ]
  52   }
  53
  54   if (is_chromeos) {
  55     deps += [
  56       "//cc",
  57       "//components/policy:policy_component_common",
  58       "//content",
  59       "//ppapi:ppapi_host",
  60       "//skia",
  61       "//ui/aura",
  62       "//ui/compositor",
  63       "//ui/events",
  64       "//ui/views",
  65     ]
  66
  67     if (use_ash) {
  68       deps += [ "//ash" ]
  69     }
  70
  71     if (use_ozone) {
  72       sources -= [
  73         "input_injector_x11.cc",
  74         "local_input_monitor_x11.cc",
  75       ]
  76     } else {
  77       sources -= [
  78         "chromeos/mouse_cursor_monitor_aura.cc",
  79         "chromeos/mouse_cursor_monitor_aura.h",
  80         "clipboard_x11.cc",
  81         "input_injector_chromeos.cc",
  82         "input_injector_chromeos.h",
  83         "linux/x_server_clipboard.cc",
  84         "linux/x_server_clipboard.h",
  85         "local_input_monitor_chromeos.cc",
  86       ]
  87     }
  88
  89     sources -= [
  90       "continue_window_linux.cc",
  91       "disconnect_window_linux.cc",
  92       "policy_hack/policy_watcher_linux.cc",
  93       "remoting_me2me_host.cc",
  94     ]
  95   }
  96
  97   if (is_mac) {
  98     defines += [
  99       "HOST_BUNDLE_NAME=\"$host_bundle_name\"",
 100       "PREFPANE_BUNDLE_NAME=\"$prefpane_bundle_name\"",
 101     ]
 102
 103     libs += [
 104       "Accelerate.framework",
 105       "libpam.a",
 106     ]
 107
 108     deps += [
 109       "//google_toolbox_for_mac"
 110     ]
 111   }
 112
 113   if (enable_webrtc) {
 114     deps += [
 115       "//third_party/libjingle:libpeerconnection",
 116       "//third_party/webrtc/modules/desktop_capture",
 117     ]
 118
 119     sources += rebase_path(
 120         gypi_values.remoting_cast_sources, ".", "//remoting")
 121   }
 122 }