media/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/arm.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/linux/pkg_config.gni")
   9 import("//build/config/ui.gni")
  10 import("//media/media_options.gni")
  11 import("//testing/test.gni")
  12
  13 # Common configuration for targets in the media directory.
  14 # NOT for exporting.
  15 config("media_config") {
  16   defines = []
  17   if (!media_use_libvpx) {
  18     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  19   }
  20   if (!media_use_ffmpeg) {
  21     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  22   }
  23   if (current_cpu == "arm" && arm_use_neon) {
  24     defines += [ "USE_NEON" ]
  25   }
  26   if (use_pulseaudio) {
  27     defines += [ "USE_PULSEAUDIO" ]
  28     if (!link_pulseaudio) {
  29       defines += [ "DLOPEN_PULSEAUDIO" ]
  30     }
  31   }
  32   if (use_cras) {
  33     defines += [ "USE_CRAS" ]
  34   }
  35   if (use_alsa) {
  36     defines += [ "USE_ALSA" ]
  37   }
  38 }
  39
  40 config("media_implementation") {
  41   defines = [ "MEDIA_IMPLEMENTATION" ]
  42 }
  43
  44 config("media_dependent_config") {
  45   defines = []
  46   if (!media_use_libvpx) {
  47     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  48   }
  49   if (!media_use_ffmpeg) {
  50     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  51   }
  52   if (is_win) {
  53     ldflags = [
  54       "/DELAYLOAD:mf.dll",
  55       "/DELAYLOAD:mfplat.dll",
  56       "/DELAYLOAD:mfreadwrite.dll",
  57     ]
  58   }
  59 }
  60
  61 if (use_ozone) {
  62   action("generate_ozone_constructor_list") {
  63     # Ozone platform objects are auto-generated using similar
  64     # patterns for naming and classes constructors. Here we build the
  65     # object MediaOzonePlatform.
  66     script = "../ui/ozone/generate_constructor_list.py"
  67
  68     platform_list_txt_file = "$target_gen_dir/../ui/ozone/platform_list.txt"
  69     constructor_list_cc_file =
  70         "$target_gen_dir/../media/ozone/constructor_list.cc"
  71
  72     sources = [
  73       platform_list_txt_file,
  74     ]
  75     outputs = [
  76       constructor_list_cc_file,
  77     ]
  78     args = [
  79       "--platform_list=" + rebase_path(platform_list_txt_file, root_build_dir),
  80       "--output_cc=" + rebase_path(constructor_list_cc_file, root_build_dir),
  81       "--namespace=media",
  82       "--typename=MediaOzonePlatform",
  83       "--include=\"media/ozone/media_ozone_platform.h\"",
  84     ]
  85   }
  86 }
  87
  88 component("media") {
  89   sources = [
  90     "blink/skcanvas_video_renderer.cc",
  91     "blink/skcanvas_video_renderer.h",
  92     "cdm/aes_decryptor.cc",
  93     "cdm/aes_decryptor.h",
  94     "cdm/cenc_utils.cc",
  95     "cdm/cenc_utils.h",
  96     "cdm/default_cdm_factory.cc",
  97     "cdm/default_cdm_factory.h",
  98     "cdm/json_web_key.cc",
  99     "cdm/json_web_key.h",
 100     "cdm/key_system_names.cc",
 101     "cdm/key_system_names.h",
 102     "cdm/player_tracker_impl.cc",
 103     "cdm/player_tracker_impl.h",
 104     "cdm/proxy_decryptor.cc",
 105     "cdm/proxy_decyrptor.h",
 106     "ffmpeg/ffmpeg_deleters.h",
 107     "filters/audio_clock.cc",
 108     "filters/audio_clock.h",
 109     "filters/audio_renderer_algorithm.cc",
 110     "filters/audio_renderer_algorithm.h",
 111     "filters/chunk_demuxer.cc",
 112     "filters/chunk_demuxer.h",
 113     "filters/context_3d.h",
 114     "filters/decoder_selector.cc",
 115     "filters/decoder_selector.h",
 116     "filters/decoder_stream.cc",
 117     "filters/decoder_stream.h",
 118     "filters/decoder_stream_traits.cc",
 119     "filters/decoder_stream_traits.h",
 120     "filters/decrypting_audio_decoder.cc",
 121     "filters/decrypting_audio_decoder.h",
 122     "filters/decrypting_demuxer_stream.cc",
 123     "filters/decrypting_demuxer_stream.h",
 124     "filters/decrypting_video_decoder.cc",
 125     "filters/decrypting_video_decoder.h",
 126     "filters/default_media_permission.cc",
 127     "filters/default_media_permission.h",
 128     "filters/file_data_source.cc",
 129     "filters/file_data_source.h",
 130     "filters/frame_processor.cc",
 131     "filters/frame_processor.h",
 132     "filters/gpu_video_decoder.cc",
 133     "filters/gpu_video_decoder.h",
 134     "filters/h264_bit_reader.cc",
 135     "filters/h264_bit_reader.h",
 136     "filters/h264_parser.cc",
 137     "filters/h264_parser.h",
 138     "filters/jpeg_parser.cc",
 139     "filters/jpeg_parser.h",
 140     "filters/source_buffer_platform.cc",
 141     "filters/source_buffer_platform.h",
 142     "filters/source_buffer_range.cc",
 143     "filters/source_buffer_range.h",
 144     "filters/source_buffer_stream.cc",
 145     "filters/source_buffer_stream.h",
 146     "filters/stream_parser_factory.cc",
 147     "filters/stream_parser_factory.h",
 148     "filters/video_frame_scheduler.h",
 149     "filters/video_frame_scheduler_impl.cc",
 150     "filters/video_frame_scheduler_impl.h",
 151     "filters/video_frame_scheduler_proxy.cc",
 152     "filters/video_frame_scheduler_proxy.h",
 153     "filters/vp8_bool_decoder.cc",
 154     "filters/vp8_bool_decoder.h",
 155     "filters/vp8_parser.cc",
 156     "filters/vp8_parser.h",
 157     "filters/webvtt_util.h",
 158     "filters/wsola_internals.cc",
 159     "filters/wsola_internals.h",
 160     "formats/common/offset_byte_queue.cc",
 161     "formats/common/offset_byte_queue.h",
 162     "formats/webm/webm_audio_client.cc",
 163     "formats/webm/webm_audio_client.h",
 164     "formats/webm/webm_cluster_parser.cc",
 165     "formats/webm/webm_cluster_parser.h",
 166     "formats/webm/webm_constants.cc",
 167     "formats/webm/webm_constants.h",
 168     "formats/webm/webm_content_encodings.cc",
 169     "formats/webm/webm_content_encodings.h",
 170     "formats/webm/webm_content_encodings_client.cc",
 171     "formats/webm/webm_content_encodings_client.h",
 172     "formats/webm/webm_crypto_helpers.cc",
 173     "formats/webm/webm_crypto_helpers.h",
 174     "formats/webm/webm_info_parser.cc",
 175     "formats/webm/webm_info_parser.h",
 176     "formats/webm/webm_parser.cc",
 177     "formats/webm/webm_parser.h",
 178     "formats/webm/webm_stream_parser.cc",
 179     "formats/webm/webm_stream_parser.h",
 180     "formats/webm/webm_tracks_parser.cc",
 181     "formats/webm/webm_tracks_parser.h",
 182     "formats/webm/webm_video_client.cc",
 183     "formats/webm/webm_video_client.h",
 184     "formats/webm/webm_webvtt_parser.cc",
 185     "formats/webm/webm_webvtt_parser.h",
 186     "midi/midi_manager.cc",
 187     "midi/midi_manager.h",
 188     "midi/midi_manager_mac.cc",
 189     "midi/midi_manager_mac.h",
 190     "midi/midi_manager_usb.cc",
 191     "midi/midi_manager_usb.h",
 192     "midi/midi_manager_win.cc",
 193     "midi/midi_manager_win.h",
 194     "midi/midi_message_queue.cc",
 195     "midi/midi_message_queue.h",
 196     "midi/midi_message_util.cc",
 197     "midi/midi_message_util.h",
 198     "midi/midi_port_info.cc",
 199     "midi/midi_port_info.h",
 200     "midi/midi_scheduler.cc",
 201     "midi/midi_scheduler.h",
 202     "midi/usb_midi_descriptor_parser.cc",
 203     "midi/usb_midi_descriptor_parser.h",
 204     "midi/usb_midi_device.h",
 205     "midi/usb_midi_input_stream.cc",
 206     "midi/usb_midi_input_stream.h",
 207     "midi/usb_midi_jack.h",
 208     "midi/usb_midi_output_stream.cc",
 209     "midi/usb_midi_output_stream.h",
 210     "renderers/audio_renderer_impl.cc",
 211     "renderers/audio_renderer_impl.h",
 212     "renderers/gpu_video_accelerator_factories.h",
 213     "renderers/renderer_impl.cc",
 214     "renderers/renderer_impl.h",
 215     "renderers/video_renderer_impl.cc",
 216     "renderers/video_renderer_impl.h",
 217     "video/capture/fake_video_capture_device.cc",
 218     "video/capture/fake_video_capture_device.h",
 219     "video/capture/fake_video_capture_device_factory.cc",
 220     "video/capture/fake_video_capture_device_factory.h",
 221     "video/capture/file_video_capture_device.cc",
 222     "video/capture/file_video_capture_device.h",
 223     "video/capture/file_video_capture_device_factory.cc",
 224     "video/capture/file_video_capture_device_factory.h",
 225     "video/capture/linux/v4l2_capture_delegate.cc",
 226     "video/capture/linux/v4l2_capture_delegate.h",
 227     "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 228     "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 229     "video/capture/linux/v4l2_capture_delegate_single_plane.cc",
 230     "video/capture/linux/v4l2_capture_delegate_single_plane.h",
 231     "video/capture/linux/video_capture_device_chromeos.cc",
 232     "video/capture/linux/video_capture_device_chromeos.h",
 233     "video/capture/linux/video_capture_device_factory_linux.cc",
 234     "video/capture/linux/video_capture_device_factory_linux.h",
 235     "video/capture/linux/video_capture_device_linux.cc",
 236     "video/capture/linux/video_capture_device_linux.h",
 237     "video/capture/mac/platform_video_capturing_mac.h",
 238     "video/capture/mac/video_capture_device_avfoundation_mac.h",
 239     "video/capture/mac/video_capture_device_avfoundation_mac.mm",
 240     "video/capture/mac/video_capture_device_decklink_mac.h",
 241     "video/capture/mac/video_capture_device_decklink_mac.mm",
 242     "video/capture/mac/video_capture_device_factory_mac.h",
 243     "video/capture/mac/video_capture_device_factory_mac.mm",
 244     "video/capture/mac/video_capture_device_mac.h",
 245     "video/capture/mac/video_capture_device_mac.mm",
 246     "video/capture/mac/video_capture_device_qtkit_mac.h",
 247     "video/capture/mac/video_capture_device_qtkit_mac.mm",
 248     "video/capture/video_capture_device.cc",
 249     "video/capture/video_capture_device.h",
 250     "video/capture/video_capture_device_factory.cc",
 251     "video/capture/video_capture_device_factory.h",
 252     "video/capture/video_capture_device_info.cc",
 253     "video/capture/video_capture_device_info.h",
 254     "video/capture/win/capability_list_win.cc",
 255     "video/capture/win/capability_list_win.h",
 256     "video/capture/win/filter_base_win.cc",
 257     "video/capture/win/filter_base_win.h",
 258     "video/capture/win/pin_base_win.cc",
 259     "video/capture/win/pin_base_win.h",
 260     "video/capture/win/sink_filter_observer_win.h",
 261     "video/capture/win/sink_filter_win.cc",
 262     "video/capture/win/sink_filter_win.h",
 263     "video/capture/win/sink_input_pin_win.cc",
 264     "video/capture/win/sink_input_pin_win.h",
 265     "video/capture/win/video_capture_device_factory_win.cc",
 266     "video/capture/win/video_capture_device_factory_win.h",
 267     "video/capture/win/video_capture_device_mf_win.cc",
 268     "video/capture/win/video_capture_device_mf_win.h",
 269     "video/capture/win/video_capture_device_win.cc",
 270     "video/capture/win/video_capture_device_win.h",
 271     "video/fake_video_encode_accelerator.cc",
 272     "video/fake_video_encode_accelerator.h",
 273     "video/h264_poc.cc",
 274     "video/h264_poc.h",
 275     "video/picture.cc",
 276     "video/picture.h",
 277     "video/video_decode_accelerator.cc",
 278     "video/video_decode_accelerator.h",
 279     "video/video_encode_accelerator.cc",
 280     "video/video_encode_accelerator.h",
 281   ]
 282
 283   configs += [
 284     ":media_config",
 285     ":media_implementation",
 286
 287     # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 288     # See http://crbug.com/171009
 289     "//build/config/compiler:no_size_t_to_int_warning",
 290   ]
 291   all_dependent_configs = [ ":media_dependent_config" ]
 292
 293   allow_circular_includes_from = []
 294   cflags = []
 295   libs = []
 296   defines = []
 297   deps = []
 298
 299   include_dirs = [ "." ]
 300   if (media_use_ffmpeg) {
 301     deps += [ "//third_party/ffmpeg" ]
 302     sources += [
 303       "ffmpeg/ffmpeg_common.cc",
 304       "ffmpeg/ffmpeg_common.h",
 305       "filters/audio_file_reader.cc",
 306       "filters/audio_file_reader.h",
 307       "filters/blocking_url_protocol.cc",
 308       "filters/blocking_url_protocol.h",
 309       "filters/ffmpeg_audio_decoder.cc",
 310       "filters/ffmpeg_audio_decoder.h",
 311       "filters/ffmpeg_bitstream_converter.h",
 312       "filters/ffmpeg_demuxer.cc",
 313       "filters/ffmpeg_demuxer.h",
 314       "filters/ffmpeg_glue.cc",
 315       "filters/ffmpeg_glue.h",
 316       "filters/ffmpeg_video_decoder.cc",
 317       "filters/ffmpeg_video_decoder.h",
 318       "filters/in_memory_url_protocol.cc",
 319       "filters/in_memory_url_protocol.h",
 320     ]
 321     if (proprietary_codecs) {
 322       sources += [
 323         "filters/ffmpeg_aac_bitstream_converter.cc",
 324         "filters/ffmpeg_aac_bitstream_converter.h",
 325         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.cc",
 326         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.h",
 327       ]
 328     }
 329   }
 330
 331   if (current_cpu == "arm" && arm_use_neon) {
 332     defines += [ "USE_NEON" ]
 333   }
 334
 335   if (media_use_libvpx) {
 336     sources += [
 337       "filters/vpx_video_decoder.cc",
 338       "filters/vpx_video_decoder.h",
 339     ]
 340     deps += [ "//third_party/libvpx" ]
 341   }
 342
 343   if (is_android) {
 344     sources += [
 345       "midi/midi_manager_android.cc",
 346       "midi/usb_midi_device_android.cc",
 347       "midi/usb_midi_device_android.h",
 348       "midi/usb_midi_device_factory_android.cc",
 349       "midi/usb_midi_device_factory_android.h",
 350       "video/capture/android/video_capture_device_android.cc",
 351       "video/capture/android/video_capture_device_android.h",
 352       "video/capture/android/video_capture_device_factory_android.cc",
 353       "video/capture/android/video_capture_device_factory_android.h",
 354     ]
 355     deps += [
 356       "//media/base/android",
 357       "//media/base/android:media_java",
 358       "//media/base/android:media_jni_headers",
 359       "//media/base/android:video_capture_jni_headers",
 360     ]
 361     allow_circular_includes_from = [ "//media/base/android" ]
 362   } else {
 363     sources += [
 364       "filters/opus_audio_decoder.cc",
 365       "filters/opus_audio_decoder.h",
 366       "renderers/default_renderer_factory.cc",
 367       "renderers/default_renderer_factory.h",
 368     ]
 369   }
 370
 371   if (current_cpu != "arm" && is_chromeos) {
 372     sources += [
 373       "filters/h264_bitstream_buffer.cc",
 374       "filters/h264_bitstream_buffer.h",
 375     ]
 376   }
 377
 378   if (use_alsa && use_udev) {
 379     libs += [ "asound" ]
 380     sources += [
 381       "midi/midi_manager_alsa.cc",
 382       "midi/midi_manager_alsa.h",
 383     ]
 384     deps += [ "//device/udev_linux" ]
 385   }
 386
 387   # A simple WebM encoder for animated avatars on ChromeOS.
 388
 389   if (use_ozone) {
 390     # Used for the generated listing header (ui/ozone/platform_list.h)
 391     include_dirs += [ target_gen_dir ]
 392
 393     sources += [
 394                  "ozone/media_ozone_platform.cc",
 395                  "ozone/media_ozone_platform.h",
 396                ] + get_target_outputs(":generate_ozone_constructor_list")
 397
 398     deps += [
 399       ":generate_ozone_constructor_list",
 400       "//ui/ozone",
 401     ]
 402   }
 403
 404   if (is_mac) {
 405     deps += [
 406       "//media/base/mac",
 407       "//third_party/decklink",
 408     ]
 409     libs += [
 410       "CoreMIDI.framework",
 411       "CoreVideo.framework",
 412       "OpenGL.framework",
 413       "QTKit.framework",
 414     ]
 415   }
 416
 417   if (is_openbsd) {
 418     sources -= [
 419       "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 420       "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 421     ]
 422   }
 423
 424   if (is_ios) {
 425     deps += [ "//media/base/mac" ]
 426   }
 427
 428   if (is_win) {
 429     deps += [ "//device/usb" ]
 430
 431     libs += [
 432       "mf.lib",
 433       "mfplat.lib",
 434       "mfreadwrite.lib",
 435       "mfuuid.lib",
 436     ]
 437   }
 438
 439   if (proprietary_codecs) {
 440     sources += [
 441       "filters/h264_to_annex_b_bitstream_converter.cc",
 442       "filters/h264_to_annex_b_bitstream_converter.h",
 443       "formats/mp2t/es_adapter_video.cc",
 444       "formats/mp2t/es_adapter_video.h",
 445       "formats/mp2t/es_parser.cc",
 446       "formats/mp2t/es_parser.h",
 447       "formats/mp2t/es_parser_adts.cc",
 448       "formats/mp2t/es_parser_adts.h",
 449       "formats/mp2t/es_parser_h264.cc",
 450       "formats/mp2t/es_parser_h264.h",
 451       "formats/mp2t/es_parser_mpeg1audio.cc",
 452       "formats/mp2t/es_parser_mpeg1audio.h",
 453       "formats/mp2t/mp2t_common.h",
 454       "formats/mp2t/mp2t_stream_parser.cc",
 455       "formats/mp2t/mp2t_stream_parser.h",
 456       "formats/mp2t/timestamp_unroller.cc",
 457       "formats/mp2t/timestamp_unroller.h",
 458       "formats/mp2t/ts_packet.cc",
 459       "formats/mp2t/ts_packet.h",
 460       "formats/mp2t/ts_section.h",
 461       "formats/mp2t/ts_section_pat.cc",
 462       "formats/mp2t/ts_section_pat.h",
 463       "formats/mp2t/ts_section_pes.cc",
 464       "formats/mp2t/ts_section_pes.h",
 465       "formats/mp2t/ts_section_pmt.cc",
 466       "formats/mp2t/ts_section_pmt.h",
 467       "formats/mp2t/ts_section_psi.cc",
 468       "formats/mp2t/ts_section_psi.h",
 469       "formats/mp4/aac.cc",
 470       "formats/mp4/aac.h",
 471       "formats/mp4/avc.cc",
 472       "formats/mp4/avc.h",
 473       "formats/mp4/box_definitions.cc",
 474       "formats/mp4/box_definitions.h",
 475       "formats/mp4/box_reader.cc",
 476       "formats/mp4/box_reader.h",
 477       "formats/mp4/cenc.cc",
 478       "formats/mp4/cenc.h",
 479       "formats/mp4/es_descriptor.cc",
 480       "formats/mp4/es_descriptor.h",
 481       "formats/mp4/mp4_stream_parser.cc",
 482       "formats/mp4/mp4_stream_parser.h",
 483       "formats/mp4/sample_to_group_iterator.cc",
 484       "formats/mp4/sample_to_group_iterator.h",
 485       "formats/mp4/track_run_iterator.cc",
 486       "formats/mp4/track_run_iterator.h",
 487       "formats/mpeg/adts_constants.cc",
 488       "formats/mpeg/adts_constants.h",
 489       "formats/mpeg/adts_stream_parser.cc",
 490       "formats/mpeg/adts_stream_parser.h",
 491       "formats/mpeg/mpeg1_audio_stream_parser.cc",
 492       "formats/mpeg/mpeg1_audio_stream_parser.h",
 493       "formats/mpeg/mpeg_audio_stream_parser_base.cc",
 494       "formats/mpeg/mpeg_audio_stream_parser_base.h",
 495     ]
 496   }
 497
 498   public_deps = [
 499     "//media/base",
 500     "//media/audio",
 501   ]
 502
 503   deps += [
 504     ":shared_memory_support",
 505     "//base",
 506     "//base:i18n",
 507     "//base/third_party/dynamic_annotations",
 508     "//crypto",
 509     "//crypto:platform",  # TODO(ajwong): This used to be provided by crypto.gyp via export_dependent_settings
 510     "//gpu/command_buffer/common",
 511     "//skia",
 512     "//third_party/libyuv",
 513     "//third_party/opus",
 514     "//ui/events:events_base",
 515     "//ui/gfx",
 516     "//ui/gfx/geometry",
 517     "//url",
 518   ]
 519 }
 520
 521 # Minimal media component for media/cast on iOS.
 522 if (is_ios) {
 523   component("media_for_cast_ios") {
 524     configs += [
 525       ":media_config",
 526       ":media_implementation",
 527     ]
 528     all_dependent_configs = [ ":media_dependent_config" ]
 529     include_dirs = [ "." ]
 530     libs = [ "CoreVideo.framework" ]
 531
 532     deps = [
 533       ":shared_memory_support",
 534       "//base",
 535       "//media/base:base_for_cast_ios",
 536       "//media/base/mac",
 537       "//ui/gfx/geometry",
 538     ]
 539   }
 540 }
 541
 542 test("media_unittests") {
 543   sources = [
 544     "blink/skcanvas_video_renderer_unittest.cc",
 545     "cdm/aes_decryptor_unittest.cc",
 546     "cdm/cenc_utils_unittest.cc",
 547     "cdm/json_web_key_unittest.cc",
 548     "filters/audio_clock_unittest.cc",
 549     "filters/audio_decoder_selector_unittest.cc",
 550     "filters/audio_renderer_algorithm_unittest.cc",
 551     "filters/chunk_demuxer_unittest.cc",
 552     "filters/decrypting_audio_decoder_unittest.cc",
 553     "filters/decrypting_demuxer_stream_unittest.cc",
 554     "filters/decrypting_video_decoder_unittest.cc",
 555     "filters/fake_demuxer_stream.cc",
 556     "filters/fake_demuxer_stream.h",
 557     "filters/fake_demuxer_stream_unittest.cc",
 558     "filters/fake_video_decoder.cc",
 559     "filters/fake_video_decoder.h",
 560     "filters/fake_video_decoder_unittest.cc",
 561     "filters/file_data_source_unittest.cc",
 562     "filters/frame_processor_unittest.cc",
 563     "filters/h264_bit_reader_unittest.cc",
 564     "filters/h264_parser_unittest.cc",
 565     "filters/jpeg_parser_unittest.cc",
 566     "filters/source_buffer_stream_unittest.cc",
 567     "filters/video_decoder_selector_unittest.cc",
 568     "filters/video_frame_scheduler_impl_unittest.cc",
 569     "filters/video_frame_scheduler_unittest.cc",
 570     "filters/video_frame_stream_unittest.cc",
 571     "filters/vp8_bool_decoder_unittest.cc",
 572     "filters/vp8_parser_unittest.cc",
 573     "formats/common/offset_byte_queue_unittest.cc",
 574     "formats/webm/cluster_builder.cc",
 575     "formats/webm/cluster_builder.h",
 576     "formats/webm/opus_packet_builder.cc",
 577     "formats/webm/opus_packet_builder.h",
 578     "formats/webm/tracks_builder.cc",
 579     "formats/webm/tracks_builder.h",
 580     "formats/webm/webm_cluster_parser_unittest.cc",
 581     "formats/webm/webm_content_encodings_client_unittest.cc",
 582     "formats/webm/webm_parser_unittest.cc",
 583     "formats/webm/webm_tracks_parser_unittest.cc",
 584     "formats/webm/webm_webvtt_parser_unittest.cc",
 585     "midi/midi_manager_unittest.cc",
 586     "midi/midi_manager_usb_unittest.cc",
 587     "midi/midi_message_queue_unittest.cc",
 588     "midi/midi_message_util_unittest.cc",
 589     "midi/usb_midi_descriptor_parser_unittest.cc",
 590     "midi/usb_midi_input_stream_unittest.cc",
 591     "midi/usb_midi_output_stream_unittest.cc",
 592     "renderers/audio_renderer_impl_unittest.cc",
 593     "renderers/renderer_impl_unittest.cc",
 594     "renderers/video_renderer_impl_unittest.cc",
 595     "video/capture/fake_video_capture_device_unittest.cc",
 596     "video/capture/video_capture_device_unittest.cc",
 597     "video/h264_poc_unittest.cc",
 598   ]
 599
 600   # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 601   # See http://crbug.com/171009
 602   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 603
 604   deps = [
 605     ":media",
 606     ":test_support",
 607     "//base/allocator",
 608     "//base/test:test_support",
 609     "//media/audio:unittests",
 610     "//media/audio:test_support",
 611     "//media/base:unittests",
 612     "//media/base:test_support",
 613     "//media/test:pipeline_integration_tests",
 614     "//skia",  # Direct dependency required to inherit config.
 615     "//testing/gmock",
 616     "//testing/gtest",
 617     "//third_party/widevine/cdm:version_h",
 618     "//ui/gfx:test_support",
 619     "//url",
 620   ]
 621
 622   if (is_android) {
 623     deps += [
 624       "//media/base/android",
 625       # TODO(GYP)
 626       #"//testing/android/native_test:native_test_native_code"
 627     ]
 628   }
 629
 630   if (media_use_ffmpeg) {
 631     sources += [
 632       "ffmpeg/ffmpeg_common_unittest.cc",
 633       "filters/audio_decoder_unittest.cc",
 634       "filters/audio_file_reader_unittest.cc",
 635       "filters/blocking_url_protocol_unittest.cc",
 636       "filters/ffmpeg_demuxer_unittest.cc",
 637       "filters/ffmpeg_glue_unittest.cc",
 638       "filters/ffmpeg_video_decoder_unittest.cc",
 639       "filters/in_memory_url_protocol_unittest.cc",
 640     ]
 641   }
 642
 643   if (current_cpu != "arm" && is_chromeos) {
 644     sources += [ "filters/h264_bitstream_buffer_unittest.cc" ]
 645   }
 646
 647   if (proprietary_codecs) {
 648     sources += [
 649       "filters/ffmpeg_aac_bitstream_converter_unittest.cc",
 650       "filters/ffmpeg_h264_to_annex_b_bitstream_converter_unittest.cc",
 651       "filters/h264_to_annex_b_bitstream_converter_unittest.cc",
 652       "formats/common/stream_parser_test_base.cc",
 653       "formats/common/stream_parser_test_base.h",
 654       "formats/mp2t/es_adapter_video_unittest.cc",
 655       "formats/mp2t/es_parser_adts_unittest.cc",
 656       "formats/mp2t/es_parser_h264_unittest.cc",
 657       "formats/mp2t/es_parser_mpeg1audio_unittest.cc",
 658       "formats/mp2t/es_parser_test_base.cc",
 659       "formats/mp2t/es_parser_test_base.h",
 660       "formats/mp2t/mp2t_stream_parser_unittest.cc",
 661       "formats/mp2t/timestamp_unroller_unittest.cc",
 662       "formats/mp4/aac_unittest.cc",
 663       "formats/mp4/avc_unittest.cc",
 664       "formats/mp4/box_reader_unittest.cc",
 665       "formats/mp4/es_descriptor_unittest.cc",
 666       "formats/mp4/mp4_stream_parser_unittest.cc",
 667       "formats/mp4/sample_to_group_iterator_unittest.cc",
 668       "formats/mp4/track_run_iterator_unittest.cc",
 669       "formats/mpeg/adts_stream_parser_unittest.cc",
 670       "formats/mpeg/mpeg1_audio_stream_parser_unittest.cc",
 671     ]
 672   }
 673
 674   if (is_mac || is_ios) {
 675     deps += [ "//media/base/mac" ]
 676   }
 677
 678   if (is_mac) {
 679     sources += [
 680       "midi/midi_manager_mac_unittest.cc",
 681       "video/capture/mac/video_capture_device_factory_mac_unittest.mm",
 682     ]
 683     libs = [
 684       # Required by midi_manager_mac_unittest.cc.
 685       "CoreMIDI.framework",
 686     ]
 687   }
 688
 689   if (use_alsa && use_udev) {
 690     sources += [ "midi/midi_manager_alsa_unittest.cc" ]
 691   }
 692
 693   #      include_dirs += [
 694   #        # Needed by media_drm_bridge.cc.
 695   #        target_gen_dir,
 696   #      ],
 697
 698   configs += [ ":media_config" ]
 699
 700   if (media_use_ffmpeg) {
 701     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 702   }
 703 }
 704
 705 test("media_perftests") {
 706   configs += [ ":media_config" ]
 707   deps = [
 708     ":media",
 709     ":shared_memory_support",
 710     ":test_support",
 711     "//base/test:test_support",
 712     "//media/audio:test_support",
 713     "//media/base:perftests",
 714     "//media/base:test_support",
 715     "//media/test:pipeline_integration_perftests",
 716     "//testing/gmock",
 717     "//testing/gtest",
 718     "//testing/perf",
 719     "//third_party/widevine/cdm:version_h",
 720     "//ui/gfx:test_support",
 721   ]
 722   if (is_android) {
 723     deps += [ "//ui/gl" ]
 724   }
 725   if (media_use_ffmpeg) {
 726     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 727   }
 728 }
 729
 730 source_set("test_support") {
 731   testonly = true
 732   sources = [
 733     "filters/clockless_video_frame_scheduler.cc",
 734     "filters/clockless_video_frame_scheduler.h",
 735     "filters/test_video_frame_scheduler.cc",
 736     "filters/test_video_frame_scheduler.h",
 737     "renderers/mock_gpu_video_accelerator_factories.cc",
 738     "renderers/mock_gpu_video_accelerator_factories.h",
 739     "video/mock_video_decode_accelerator.cc",
 740     "video/mock_video_decode_accelerator.h",
 741   ]
 742   deps = [
 743     ":media",
 744     ":shared_memory_support",
 745     "//base",
 746     "//skia",
 747     "//testing/gmock",
 748     "//testing/gtest",
 749   ]
 750 }
 751
 752 # TODO(dalecurtis): How to split this across audio/base directories??
 753 component("shared_memory_support") {
 754   sources = [
 755     "audio/audio_parameters.cc",
 756     "audio/audio_parameters.h",
 757     "base/audio_bus.cc",
 758     "base/audio_bus.h",
 759     "base/channel_layout.cc",
 760     "base/channel_layout.h",
 761     "base/limits.h",
 762     "base/media_export.h",
 763     "base/vector_math.cc",
 764     "base/vector_math.h",
 765   ]
 766   configs += [
 767     ":media_config",
 768     ":media_implementation",
 769   ]
 770   deps = [
 771     "//base",
 772   ]
 773 }
 774
 775 if (media_use_ffmpeg) {
 776   test("ffmpeg_regression_tests") {
 777     sources = [
 778       "base/run_all_unittests.cc",
 779       "ffmpeg/ffmpeg_regression_tests.cc",
 780     ]
 781
 782     configs += [ "//media:media_config" ]
 783
 784     deps = [
 785       "//base/test:test_support",
 786       "//media",
 787       "//media:test_support",
 788       "//media/audio:test_support",
 789       "//media/base:test_support",
 790       "//media/test:pipeline_integration_tests",
 791       "//testing/gmock",
 792       "//testing/gtest",
 793       "//third_party/ffmpeg",
 794       "//ui/gfx/geometry",
 795       "//ui/gfx:test_support",
 796     ]
 797   }
 798 }