build/config/linux/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/linux/pkg_config.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/sysroot.gni")
   8 import("//build/config/ui.gni")
   9 import("//tools/generate_library_loader/generate_library_loader.gni")
  10
  11 gypi_values = exec_script("//build/gypi_to_gn.py",
  12                           [ rebase_path("../../linux/system.gyp") ],
  13                           "scope",
  14                           [ "../../linux/system.gyp" ])
  15
  16 config("sdk") {
  17   if (sysroot != "") {
  18     cflags = [ "--sysroot=" + sysroot ]
  19     ldflags = [ "--sysroot=" + sysroot ]
  20
  21     # Need to get some linker flags out of the sysroot.
  22     ldflags += [ exec_script("sysroot_ld_path.py",
  23                              [
  24                                rebase_path("//build/linux/sysroot_ld_path.sh",
  25                                            root_build_dir),
  26                                sysroot,
  27                              ],
  28                              "value") ]
  29   }
  30
  31   # Set here because OS_CHROMEOS cannot be autodetected in build_config.h like
  32   # OS_LINUX and the like.
  33   if (is_chromeos) {
  34     defines = [ "OS_CHROMEOS" ]
  35   }
  36 }
  37
  38 config("fontconfig") {
  39   libs = [ "fontconfig" ]
  40 }
  41
  42 pkg_config("freetype2") {
  43   packages = [ "freetype2" ]
  44 }
  45
  46 pkg_config("glib") {
  47   packages = [
  48     "glib-2.0",
  49     "gmodule-2.0",
  50     "gobject-2.0",
  51     "gthread-2.0",
  52   ]
  53 }
  54
  55 pkg_config("pangocairo") {
  56   packages = [ "pangocairo" ]
  57 }
  58
  59 pkg_config("pangoft2") {
  60   packages = [ "pangoft2" ]
  61 }
  62
  63 # Note: if your target also depends on //dbus, you don't need to add this
  64 # config (it will get added automatically if you depend on //dbus).
  65 pkg_config("dbus") {
  66   packages = [ "dbus-1" ]
  67 }
  68
  69 if (use_evdev_gestures) {
  70   pkg_config("libevdev-cros") {
  71     packages = [ "libevdev-cros" ]
  72   }
  73
  74   pkg_config("libgestures") {
  75     packages = [ "libgestures" ]
  76   }
  77 }
  78
  79 config("x11") {
  80   libs = [
  81     "X11",
  82     "Xcomposite",
  83     "Xcursor",
  84     "Xdamage",
  85     "Xext",
  86     "Xfixes",
  87     "Xi",
  88     "Xrender",
  89     "Xtst",
  90   ]
  91 }
  92
  93 config("xcomposite") {
  94   libs = [ "Xcomposite" ]
  95 }
  96
  97 config("xext") {
  98   libs = [ "Xext" ]
  99 }
 100
 101 config("xrandr") {
 102   libs = [ "Xrandr" ]
 103 }
 104
 105 config("xscrnsaver") {
 106   libs = [ "Xss" ]
 107 }
 108
 109 config("xfixes") {
 110   libs = [ "Xfixes" ]
 111 }
 112
 113 config("libcap") {
 114   libs = [ "cap" ]
 115 }
 116
 117 config("xi") {
 118   libs = [ "Xi" ]
 119 }
 120
 121 config("xtst") {
 122   libs = [ "Xtst" ]
 123 }
 124
 125 config("libresolv") {
 126   libs = [ "resolv" ]
 127 }
 128
 129 # CrOS doesn't install GTK, gconf or any gnome packages.
 130 if (!is_chromeos) {
 131   # These packages should _only_ be expected when building for a target.
 132   # If these extra checks are not run, gconf is required when building host
 133   # tools for a CrOS build.
 134   if (current_toolchain == default_toolchain) {
 135     pkg_config("atk") {
 136       packages = [ "atk" ]
 137       atk_lib_dir = exec_script(pkg_config_script,
 138                                 [
 139                                   "--libdir",
 140                                   "atk",
 141                                 ],
 142                                 "string")
 143       defines = [ "ATK_LIB_DIR=\"$atk_lib_dir\"" ]
 144     }
 145
 146     # gn orders flags on a target before flags from configs. The default config
 147     # adds -Wall, and these flags have to be after -Wall -- so they need to
 148     # come from a config and can't be on the target directly.
 149     config("atk_warnings") {
 150       cflags = [
 151         # glib uses the pre-c++11 typedef-as-static_assert hack.
 152         "-Wno-unused-local-typedef",
 153
 154         # G_DEFINE_TYPE automatically generates a *get_instance_private
 155         # inline function after glib 2.37. That's unused. Prevent to
 156         # complain about it.
 157         "-Wno-unused-function",
 158       ]
 159     }
 160
 161     pkg_config("gconf") {
 162       packages = [ "gconf-2.0" ]
 163       defines = [ "USE_GCONF" ]
 164     }
 165   }
 166 }
 167
 168 # If brlapi isn't needed, don't require it to be installed.
 169 if (use_brlapi) {
 170   config("brlapi_config") {
 171     defines = [ "USE_BRLAPI" ]
 172   }
 173
 174   # TODO(GYP) linux_link_brlapi support. Is this needed?
 175   generate_library_loader("libbrlapi") {
 176     name = "LibBrlapiLoader"
 177     output_h = "libbrlapi.h"
 178     output_cc = "libbrlapi_loader.cc"
 179     header = "<brlapi.h>"
 180     config = ":brlapi_config"
 181
 182     functions = gypi_values.libbrlapi_functions
 183   }
 184 }
 185
 186 pkg_config("gio_config") {
 187   packages = [ "gio-2.0" ]
 188
 189   # glib >=2.40 deprecate g_settings_list_schemas in favor of
 190   # g_settings_schema_source_list_schemas. This function is not available on
 191   # earlier versions that we still need to support (specifically, 2.32), so
 192   # disable the warning with the GLIB_DISABLE_DEPRECATION_WARNINGS define.
 193   # TODO(mgiuca): Remove this suppression when we drop support for Ubuntu 13.10
 194   # (saucy) and earlier. Update the code to use
 195   # g_settings_schema_source_list_schemas instead.
 196   defines = [
 197     "USE_GIO",
 198     "GLIB_DISABLE_DEPRECATION_WARNINGS",
 199   ]
 200
 201   # TODO(brettw) Theoretically I think ignore_libs should be set so that we
 202   # don't link directly to GIO and use the loader generated below. But the gio
 203   # target in GYP doesn't make any sense to me and appears to link directly to
 204   # GIO in addition to making a loader. This this uncommented, the link in
 205   # component build fails, so I think this is closer to the GYP build.
 206   #ignore_libs = true  # Loader generated below.
 207 }
 208
 209 if (is_desktop_linux) {
 210   # This generates a target named "gio".
 211   generate_library_loader("gio") {
 212     name = "LibGioLoader"
 213     output_h = "libgio.h"
 214     output_cc = "libgio_loader.cc"
 215     header = "<gio/gio.h>"
 216     config = ":gio_config"
 217
 218     functions = gypi_values.libgio_functions
 219   }
 220 }
 221
 222 # This generates a target named "libpci".
 223 generate_library_loader("libpci") {
 224   name = "LibPciLoader"
 225   output_h = "libpci.h"
 226   output_cc = "libpci_loader.cc"
 227   header = "<pci/pci.h>"
 228
 229   functions = gypi_values.libpci_functions
 230 }
 231
 232 # Looking for libspeechd? Use //third_party/speech-dispatcher
 233
 234 # This generates a target named "udev0_loader".
 235 generate_library_loader("udev0_loader") {
 236   name = "LibUdev0Loader"
 237   output_h = "libudev0.h"
 238   output_cc = "libudev0_loader.cc"
 239   header = "\"third_party/libudev/libudev0.h\""
 240
 241   functions = gypi_values.libudev_functions
 242 }
 243
 244 # This generates a target named "udev1_loader".
 245 generate_library_loader("udev1_loader") {
 246   name = "LibUdev1Loader"
 247   output_h = "libudev1.h"
 248   output_cc = "libudev1_loader.cc"
 249   header = "\"third_party/libudev/libudev1.h\""
 250
 251   functions = gypi_values.libudev_functions
 252 }
 253
 254 group("udev") {
 255   deps = [
 256     ":udev0_loader",
 257     ":udev1_loader",
 258   ]
 259 }