media/midi/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//media/media_options.gni")
   9 import("//testing/test.gni")
  10
  11 if (is_android) {
  12   # For generate_jni().
  13   import("//build/config/android/rules.gni")
  14 }
  15
  16 # Common configuration for targets in the media/midi directory.
  17 config("midi_config") {
  18   if (use_alsa) {
  19     defines = [
  20       "USE_ALSA",
  21       "USE_UDEV",
  22     ]
  23   }
  24
  25   visibility = [ ":*" ]
  26 }
  27
  28 # USB MIDI specific source files that are used in Android port, and unit tests.
  29 # These can't easily be a source set because "midi" is a component and the
  30 # component export flags must always be the same.
  31 usb_midi_sources = [
  32   "midi_manager_usb.cc",
  33   "midi_manager_usb.h",
  34   "usb_midi_descriptor_parser.cc",
  35   "usb_midi_descriptor_parser.h",
  36   "usb_midi_device.h",
  37   "usb_midi_export.h",
  38   "usb_midi_input_stream.cc",
  39   "usb_midi_input_stream.h",
  40   "usb_midi_jack.h",
  41   "usb_midi_output_stream.cc",
  42   "usb_midi_output_stream.h",
  43 ]
  44
  45 # Android specific Java source files that are used to generate jni header files.
  46 if (is_android) {
  47   android_library("midi_java") {
  48     deps = [
  49       "//base:base_java",
  50     ]
  51
  52     DEPRECATED_java_in_dir = "java/src"
  53   }
  54
  55   generate_jni("midi_jni_headers") {
  56     sources = [
  57       "java/src/org/chromium/media/midi/UsbMidiDeviceAndroid.java",
  58       "java/src/org/chromium/media/midi/UsbMidiDeviceFactoryAndroid.java",
  59     ]
  60     jni_package = "media/midi"
  61   }
  62 }
  63
  64 component("midi") {
  65   sources = [
  66     "midi_export.h",
  67     "midi_manager.cc",
  68     "midi_manager.h",
  69     "midi_manager_mac.cc",
  70     "midi_manager_mac.h",
  71     "midi_manager_win.cc",
  72     "midi_manager_win.h",
  73     "midi_message_queue.cc",
  74     "midi_message_queue.h",
  75     "midi_message_util.cc",
  76     "midi_message_util.h",
  77     "midi_port_info.cc",
  78     "midi_port_info.h",
  79     "midi_scheduler.cc",
  80     "midi_scheduler.h",
  81   ]
  82
  83   configs += [ ":midi_config" ]
  84
  85   defines = [ "MIDI_IMPLEMENTATION" ]
  86   deps = [
  87     "//base",
  88   ]
  89   libs = []
  90
  91   if (is_android) {
  92     sources += [
  93                  "midi_jni_registrar.cc",
  94                  "midi_jni_registrar.h",
  95                  "midi_manager_android.cc",
  96                  "usb_midi_device_android.cc",
  97                  "usb_midi_device_android.h",
  98                  "usb_midi_device_factory_android.cc",
  99                  "usb_midi_device_factory_android.h",
 100                ] + usb_midi_sources
 101
 102     # Since the USB sources are part of the component.
 103     defines += [ "EXPORT_USB_MIDI" ]
 104
 105     deps += [
 106       "//base:i18n",
 107       ":midi_jni_headers",
 108     ]
 109   }
 110
 111   if (is_mac) {
 112     libs += [
 113       "CoreAudio.framework",
 114       "CoreMIDI.framework",
 115     ]
 116   }
 117
 118   if (is_win) {
 119     deps += [ "//device/usb" ]
 120   }
 121
 122   if (use_alsa && use_udev) {
 123     deps += [
 124       "//crypto",
 125       "//crypto:platform",
 126     ]
 127     libs += [ "asound" ]
 128     sources += [
 129       "midi_manager_alsa.cc",
 130       "midi_manager_alsa.h",
 131     ]
 132   }
 133
 134   if (use_udev) {
 135     deps += [ "//device/udev_linux" ]
 136   }
 137 }
 138
 139 # TODO(GYP): Delete this after we've converted everything to GN.
 140 # The _run targets exist only for compatibility w/ GYP.
 141 group("midi_unittests_run") {
 142   testonly = true
 143   deps = [
 144     ":midi_unittests",
 145   ]
 146 }
 147
 148 test("midi_unittests") {
 149   sources = [
 150     "midi_manager_unittest.cc",
 151     "midi_manager_usb_unittest.cc",
 152     "midi_message_queue_unittest.cc",
 153     "midi_message_util_unittest.cc",
 154     "usb_midi_descriptor_parser_unittest.cc",
 155     "usb_midi_input_stream_unittest.cc",
 156     "usb_midi_output_stream_unittest.cc",
 157   ]
 158
 159   configs += [ ":midi_config" ]
 160   deps = [
 161     ":midi",
 162     "//base/test/:run_all_unittests",
 163     "//base/test/:test_support",
 164     "//testing/gtest",
 165   ]
 166
 167   if (is_android) {
 168     isolate_file = "midi_unittests.isolate"
 169   }
 170
 171   if (!is_android) {
 172     sources += usb_midi_sources
 173   }
 174
 175   if (is_mac) {
 176     sources += [ "midi_manager_mac_unittest.cc" ]
 177   }
 178
 179   if (use_alsa && use_udev) {
 180     sources += [ "midi_manager_alsa_unittest.cc" ]
 181   }
 182
 183   if (use_x11) {
 184     deps += [ "//tools/xdisplaycheck" ]
 185   }
 186 }