chrome/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8
   9 # //build/config/android/rules.gni imports //tools/grit/grit_rule.gni, which
  10 # produces a conflict for the "grit" template so we have to only include one.
  11 if (is_android) {
  12   import("//build/config/android/rules.gni")
  13 } else {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16 if (is_desktop_linux) {
  17   import("//build/config/linux/pkg_config.gni")
  18 }
  19
  20 about_credits_file = "$target_gen_dir/about_credits.html"
  21 additional_modules_list_file =
  22     "$root_gen_dir/chrome/browser/internal/additional_modules_list.txt"
  23
  24 gypi_values = exec_script("//build/gypi_to_gn.py",
  25                           [ rebase_path("../chrome_browser.gypi") ],
  26                           "scope",
  27                           [ "../chrome_browser.gypi" ])
  28
  29 if (is_desktop_linux) {
  30   # Gnome-keyring is normally dynamically loaded. The gnome_keyring config
  31   # will set this up.
  32   pkg_config("gnome_keyring") {
  33     packages = [ "gnome-keyring-1" ]
  34     defines = [
  35       "USE_GNOME_KEYRING",
  36       "DLOPEN_GNOME_KEYRING",
  37     ]
  38     ignore_libs = true
  39   }
  40
  41   # If you want to link gnome-keyring directly (use only for unit tests)
  42   # ADDITIONALLY add this config on top of ":gnome_keyring". pkg-config is a
  43   # bit slow, so prefer not to run it again. In practice, gnome-keyring's libs
  44   # are just itself and common gnome ones we link already, so we can get away
  45   # with additionally just coding the library name here.
  46   config("gnome_keyring_direct") {
  47     libs = [ "gnome-keyring" ]
  48   }
  49 }
  50
  51 static_library("browser") {
  52   configs += [
  53     "//build/config/compiler:wexit_time_destructors",
  54     "//third_party/WebKit/public:debug_devtools",
  55   ]
  56   defines = []
  57   sources = []
  58   libs = []
  59   ldflags = []
  60
  61   # iOS/non-iOS shared deps. New dependencies should generally be added in the
  62   # non-iOS deps below.
  63   public_deps = [
  64     "//components/autofill/core/browser",
  65     "//content/public/browser",
  66     "//sql",
  67     "//sync",
  68   ]
  69   deps = [
  70     "//base/allocator",
  71     "//chrome:extra_resources",
  72     "//chrome:resources",
  73     "//chrome:strings",
  74     "//chrome/app:generated_resources_map",
  75     "//chrome/app/resources:platform_locale_settings",
  76     "//chrome/app/theme:theme_resources",
  77     "//chrome/browser/net:cert_logger_proto",
  78     "//chrome/browser/net:probe_message_proto",
  79     "//chrome/browser/ui",
  80     "//chrome/common",
  81     "//chrome/common/net",
  82     "//components/autofill/core/browser",
  83     "//components/bookmarks/browser",
  84     "//components/captive_portal",
  85     "//components/cloud_devices/common",
  86     "//components/component_updater",
  87     "//components/content_settings/core/browser",
  88     "//components/content_settings/core/common",
  89     "//components/crx_file",
  90     "//components/data_reduction_proxy/core/browser",
  91     "//components/device_event_log",
  92     "//components/domain_reliability",
  93     "//components/enhanced_bookmarks",
  94     "//components/favicon_base",
  95     "//components/favicon/core",
  96     "//components/feedback",
  97     "//components/gcm_driver",
  98     "//components/google/core/browser",
  99     "//components/handoff",
 100     "//components/history/core/browser",
 101     "//components/history/core/browser:proto",
 102     "//components/history/core/common",
 103     "//components/infobars/core",
 104     "//components/invalidation",
 105     "//components/metrics:gpu",
 106     "//components/metrics:net",
 107     "//components/metrics:profiler",
 108     "//components/metrics/proto:proto",
 109     "//components/navigation_metrics",
 110     "//components/network_time",
 111     "//components/omnibox",
 112     "//components/os_crypt",
 113     "//components/packed_ct_ev_whitelist",
 114     "//components/password_manager/core/browser",
 115     "//components/password_manager/core/common",
 116     "//components/policy:policy_component",
 117     "//components/precache/core",
 118     "//components/query_parser",
 119     "//components/rappor",
 120     "//components/renderer_context_menu",
 121     "//components/search",
 122     "//components/search_engines",
 123     "//components/search_provider_logos",
 124     "//components/signin/core/browser",
 125     "//components/startup_metric_utils",
 126     "//components/strings",
 127     "//components/suggestions",
 128     "//components/sync_driver",
 129     "//components/translate/core/browser",
 130     "//components/translate/core/common",
 131     "//components/ui/zoom:ui_zoom",
 132     "//components/update_client",
 133     "//components/url_fixer",
 134     "//components/user_prefs",
 135     "//components/variations",
 136     "//components/variations/net",
 137     "//components/webdata/common",
 138     "//components/webdata_services",
 139     "//components/web_resource",
 140     "//content/public/browser",
 141     "//content/public/common",
 142     "//courgette:courgette_lib",
 143     "//crypto",
 144     "//google_apis",
 145     "//gpu/config",
 146     "//jingle:notifier",
 147     "//skia",
 148     "//sql",
 149     "//sync",
 150     "//third_party/cacheinvalidation",
 151     "//third_party/icu",
 152     "//third_party/libxml",
 153     "//third_party/libjingle",
 154     "//third_party/widevine/cdm:version_h",
 155     "//third_party/zlib",
 156     "//third_party/zlib:minizip",
 157     "//third_party/zlib:zip",
 158     "//ui/base",
 159     "//ui/events:events_base",
 160     "//ui/gfx",
 161     "//ui/gfx/geometry",
 162     "//ui/message_center",
 163     "//ui/shell_dialogs",
 164     "//ui/strings",
 165     "//ui/resources",
 166   ]
 167
 168   sources +=
 169       rebase_path(gypi_values.chrome_browser_undo_sources, ".", "//chrome")
 170
 171   if (!is_ios) {
 172     sources +=
 173         rebase_path(gypi_values.chrome_browser_non_ios_sources, ".", "//chrome")
 174     sources += rebase_path(gypi_values.chrome_browser_autocomplete_sources,
 175                            ".",
 176                            "//chrome")
 177     sources += rebase_path(gypi_values.chrome_browser_bookmark_sources,
 178                            ".",
 179                            "//chrome")
 180     sources += rebase_path(gypi_values.chrome_browser_browser_process_sources,
 181                            ".",
 182                            "//chrome")
 183     sources += rebase_path(gypi_values.chrome_browser_content_settings_sources,
 184                            ".",
 185                            "//chrome")
 186     sources +=
 187         rebase_path(gypi_values.chrome_browser_favicon_sources, ".", "//chrome")
 188     sources +=
 189         rebase_path(gypi_values.chrome_browser_google_sources, ".", "//chrome")
 190     sources +=
 191         rebase_path(gypi_values.chrome_browser_history_sources, ".", "//chrome")
 192     sources +=
 193         rebase_path(gypi_values.chrome_browser_metrics_sources, ".", "//chrome")
 194     sources +=
 195         rebase_path(gypi_values.chrome_browser_net_sources, ".", "//chrome")
 196     sources += rebase_path(gypi_values.chrome_browser_password_manager_sources,
 197                            ".",
 198                            "//chrome")
 199     sources += rebase_path(gypi_values.chrome_browser_predictor_sources,
 200                            ".",
 201                            "//chrome")
 202     sources +=
 203         rebase_path(gypi_values.chrome_browser_pref_sources, ".", "//chrome")
 204     sources += rebase_path(gypi_values.chrome_browser_profiles_sources,
 205                            ".",
 206                            "//chrome")
 207     sources += rebase_path(gypi_values.chrome_browser_search_engines_sources,
 208                            ".",
 209                            "//chrome")
 210     sources += rebase_path(gypi_values.chrome_browser_services_sources,
 211                            ".",
 212                            "//chrome")
 213     sources +=
 214         rebase_path(gypi_values.chrome_browser_session_sources, ".", "//chrome")
 215     sources +=
 216         rebase_path(gypi_values.chrome_browser_signin_sources, ".", "//chrome")
 217     sources +=
 218         rebase_path(gypi_values.chrome_browser_ssl_sources, ".", "//chrome")
 219     sources +=
 220         rebase_path(gypi_values.chrome_browser_sync_sources, ".", "//chrome")
 221     sources += rebase_path(gypi_values.chrome_browser_web_resource_sources,
 222                            ".",
 223                            "//chrome")
 224
 225     deps += [
 226       "//apps",
 227       "//cc",
 228       "//chrome/app:generated_resources_map",
 229       "//chrome/app/theme:theme_resources",
 230       "//chrome/browser/devtools",
 231       "//chrome/browser/resources:component_extension_resources",
 232       "//chrome/installer/util",
 233       "//components/app_modal",
 234       "//components/autofill/content/browser",
 235       "//components/data_reduction_proxy/content/browser",
 236       "//components/dom_distiller/content",
 237       "//components/history/content/browser",
 238       "//components/keyed_service/content",
 239       "//components/navigation_interception",
 240       "//components/password_manager/content/browser",
 241       "//components/precache/content",
 242       "//components/sessions:sessions_content",
 243       "//components/storage_monitor",
 244       "//components/translate/content/browser",
 245       "//components/url_matcher",
 246       "//components/visitedlink/browser",
 247       "//components/visitedlink/common",
 248       "//components/web_cache/browser",
 249       "//components/web_modal",
 250       "//content/app/resources",
 251       "//media",
 252       "//mojo/common",
 253       "//mojo/environment:chromium",
 254       "//net:extras",
 255       "//net:net_with_v8",
 256       "//storage/browser",
 257       "//storage/common",
 258       "//third_party/WebKit/public:resources",
 259       "//third_party/expat",
 260       "//third_party/leveldatabase",
 261       "//third_party/libaddressinput",
 262       "//third_party/libyuv",
 263       "//third_party/mojo/src/mojo/edk/system",
 264       "//third_party/mojo/src/mojo/public/cpp/bindings",
 265       "//third_party/mojo/src/mojo/public/js",
 266       "//third_party/npapi",
 267       "//third_party/re2",
 268       "//third_party/smhasher:cityhash",
 269       "//third_party/webrtc/modules/desktop_capture",
 270       "//ui/base/ime",
 271       "//ui/gl",
 272       "//ui/resources",
 273       "//ui/surface",
 274       "//ui/web_dialogs",
 275       "//v8",
 276     ]
 277   } else {  # iOS
 278     sources +=
 279         rebase_path(gypi_values.chrome_browser_ios_sources, ".", "//chrome")
 280     sources +=
 281         rebase_path(gypi_values.chrome_browser_google_sources, ".", "//chrome")
 282     deps += [ "//net" ]
 283     libs += [
 284       "CoreTelephony.framework",
 285       "CoreText.framework",
 286       "MobileCoreServices.framework",
 287       "QuartzCore.framework",
 288     ]
 289     ldflags += [
 290       "-weak_framework",
 291       "CoreImage",
 292     ]
 293   }
 294
 295   if (is_win || is_mac) {
 296     sources +=
 297         rebase_path(gypi_values.chrome_browser_win_mac_sources, ".", "//chrome")
 298   }
 299   if (!is_android && !is_ios && !is_chromeos && enable_configuration_policy) {
 300     sources += [
 301       "net/disk_cache_dir_policy_handler.cc",
 302       "net/disk_cache_dir_policy_handler.h",
 303     ]
 304   }
 305   if (!is_android && !is_ios && enable_configuration_policy) {
 306     sources += [
 307       "download/download_dir_policy_handler.cc",
 308       "download/download_dir_policy_handler.h",
 309     ]
 310   }
 311   if (is_mac) {
 312     sources +=
 313         rebase_path(gypi_values.chrome_browser_mac_sources, ".", "//chrome")
 314     deps += [
 315       #"app_shim"  TODO(GYP)
 316       #"browser_app_shim"  TODO(GYP)
 317     ]
 318   }
 319   if (enable_extensions) {
 320     public_deps += [ "//chrome/browser/extensions" ]
 321     deps += [
 322       "//chrome/browser/sync_file_system/drive_backend:sync_file_system_drive_proto",
 323       "//chrome/common/extensions/api",
 324       "//chrome/common/extensions/api:api_registration",
 325       "//components/proximity_auth/cryptauth",
 326       "//extensions/components/javascript_dialog_extensions_client",
 327       "//media/cast:net",
 328     ]
 329     sources += rebase_path(gypi_values.chrome_browser_extensions_sources,
 330                            ".",
 331                            "//chrome")
 332   }
 333   if (enable_background) {
 334     sources += rebase_path(gypi_values.chrome_browser_background_sources,
 335                            ".",
 336                            "//chrome")
 337     if (!use_aura || is_win || is_chromeos) {
 338       sources -= [ "background/background_mode_manager_aura.cc" ]
 339     }
 340     defines += [ "ENABLE_BACKGROUND=1" ]
 341   }
 342   if (enable_task_manager) {
 343     sources += rebase_path(gypi_values.chrome_browser_task_manager_sources,
 344                            ".",
 345                            "//chrome")
 346   }
 347   if (enable_spellcheck) {
 348     sources += rebase_path(gypi_values.chrome_browser_spellchecker_sources,
 349                            ".",
 350                            "//chrome")
 351     deps += [ "//third_party/hunspell" ]
 352   }
 353   if (enable_nacl) {
 354     sources +=
 355         rebase_path(gypi_values.chrome_browser_nacl_sources, ".", "//chrome")
 356     deps += [ "//components/nacl:nacl_browser" ]
 357   }
 358
 359   if (enable_configuration_policy) {
 360     sources +=
 361         rebase_path(gypi_values.chrome_browser_policy_shared_with_ios_sources,
 362                     ".",
 363                     "//chrome")
 364     deps += [
 365       "//components/policy",
 366       "//components/policy/proto",
 367     ]
 368     if (!is_ios) {
 369       sources += rebase_path(gypi_values.chrome_browser_policy_non_ios_sources,
 370                              ".",
 371                              "//chrome")
 372     }
 373     if (!is_chromeos) {
 374       sources += rebase_path(
 375               gypi_values.chrome_browser_policy_shared_with_ios_not_chromeos_sources,
 376               ".",
 377               "//chrome")
 378     }
 379     if (is_win || is_mac || is_desktop_linux) {
 380       sources += rebase_path(gypi_values.chrome_browser_policy_desktop_sources,
 381                              ".",
 382                              "//chrome")
 383     }
 384     if (is_android || is_ios) {
 385       sources += rebase_path(gypi_values.chrome_browser_policy_mobile_sources,
 386                              ".",
 387                              "//chrome")
 388     } else {
 389       deps += [ "//chrome/browser/policy:path_parser" ]
 390     }
 391   } else {
 392     # Configuration policy disabled.
 393     sources += rebase_path(gypi_values.chrome_browser_policy_disabled_sources,
 394                            ".",
 395                            "//chrome")
 396   }
 397
 398   if (enable_plugins) {
 399     sources +=
 400         rebase_path(gypi_values.chrome_browser_plugins_sources, ".", "//chrome")
 401     deps += [
 402       "//components/pdf/browser",
 403       "//ppapi/proxy:ipc",
 404       "//third_party/adobe/flash:flapper_version_h",
 405     ]
 406   }
 407   if (safe_browsing_mode != 0) {
 408     sources +=
 409         rebase_path(gypi_values.chrome_browser_safe_browsing_basic_sources,
 410                     ".",
 411                     "//chrome")
 412     deps += [
 413       "//chrome/browser/safe_browsing:chunk_proto",
 414       "//chrome/browser/safe_browsing:metadata_proto",
 415       "//chrome/browser/safe_browsing:report_proto",
 416     ]
 417     if (safe_browsing_mode == 1) {
 418       sources +=
 419           rebase_path(gypi_values.chrome_browser_safe_browsing_full_sources,
 420                       ".",
 421                       "//chrome")
 422       defines += [ "FULL_SAFE_BROWSING" ]
 423       deps += [ "//chrome/common/safe_browsing:proto" ]
 424     } else if (safe_browsing_mode == 2) {
 425       defines += [ "MOBILE_SAFE_BROWSING" ]
 426     }
 427   }
 428
 429   if (is_linux) {
 430     deps += [
 431       "//device/media_transfer_protocol",
 432       "//device/udev_linux",
 433     ]
 434   }
 435   if (is_linux && !is_chromeos) {
 436     deps += [ "//third_party/speech-dispatcher" ]
 437   }
 438
 439   if (is_chromeos) {
 440     sources += rebase_path(gypi_values.chrome_browser_chromeos_sources,
 441                            ".",
 442                            "//chrome")
 443     deps += [ "//chrome/browser/chromeos" ]
 444   } else {
 445     # Non-ChromeOS.
 446     sources += rebase_path(gypi_values.chrome_browser_non_chromeos_sources,
 447                            ".",
 448                            "//chrome")
 449   }
 450
 451   if (is_ios) {
 452     sources -= [
 453       "metrics/signin_status_metrics_provider_base.cc",
 454       "metrics/signin_status_metrics_provider_base.h",
 455     ]
 456   }
 457
 458   if (is_chromeos || is_ios) {
 459     sources -= [
 460       "metrics/signin_status_metrics_provider.cc",
 461       "metrics/signin_status_metrics_provider.h",
 462     ]
 463   }
 464
 465   if (use_cups) {
 466     configs += [ "//printing:cups" ]
 467   }
 468   if (is_desktop_linux) {
 469     sources += rebase_path(gypi_values.chrome_browser_gnome_keyring_sources,
 470                            ".",
 471                            "//chrome")
 472     configs += [ ":gnome_keyring" ]
 473   }
 474   if (is_desktop_linux) {
 475     sources += rebase_path(gypi_values.chrome_browser_libsecret_sources,
 476                            ".",
 477                            "//chrome")
 478     defines += [ "USE_LIBSECRET" ]
 479   }
 480   if (use_aura) {
 481     sources +=
 482         rebase_path(gypi_values.chrome_browser_aura_sources, ".", "//chrome")
 483     deps += [
 484       "//ui/aura",
 485       "//ui/compositor",
 486       "//ui/keyboard",
 487     ]
 488   }
 489   if (ui_compositor_image_transport) {
 490     deps += [ "//ui/gl" ]
 491   }
 492
 493   if (use_ash) {
 494     sources +=
 495         rebase_path(gypi_values.chrome_browser_ash_sources, ".", "//chrome")
 496   }
 497
 498   if (use_x11) {
 499     sources +=
 500         rebase_path(gypi_values.chrome_browser_x11_sources, ".", "//chrome")
 501   } else {
 502     sources -= [ "password_manager/password_store_x.cc" ]
 503   }
 504   if (is_posix && !is_mac && !is_ios) {
 505     sources += [
 506       "//chrome/app/chrome_crash_reporter_client.cc",
 507       "//chrome/app/chrome_crash_reporter_client.h",
 508     ]
 509     deps += [
 510       "//components/crash/app",
 511       "//components/crash/browser",
 512     ]
 513   }
 514   if (use_nss_certs) {
 515     sources +=
 516         rebase_path(gypi_values.chrome_browser_nss_sources, ".", "//chrome")
 517     if (is_chromeos) {
 518       sources -= [ "net/nss_context_linux.cc" ]
 519     }
 520   }
 521   if (enable_notifications) {
 522     sources += rebase_path(gypi_values.chrome_browser_notifications_sources,
 523                            ".",
 524                            "//chrome")
 525     if (!is_android) {
 526       sources += rebase_path(
 527               gypi_values.chrome_browser_notifications_non_android_sources,
 528               ".",
 529               "//chrome")
 530     }
 531   }
 532   if (enable_themes) {
 533     sources +=
 534         rebase_path(gypi_values.chrome_browser_themes_sources, ".", "//chrome")
 535   }
 536
 537   if (enable_basic_printing || enable_print_preview) {
 538     # Some form of printing support.
 539     sources += rebase_path(gypi_values.chrome_browser_printing_basic_sources,
 540                            ".",
 541                            "//chrome")
 542     deps += [ "//printing" ]
 543     if (is_win) {
 544       sources += rebase_path(gypi_values.chrome_browser_printing_emf_sources,
 545                              ".",
 546                              "//chrome")
 547     }
 548     if (enable_print_preview) {
 549       # Full printing on top of the above.
 550       sources += rebase_path(gypi_values.chrome_browser_printing_full_sources,
 551                              ".",
 552                              "//chrome")
 553     } else {
 554       # Partial-only printing support.
 555       sources +=
 556           rebase_path(gypi_values.chrome_browser_printing_basic_only_sources,
 557                       ".",
 558                       "//chrome")
 559     }
 560   }
 561   if (enable_captive_portal_detection) {
 562     sources += rebase_path(gypi_values.chrome_browser_captive_portal_sources,
 563                            ".",
 564                            "//chrome")
 565   }
 566   if (enable_session_service) {
 567     sources += rebase_path(gypi_values.chrome_browser_session_service_sources,
 568                            ".",
 569                            "//chrome")
 570   }
 571
 572   if (!is_android && !is_ios && !is_chromeos) {
 573     sources +=
 574         rebase_path(gypi_values.chrome_browser_desktop_sources, ".", "//chrome")
 575   }
 576
 577   if (is_android || is_ios) {
 578     # Mobile.
 579     sources +=
 580         rebase_path(gypi_values.chrome_browser_mobile_sources, ".", "//chrome")
 581   } else {
 582     # Non-mobile.
 583     sources += rebase_path(gypi_values.chrome_browser_non_mobile_sources,
 584                            ".",
 585                            "//chrome")
 586     deps += [
 587       "//device/core",
 588       "//device/usb",
 589     ]
 590   }
 591
 592   if (is_android) {
 593     sources +=
 594         rebase_path(gypi_values.chrome_browser_android_sources, ".", "//chrome")
 595     deps += [
 596       ":jni_headers",
 597       "//components/cdm/browser",
 598       "//components/enhanced_bookmarks",
 599       "//components/resources:components_resources",
 600       "//components/web_contents_delegate_android",
 601       "//third_party/android_opengl/etc1",
 602       "//third_party/libaddressinput:util",
 603     ]
 604     deps -= [
 605       "//third_party/libaddressinput",
 606       "//components/feedback",
 607       "//components/storage_monitor",
 608       "//components/web_modal",
 609     ]
 610     defines += [ "ENABLE_DATA_REDUCTION_PROXY_DEBUGGING" ]
 611   }
 612
 613   if (is_mac) {
 614     deps += [
 615       "//third_party/google_toolbox_for_mac",
 616       "//third_party/mozilla",
 617     ]
 618     libs += [
 619       "Accelerate.framework",
 620       "AddressBook.framework",
 621       "AudioUnit.framework",
 622       "DiskArbitration.framework",
 623       "IOKit.framework",
 624       "ImageCaptureCore.framework",
 625       "OpenGL.framework",
 626       "QuartzCore.framework",
 627       "SecurityInterface.framework",
 628     ]
 629   }
 630
 631   if (enable_rlz) {
 632     sources +=
 633         rebase_path(gypi_values.chrome_browser_rlz_sources, ".", "//chrome")
 634     deps += [ "//rlz:rlz_lib" ]
 635   }
 636
 637   # TODO(GYP)
 638   # Temporary fix to break the browser target into smaller chunks so it
 639   # will link with goma builds.
 640   #["OS=="win" and chromium_win_pch==0", {
 641   #  "msvs_shard": 4,
 642   #}],
 643
 644   if (is_win) {
 645     sources +=
 646         rebase_path(gypi_values.chrome_browser_win_sources, ".", "//chrome")
 647     if (!is_chrome_branded) {
 648       sources -= [
 649         "google/did_run_updater_win.cc",
 650         "google/did_run_updater_win.h",
 651       ]
 652     }
 653     public_deps += [
 654       "//ui/views",
 655       "//ui/views/controls/webview",
 656     ]
 657     deps += [
 658       ":chrome_process_finder",
 659       "//chrome:version_header",
 660       "//chrome/installer/util:strings",
 661       "//chrome_elf",
 662       "//chrome_elf:constants",
 663       "//chrome_elf:dll_hash",
 664       "//components/browser_watcher",
 665       "//components/browser_watcher:browser_watcher_client",
 666       "//google_update",
 667       "//third_party/iaccessible2",
 668       "//third_party/isimpledom",
 669       "//third_party/wtl",
 670       "//ui/metro_viewer",
 671       "//win8:metro_viewer",
 672     ]
 673     libs += [ "credui.lib" ]
 674   } else {
 675     # Non-Windows.
 676     sources +=
 677         rebase_path(gypi_values.chrome_browser_non_win_sources, ".", "//chrome")
 678     if (toolkit_views) {
 679       deps += [
 680         "//ui/views",
 681         "//ui/views/controls/webview",
 682       ]
 683     }
 684   }
 685
 686   if (is_linux) {
 687     sources +=
 688         rebase_path(gypi_values.chrome_browser_linux_sources, ".", "//chrome")
 689     if (use_aura) {
 690       configs += [
 691         "//build/config/linux:dbus",
 692         "//build/config/linux:fontconfig",
 693       ]
 694       deps += [ "//dbus" ]
 695     }
 696     if (use_x11) {
 697       configs += [ "//build/config/linux:x11" ]
 698       deps += [ "//ui/gfx/x" ]
 699     }
 700   }
 701
 702   if (is_desktop_linux) {
 703     sources += rebase_path(gypi_values.chrome_browser_linux_desktop_sources,
 704                            ".",
 705                            "//chrome")
 706   }
 707   if (enable_plugin_installation) {
 708     sources +=
 709         rebase_path(gypi_values.chrome_browser_plugin_installation_sources,
 710                     ".",
 711                     "//chrome")
 712   }
 713   if (enable_app_list) {
 714     deps += [ "//ui/app_list" ]
 715   }
 716   if (enable_supervised_users) {
 717     sources += rebase_path(gypi_values.chrome_browser_supervised_user_sources,
 718                            ".",
 719                            "//chrome")
 720   }
 721   if (enable_supervised_users && enable_themes) {
 722     sources += rebase_path(
 723             gypi_values.chrome_browser_supervised_user_and_themes_sources,
 724             ".",
 725             "//chrome")
 726   }
 727   if (enable_webrtc) {
 728     sources +=
 729         rebase_path(gypi_values.chrome_browser_webrtc_sources, ".", "//chrome")
 730   }
 731   if (enable_service_discovery) {
 732     sources += rebase_path(gypi_values.chrome_browser_service_discovery_sources,
 733                            ".",
 734                            "//chrome")
 735   }
 736   if (enable_mdns) {
 737     sources +=
 738         rebase_path(gypi_values.chrome_browser_mdns_sources, ".", "//chrome")
 739   }
 740   if (!enable_autofill_dialog || is_android || is_ios) {
 741     sources -= [
 742       "autofill/validation_rules_storage_factory.cc",
 743       "autofill/validation_rules_storage_factory.h",
 744     ]
 745   }
 746   if (enable_wifi_bootstrapping) {
 747     sources +=
 748         rebase_path(gypi_values.chrome_browser_wifi_bootstrapping_sources,
 749                     ".",
 750                     "//chrome")
 751     if (is_win || is_mac) {
 752       # TODO(brettw) as of this writing wifi bootstrapping is set on Windows
 753       # and Mac, so this test is meaningless. Can we merge these lists?
 754       sources += rebase_path(
 755               gypi_values.chrome_browser_wifi_bootstrapping_win_mac_sources,
 756               ".",
 757               "//chrome")
 758     }
 759   }
 760 }
 761
 762 if (is_android) {
 763   # GYP version: chrome/chrome_browser.gypi:chrome_browser_jni_headers
 764   generate_jni("jni_headers") {
 765     sources =
 766         rebase_path(gypi_values.chrome_browser_jni_sources, ".", "//chrome")
 767     jni_package = "chrome"
 768   }
 769 }
 770
 771 if (is_win) {
 772   source_set("chrome_process_finder") {
 773     sources = [
 774       "chrome_process_finder_win.cc",
 775       "chrome_process_finder_win.h",
 776     ]
 777     deps = [
 778       "//base",
 779       "//chrome/browser/metro_utils",
 780       "//chrome/common:constants",
 781     ]
 782     if (enable_configuration_policy) {
 783       deps += [ "//chrome/browser/policy:path_parser" ]
 784     }
 785   }
 786 }
 787
 788 # GYP version: chrome/chrome_resources.gyp:chrome_resources
 789 # (generate_browser_resources action)
 790 grit("resources") {
 791   source = "browser_resources.grd"
 792   output_dir = "$root_gen_dir/chrome"
 793   outputs = [
 794     "grit/browser_resources.h",
 795     "browser_resources.pak",
 796   ]
 797
 798   omnibox_mojom_file =
 799       "$root_gen_dir/chrome/browser/ui/webui/omnibox/omnibox.mojom.js"
 800
 801   grit_flags = [
 802     "-E",
 803     "about_credits_file=" + rebase_path(about_credits_file, root_build_dir),
 804     "-E",
 805     "additional_modules_list_file=" +
 806         rebase_path(additional_modules_list_file, root_build_dir),
 807     "-E",
 808     "omnibox_mojom_file=" + rebase_path(omnibox_mojom_file, root_build_dir),
 809   ]
 810
 811   deps = [
 812     ":about_credits",
 813     ":chrome_internal_resources_gen",
 814   ]
 815   inputs = [
 816     omnibox_mojom_file,
 817   ]
 818 }
 819
 820 # GYP version: chrome/chrome_resource.gyp:about_credits
 821 action("about_credits") {
 822   script = "//tools/licenses.py"
 823
 824   inputs = [
 825     # This is not a complete list. TODO(phajdan.jr, dbeam): licenses.py needs to
 826     # generate a .d file with all the licenses/credits that about:credits uses.
 827     # Then about:credits will automatically rebuild when one of them changes.
 828     # See: depfile in gn's documentation (gn help depfile).
 829     "resources/about_credits.tmpl",
 830     "resources/about_credits_entry.tmpl",
 831   ]
 832
 833   outputs = [
 834     about_credits_file,
 835   ]
 836
 837   args = [
 838     "credits",
 839     rebase_path(about_credits_file, root_build_dir),
 840   ]
 841 }
 842
 843 # GYP version: chrome/chrome_resource.gyp:chrome_internal_resources_gen
 844 if (is_chrome_branded) {
 845   action("chrome_internal_resources_gen") {
 846     script = "internal/transform_additional_modules_list.py"
 847     sources = [
 848       "internal/resources/additional_modules_list.input",
 849     ]
 850     outputs = [
 851       additional_modules_list_file,
 852     ]
 853     args = rebase_path(sources, root_build_dir) +
 854            rebase_path(outputs, root_build_dir)
 855   }
 856 } else {
 857   group("chrome_internal_resources_gen") {
 858     # Empty placeholder.
 859   }
 860 }
 861
 862 # In GYP this is part of test_support_common.
 863 source_set("test_support") {
 864   testonly = true
 865
 866   # Always include this via the main test support target.
 867   visibility = [ "//chrome/test:test_support" ]
 868
 869   sources = [
 870     "browsing_data/mock_browsing_data_appcache_helper.cc",
 871     "browsing_data/mock_browsing_data_appcache_helper.h",
 872     "browsing_data/mock_browsing_data_channel_id_helper.cc",
 873     "browsing_data/mock_browsing_data_channel_id_helper.h",
 874     "browsing_data/mock_browsing_data_cookie_helper.cc",
 875     "browsing_data/mock_browsing_data_cookie_helper.h",
 876     "browsing_data/mock_browsing_data_database_helper.cc",
 877     "browsing_data/mock_browsing_data_database_helper.h",
 878     "browsing_data/mock_browsing_data_file_system_helper.cc",
 879     "browsing_data/mock_browsing_data_file_system_helper.h",
 880     "browsing_data/mock_browsing_data_flash_lso_helper.cc",
 881     "browsing_data/mock_browsing_data_flash_lso_helper.h",
 882     "browsing_data/mock_browsing_data_indexed_db_helper.cc",
 883     "browsing_data/mock_browsing_data_indexed_db_helper.h",
 884     "browsing_data/mock_browsing_data_local_storage_helper.cc",
 885     "browsing_data/mock_browsing_data_local_storage_helper.h",
 886     "browsing_data/mock_browsing_data_quota_helper.cc",
 887     "browsing_data/mock_browsing_data_quota_helper.h",
 888     "browsing_data/mock_browsing_data_service_worker_helper.cc",
 889     "browsing_data/mock_browsing_data_service_worker_helper.h",
 890     "download/download_test_file_activity_observer.cc",
 891     "download/download_test_file_activity_observer.h",
 892     "download/test_download_shelf.cc",
 893     "download/test_download_shelf.h",
 894     "invalidation/fake_invalidation_service.cc",
 895     "invalidation/fake_invalidation_service.h",
 896     "media/fake_desktop_media_list.cc",
 897     "media/fake_desktop_media_list.h",
 898     "net/dns_probe_test_util.cc",
 899     "net/dns_probe_test_util.h",
 900     "net/url_request_mock_util.cc",
 901     "net/url_request_mock_util.h",
 902     "notifications/notification_test_util.cc",
 903     "notifications/notification_test_util.h",
 904     "password_manager/mock_password_store_service.cc",
 905     "password_manager/mock_password_store_service.h",
 906     "password_manager/null_password_store_service.cc",
 907     "password_manager/null_password_store_service.h",
 908     "password_manager/test_password_store_service.cc",
 909     "password_manager/test_password_store_service.h",
 910     "prefs/pref_service_mock_factory.cc",
 911     "prefs/pref_service_mock_factory.h",
 912     "profile_resetter/profile_resetter_test_base.cc",
 913     "profile_resetter/profile_resetter_test_base.h",
 914     "search_engines/template_url_service_factory_test_util.cc",
 915     "search_engines/template_url_service_factory_test_util.h",
 916     "search_engines/template_url_service_test_util.cc",
 917     "search_engines/template_url_service_test_util.h",
 918     "sessions/session_restore_test_helper.cc",
 919     "sessions/session_restore_test_helper.h",
 920     "sessions/session_service_test_helper.cc",
 921     "sessions/session_service_test_helper.h",
 922     "signin/fake_account_reconcilor.cc",
 923     "signin/fake_account_reconcilor.h",
 924     "signin/fake_account_tracker_service.cc",
 925     "signin/fake_account_tracker_service.h",
 926     "signin/fake_profile_oauth2_token_service.cc",
 927     "signin/fake_profile_oauth2_token_service.h",
 928     "signin/fake_profile_oauth2_token_service_builder.cc",
 929     "signin/fake_profile_oauth2_token_service_builder.h",
 930     "signin/fake_signin_manager.cc",
 931     "signin/fake_signin_manager.h",
 932     "ssl/ssl_client_auth_requestor_mock.cc",
 933     "ssl/ssl_client_auth_requestor_mock.h",
 934     "sync/profile_sync_components_factory_mock.cc",
 935     "sync/profile_sync_components_factory_mock.h",
 936     "sync/profile_sync_service_mock.cc",
 937     "sync/profile_sync_service_mock.h",
 938     "ui/webui/signin/login_ui_test_utils.cc",
 939     "ui/webui/signin/login_ui_test_utils.h",
 940   ]
 941
 942   public_deps = [
 943     ":browser",
 944     "//chrome/browser/ui:test_support",
 945   ]
 946   deps = [
 947     "//base:prefs_test_support",
 948     "//chrome/browser",
 949     "//chrome/common",
 950     "//chrome/common/safe_browsing:proto",
 951     "//components/invalidation",
 952     "//components/invalidation:test_support",
 953     "//components/password_manager/core/browser:test_support",
 954     "//components/search_engines:test_support",
 955     "//content/test:test_support",
 956     "//chrome/app/theme:theme_resources",
 957     "//net:test_support",
 958     "//skia",
 959     "//testing/gmock",
 960     "//testing/gtest",
 961     "//ui/gfx",
 962   ]
 963
 964   if (!is_ios) {
 965     deps += [
 966       "//components/sessions:test_support",
 967       "//google_apis:test_support",
 968     ]
 969   }
 970
 971   if (enable_extensions) {
 972     sources += [
 973       "extensions/extension_action_test_util.cc",
 974       "extensions/extension_action_test_util.h",
 975     ]
 976     deps += [ "//extensions:test_support" ]
 977   }
 978
 979   if (is_chromeos) {
 980     sources += [
 981       "chromeos/app_mode/fake_cws.cc",
 982       "chromeos/app_mode/fake_cws.h",
 983       "chromeos/file_manager/fake_disk_mount_manager.cc",
 984       "chromeos/file_manager/fake_disk_mount_manager.h",
 985       "chromeos/input_method/mock_candidate_window_controller.cc",
 986       "chromeos/input_method/mock_candidate_window_controller.h",
 987       "chromeos/input_method/mock_input_method_engine.cc",
 988       "chromeos/input_method/mock_input_method_engine.h",
 989       "chromeos/input_method/mock_input_method_manager.cc",
 990       "chromeos/input_method/mock_input_method_manager.h",
 991       "chromeos/login/screens/mock_device_disabled_screen_actor.cc",
 992       "chromeos/login/screens/mock_device_disabled_screen_actor.h",
 993       "chromeos/login/session/user_session_manager_test_api.cc",
 994       "chromeos/login/session/user_session_manager_test_api.h",
 995       "chromeos/login/test/js_checker.cc",
 996       "chromeos/login/test/js_checker.h",
 997       "chromeos/login/test/oobe_screen_waiter.cc",
 998       "chromeos/login/test/oobe_screen_waiter.h",
 999       "chromeos/login/ui/mock_login_display.cc",
1000       "chromeos/login/ui/mock_login_display.h",
1001       "chromeos/login/ui/mock_login_display_host.cc",
1002       "chromeos/login/ui/mock_login_display_host.h",
1003       "chromeos/login/users/avatar/mock_user_image_manager.cc",
1004       "chromeos/login/users/avatar/mock_user_image_manager.h",
1005       "chromeos/login/users/fake_chrome_user_manager.cc",
1006       "chromeos/login/users/fake_chrome_user_manager.h",
1007       "chromeos/login/users/fake_supervised_user_manager.cc",
1008       "chromeos/login/users/fake_supervised_user_manager.h",
1009       "chromeos/login/users/mock_user_manager.cc",
1010       "chromeos/login/users/mock_user_manager.h",
1011       "chromeos/net/network_portal_detector_test_utils.cc",
1012       "chromeos/net/network_portal_detector_test_utils.h",
1013       "chromeos/policy/cloud_external_data_manager_base_test_util.cc",
1014       "chromeos/policy/cloud_external_data_manager_base_test_util.h",
1015       "chromeos/policy/device_policy_builder.cc",
1016       "chromeos/policy/device_policy_builder.h",
1017       "chromeos/policy/fake_consumer_management_service.cc",
1018       "chromeos/policy/fake_consumer_management_service.h",
1019       "chromeos/policy/fake_device_cloud_policy_initializer.cc",
1020       "chromeos/policy/fake_device_cloud_policy_initializer.h",
1021       "chromeos/policy/fake_device_cloud_policy_manager.cc",
1022       "chromeos/policy/fake_device_cloud_policy_manager.h",
1023       "chromeos/policy/stub_enterprise_install_attributes.cc",
1024       "chromeos/policy/stub_enterprise_install_attributes.h",
1025       "chromeos/settings/device_settings_test_helper.cc",
1026       "chromeos/settings/device_settings_test_helper.h",
1027       "chromeos/system/fake_input_device_settings.cc",
1028       "chromeos/system/fake_input_device_settings.h",
1029     ]
1030     configs += [ "//build/config/linux:dbus" ]
1031     deps += [ "//chromeos:test_support" ]
1032   }
1033
1034   if (enable_configuration_policy) {
1035     sources += [
1036       "policy/test/local_policy_test_server.cc",
1037       "policy/test/local_policy_test_server.h",
1038     ]
1039     public_deps += [
1040       "//components/policy:policy_component_test_support",
1041       "//components/policy:test_support",
1042     ]
1043   }
1044
1045   if (safe_browsing_mode == 1) {
1046     sources += [
1047       "extensions/fake_safe_browsing_database_manager.cc",
1048       "extensions/fake_safe_browsing_database_manager.h",
1049     ]
1050   }
1051
1052   if (enable_extensions) {
1053     sources += [
1054       "drive/dummy_drive_service.cc",
1055       "drive/dummy_drive_service.h",
1056       "drive/fake_drive_service.cc",
1057       "drive/fake_drive_service.h",
1058       "drive/test_util.cc",
1059       "drive/test_util.h",
1060       "extensions/api/messaging/native_messaging_test_util.cc",
1061       "extensions/api/messaging/native_messaging_test_util.h",
1062       "extensions/extension_notification_observer.cc",
1063       "extensions/extension_notification_observer.h",
1064       "extensions/mock_extension_special_storage_policy.cc",
1065       "extensions/mock_extension_special_storage_policy.h",
1066       "extensions/test_blacklist.cc",
1067       "extensions/test_blacklist.h",
1068       "extensions/test_blacklist_state_fetcher.cc",
1069       "extensions/test_blacklist_state_fetcher.h",
1070       "extensions/test_extension_dir.cc",
1071       "extensions/test_extension_dir.h",
1072       "extensions/test_extension_environment.cc",
1073       "extensions/test_extension_environment.h",
1074       "extensions/test_extension_prefs.cc",
1075       "extensions/test_extension_prefs.h",
1076       "extensions/test_extension_service.cc",
1077       "extensions/test_extension_service.h",
1078       "extensions/test_extension_system.cc",
1079       "extensions/test_extension_system.h",
1080       "media_galleries/media_galleries_test_util.cc",
1081       "media_galleries/media_galleries_test_util.h",
1082     ]
1083     deps += [ "//components/storage_monitor:test_support" ]
1084   }
1085
1086   if (enable_mdns) {
1087     sources += [
1088       "local_discovery/test_service_discovery_client.cc",
1089       "local_discovery/test_service_discovery_client.h",
1090     ]
1091   }
1092
1093   if (enable_app_list) {
1094     sources += [
1095       "ui/app_list/test/chrome_app_list_test_support.cc",
1096       "ui/app_list/test/chrome_app_list_test_support.h",
1097       "ui/app_list/test/test_app_list_controller_delegate.cc",
1098       "ui/app_list/test/test_app_list_controller_delegate.h",
1099     ]
1100   }
1101
1102   if (enable_wifi_bootstrapping) {
1103     sources += [
1104       "local_discovery/wifi/mock_wifi_manager.cc",
1105       "local_discovery/wifi/mock_wifi_manager.h",
1106     ]
1107   }
1108 }