build/config/android/config.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This file contains common system config stuff for the Android build.
   6
   7 if (is_android) {
   8   has_chrome_android_internal =
   9       exec_script("//build/dir_exists.py",
  10                   [ rebase_path("//clank", root_build_dir) ],
  11                   "string") == "True"
  12
  13   if (has_chrome_android_internal) {
  14     import("//clank/config.gni")
  15   }
  16
  17   if (!defined(default_android_sdk_root)) {
  18     default_android_sdk_root = "//third_party/android_tools/sdk"
  19     default_android_sdk_version = "22"
  20     default_android_sdk_build_tools_version = "22.0.0"
  21   }
  22
  23   if (!defined(google_play_services_library)) {
  24     google_play_services_library =
  25         "//third_party/android_tools:google_play_services_default_java"
  26   }
  27
  28   declare_args() {
  29     android_sdk_root = default_android_sdk_root
  30     android_sdk_version = default_android_sdk_version
  31     android_sdk_build_tools_version = default_android_sdk_build_tools_version
  32
  33     android_default_keystore_path =
  34         "//build/android/ant/chromium-debug.keystore"
  35     android_default_keystore_name = "chromiumdebugkey"
  36     android_default_keystore_password = "chromium"
  37
  38     # This is a unique identifier for a given build. It's used for
  39     # identifying various build artifacts corresponding to a particular build of
  40     # chrome (e.g. where to find archived symbols).
  41     android_chrome_build_id = "\"\""
  42
  43     # Set to true to run findbugs on JAR targets.
  44     run_findbugs = false
  45
  46     # Set to true to enable the Errorprone compiler
  47     use_errorprone_java_compiler = false
  48   }
  49
  50   # Host stuff -----------------------------------------------------------------
  51
  52   # Defines the name the Android build gives to the current host CPU
  53   # architecture, which is different than the names GN uses.
  54   if (host_cpu == "x64") {
  55     android_host_arch = "x86_64"
  56   } else if (host_cpu == "x86") {
  57     android_host_arch = "x86"
  58   } else {
  59     assert(false, "Need Android toolchain support for your build CPU arch.")
  60   }
  61
  62   # Defines the name the Android build gives to the current host CPU
  63   # architecture, which is different than the names GN uses.
  64   if (host_os == "linux") {
  65     android_host_os = "linux"
  66   } else if (host_os == "mac") {
  67     android_host_os = "darwin"
  68   } else {
  69     assert(false, "Need Android toolchain support for your build OS.")
  70   }
  71
  72   # Directories and files ------------------------------------------------------
  73   #
  74   # We define may of the dirs strings here for each output architecture (rather
  75   # than just the current one) since these are needed by the Android toolchain
  76   # file to define toolchains for all possible targets in one pass.
  77
  78   android_sdk = "${android_sdk_root}/platforms/android-${android_sdk_version}"
  79
  80   # Path to the Android NDK and SDK.
  81   android_ndk_root = "//third_party/android_tools/ndk"
  82   android_ndk_include_dir = "$android_ndk_root/usr/include"
  83
  84   android_sdk = "${android_sdk_root}/platforms/android-${android_sdk_version}"
  85
  86   android_sdk_tools = "${android_sdk_root}/tools"
  87   android_sdk_build_tools =
  88       "${android_sdk_root}/build-tools/$android_sdk_build_tools_version"
  89
  90   # Path to the SDK's android.jar
  91   android_sdk_jar = "$android_sdk/android.jar"
  92
  93   zipalign_path = "$android_sdk_build_tools/zipalign"
  94
  95   # Subdirectories inside android_ndk_root that contain the sysroot for the
  96   # associated platform.
  97   _android_api_level = 16
  98   x86_android_sysroot_subdir =
  99       "platforms/android-${_android_api_level}/arch-x86"
 100   arm_android_sysroot_subdir =
 101       "platforms/android-${_android_api_level}/arch-arm"
 102   mips_android_sysroot_subdir =
 103       "platforms/android-${_android_api_level}/arch-mips"
 104   _android64_api_level = 21
 105   x86_64_android_sysroot_subdir =
 106       "platforms/android-${_android64_api_level}/arch-x86_64"
 107   arm64_android_sysroot_subdir =
 108       "platforms/android-${_android64_api_level}/arch-arm64"
 109   mips64_android_sysroot_subdir =
 110       "platforms/android-${_android64_api_level}/arch-mips64"
 111
 112   # Toolchain root directory for each build. The actual binaries are inside
 113   # a "bin" directory inside of these.
 114   _android_toolchain_version = "4.9"
 115   x86_android_toolchain_root = "$android_ndk_root/toolchains/x86-${_android_toolchain_version}/prebuilt/${android_host_os}-${android_host_arch}"
 116   arm_android_toolchain_root = "$android_ndk_root/toolchains/arm-linux-androideabi-${_android_toolchain_version}/prebuilt/${android_host_os}-${android_host_arch}"
 117   mips_android_toolchain_root = "$android_ndk_root/toolchains/mipsel-linux-android-${_android_toolchain_version}/prebuilt/${android_host_os}-${android_host_arch}"
 118   x86_64_android_toolchain_root = "$android_ndk_root/toolchains/x86_64-${_android_toolchain_version}/prebuilt/${android_host_os}-${android_host_arch}"
 119   arm64_android_toolchain_root = "$android_ndk_root/toolchains/aarch64-${_android_toolchain_version}/prebuilt/${android_host_os}-${android_host_arch}"
 120   mips64_android_toolchain_root = "$android_ndk_root/toolchains/mips64el-${_android_toolchain_version}/prebuilt/${android_host_os}-${android_host_arch}"
 121
 122   # Location of libgcc. This is only needed for the current GN toolchain, so we
 123   # only need to define the current one, rather than one for every platform
 124   # like the toolchain roots.
 125   if (current_cpu == "x86") {
 126     android_prebuilt_arch = "android-x86"
 127     _binary_prefix = "i686-linux-android"
 128     android_toolchain_root = "$x86_android_toolchain_root"
 129     android_libgcc_file = "$android_toolchain_root/lib/gcc/i686-linux-android/${_android_toolchain_version}/libgcc.a"
 130   } else if (current_cpu == "arm") {
 131     android_prebuilt_arch = "android-arm"
 132     _binary_prefix = "arm-linux-androideabi"
 133     android_toolchain_root = "$arm_android_toolchain_root"
 134     android_libgcc_file = "$android_toolchain_root/lib/gcc/arm-linux-androideabi/${_android_toolchain_version}/libgcc.a"
 135   } else if (current_cpu == "mipsel") {
 136     android_prebuilt_arch = "android-mips"
 137     _binary_prefix = "mipsel-linux-android"
 138     android_toolchain_root = "$mips_android_toolchain_root"
 139     android_libgcc_file = "$android_toolchain_root/lib/gcc/mipsel-linux-android/${_android_toolchain_version}/libgcc.a"
 140   } else if (current_cpu == "x64") {
 141     android_prebuilt_arch = "android-x86_64"
 142     _binary_prefix = "x86_64-linux-android"
 143     android_toolchain_root = "$x86_64_android_toolchain_root"
 144     android_libgcc_file = "$android_toolchain_root/lib/gcc/x86_64-linux-android/${_android_toolchain_version}/libgcc.a"
 145   } else if (current_cpu == "arm64") {
 146     android_prebuilt_arch = "android-arm64"
 147     _binary_prefix = "aarch64-linux-android"
 148     android_toolchain_root = "$arm64_android_toolchain_root"
 149     android_libgcc_file = "$android_toolchain_root/lib/gcc/aarch64-linux-android/${_android_toolchain_version}/libgcc.a"
 150   } else if (current_cpu == "mips64el") {
 151     android_prebuilt_arch = "android-mips64"
 152     _binary_prefix = "mips64el-linux-android"
 153     android_toolchain_root = "$mips64_android_toolchain_root"
 154     android_libgcc_file = "$android_toolchain_root/lib/gcc/mips64el-linux-android/${_android_toolchain_version}/libgcc.a"
 155   } else {
 156     assert(false, "Need android libgcc support for your target arch.")
 157   }
 158
 159   android_tool_prefix = "$android_toolchain_root/bin/$_binary_prefix-"
 160   android_readelf = "${android_tool_prefix}readelf"
 161   android_objcopy = "${android_tool_prefix}objcopy"
 162   android_gdbserver =
 163       "$android_ndk_root/prebuilt/$android_prebuilt_arch/gdbserver/gdbserver"
 164
 165   # Toolchain stuff ------------------------------------------------------------
 166
 167   android_libcpp_root = "$android_ndk_root/sources/cxx-stl/llvm-libc++"
 168   if (is_component_build) {
 169     android_libcpp_library = "c++_shared"
 170     # By appending .cr, we prevent name collisions with libraries already
 171     # loaded by the Android zygote.
 172     android_product_extension = ".cr.so"
 173   } else {
 174     android_libcpp_library = "c++_static"
 175     android_product_extension = ".so"
 176   }
 177
 178   # ABI ------------------------------------------------------------------------
 179
 180   if (current_cpu == "x86") {
 181     android_app_abi = "x86"
 182   } else if (current_cpu == "arm") {
 183     import("//build/config/arm.gni")
 184     if (arm_version < 7) {
 185       android_app_abi = "armeabi"
 186     } else {
 187       android_app_abi = "armeabi-v7a"
 188     }
 189   } else if (current_cpu == "mipsel") {
 190     android_app_abi = "mips"
 191   } else if (current_cpu == "x64") {
 192     android_app_abi = "x86_64"
 193   } else if (current_cpu == "arm64") {
 194     android_app_abi = "arm64-v8a"
 195   } else if (current_cpu == "mips64el") {
 196     android_app_abi = "mips64"
 197   } else {
 198     assert(false, "Unknown Android ABI: " + current_cpu)
 199   }
 200 }