extensions/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//extensions/extensions.gni")
   6 import("//testing/test.gni")
   7 import("//tools/grit/grit_rule.gni")
   8 import("//tools/grit/repack.gni")
   9
  10 assert(enable_extensions)
  11
  12 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  13 group("extensions_resources") {
  14   deps = [
  15     ":extensions_browser_resources",
  16     ":extensions_renderer_resources",
  17     ":extensions_resources_grd",
  18   ]
  19 }
  20
  21 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  22 #              (extensions_resources action)
  23 grit("extensions_resources_grd") {
  24   source = "extensions_resources.grd"
  25   outputs = [
  26     "grit/extensions_resources.h",
  27     "extensions_resources.pak",
  28   ]
  29 }
  30
  31 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  32 #              (extensions_browser_resources action)
  33 grit("extensions_browser_resources") {
  34   source = "browser/resources/extensions_browser_resources.grd"
  35   outputs = [
  36     "grit/extensions_browser_resources.h",
  37     "grit/extensions_browser_resources_map.cc",
  38     "grit/extensions_browser_resources_map.h",
  39     "extensions_browser_resources_100_percent.pak",
  40     "extensions_browser_resources_200_percent.pak",
  41   ]
  42   grit_flags = [
  43     "-E",
  44     "mojom_root=" + rebase_path(root_gen_dir),
  45   ]
  46 }
  47
  48 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  49 #              (extensions_renderer_resources action)
  50 grit("extensions_renderer_resources") {
  51   source = "renderer/resources/extensions_renderer_resources.grd"
  52   outputs = [
  53     "grit/extensions_renderer_resources.h",
  54     "extensions_renderer_resources.pak",
  55   ]
  56   grit_flags = [
  57     "-E",
  58     "mojom_root=" + rebase_path(root_gen_dir),
  59   ]
  60
  61   deps = [
  62     "//device/serial:serial_mojo",
  63     "//extensions/common:mojo",
  64     "//extensions/common/api:mojom",
  65   ]
  66 }
  67
  68 source_set("test_support") {
  69   testonly = true
  70   sources = rebase_path(extensions_gypi_values.extensions_test_support_sources,
  71                         ".",
  72                         "//extensions")
  73
  74   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  75   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  76
  77   deps = [
  78     ":extensions_resources",
  79     "//base",
  80     "//base:prefs_test_support",
  81     "//content/public/common",
  82     "//content/test:test_support",
  83     "//extensions/browser",
  84     "//extensions/common",
  85     "//extensions/common/api",
  86     "//extensions/common/api:api_registration",
  87     "//net:test_support",
  88     "//testing/gmock",
  89     "//testing/gtest",
  90   ]
  91
  92   public_deps = [
  93     "//content/public/browser",
  94     "//extensions/common/api/cast_channel:cast_channel_proto",
  95   ]
  96 }
  97
  98 # GYP version: //extensions/extensions.gyp:extensions_shell_and_test_pak
  99 repack("shell_and_test_pak") {
 100   sources = [
 101     "$root_gen_dir/blink/devtools_resources.pak",
 102     "$root_gen_dir/blink/public/resources/blink_resources.pak",
 103     "$root_gen_dir/content/app/strings/content_strings_en-US.pak",
 104     "$root_gen_dir/content/content_resources.pak",
 105     "$root_gen_dir/content/shell/shell_resources.pak",
 106     "$root_gen_dir/extensions/extensions_browser_resources_100_percent.pak",
 107     "$root_gen_dir/extensions/extensions_renderer_resources.pak",
 108     "$root_gen_dir/extensions/extensions_resources.pak",
 109     "$root_gen_dir/extensions/shell/app_shell_resources.pak",
 110     "$root_gen_dir/extensions/strings/extensions_strings_en-US.pak",
 111     "$root_gen_dir/ui/resources/ui_resources_100_percent.pak",
 112     "$root_gen_dir/ui/strings/app_locale_settings_en-US.pak",
 113     "$root_gen_dir/ui/strings/ui_strings_en-US.pak",
 114   ]
 115
 116   output = "$root_out_dir/extensions_shell_and_test.pak"
 117
 118   deps = [
 119     ":extensions_resources",
 120     "//content:resources",
 121     "//content/browser/devtools:devtools_resources",
 122     "//content/shell:resources",
 123     "//extensions/shell:resources",
 124     "//extensions/strings",
 125     "//third_party/WebKit/public:resources",
 126     "//ui/resources",
 127     "//ui/strings",
 128   ]
 129 }
 130
 131 test("extensions_unittests") {
 132   sources =
 133       rebase_path(extensions_tests_gypi_values.extensions_unittests_sources,
 134                   ".",
 135                   "//extensions")
 136
 137   sources += [
 138     # TODO(rockot): DisplayInfoProvider::Create() is only implemented in Chrome
 139     # and app_shell. This is wrong.
 140     "shell/browser/shell_display_info_provider.cc",
 141   ]
 142
 143   deps = [
 144     ":extensions_resources",
 145     ":shell_and_test_pak",
 146     ":test_support",
 147     "//base",
 148     "//base:prefs_test_support",
 149     "//base/test:test_support",
 150     "//components/keyed_service/content",
 151     "//components/user_prefs",
 152     "//content/test:test_support",
 153     "//device/bluetooth:mocks",
 154     "//device/serial",
 155     "//device/serial:test_support",
 156     "//extensions/common",
 157     "//extensions/common/api/cast_channel:cast_channel_proto",
 158     "//extensions/renderer",
 159     "//extensions/strings",
 160     "//extensions/utility",
 161     "//mojo/environment:chromium",
 162     "//testing/gmock",
 163     "//testing/gtest",
 164     "//third_party/leveldatabase",
 165     "//third_party/mojo/src/mojo/edk/js",
 166     "//third_party/mojo/src/mojo/edk/system",
 167     "//third_party/mojo/src/mojo/public/cpp/bindings",
 168     "//third_party/mojo/src/mojo/public/interfaces/application",
 169   ]
 170
 171   if (is_win) {
 172     deps += [ "//base/allocator" ]
 173   }
 174
 175   if (is_chromeos) {
 176     sources += [
 177       # TODO(rockot): There are two implementations of VpnServiceFactory, a
 178       # stub in app_shell and a real one in Chrome. This is wrong.
 179       "shell/browser/api/vpn_provider/vpn_service_factory.cc",
 180     ]
 181
 182     deps += [ "//chromeos:test_support" ]
 183   }
 184 }
 185
 186 test("extensions_browsertests") {
 187   sources =
 188       rebase_path(extensions_tests_gypi_values.extensions_browsertests_sources,
 189                   ".",
 190                   "//extensions")
 191
 192   defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
 193
 194   deps = [
 195     ":test_support",
 196     "shell:app_shell_lib",
 197
 198     # TODO(yoz): find the right deps
 199     "//base",
 200     "//base:prefs_test_support",
 201     "//base/test:test_support",
 202     "//components/storage_monitor:test_support",
 203     "//content/test:test_support",
 204     "//device/bluetooth:mocks",
 205     "//mojo/environment:chromium",
 206     "//testing/gmock",
 207     "//testing/gtest",
 208     "//third_party/mojo/src/mojo/edk/js",
 209     "//third_party/mojo/src/mojo/edk/system",
 210     "//third_party/mojo/src/mojo/public/cpp/bindings",
 211   ]
 212
 213   if (is_win) {
 214     deps += [ "//base/allocator" ]
 215   }
 216
 217   if (is_mac) {
 218     deps += [ "shell:app_shell" ]  # Needed for App Shell.app's Helper.
 219   }
 220 }