v2/examples/stk/rhodey.ck

   1 // more music for replicants
   2
   3 // patch
   4 Rhodey voc=> JCRev r => Echo a => Echo b => Echo c => dac;
   5
   6 220.0 => voc.freq;
   7 0.8 => voc.gain;
   8 .8 => r.gain;
   9 .2 => r.mix;
  10 1000::ms => a.max => b.max => c.max;
  11 750::ms => a.delay => b.delay => c.delay;
  12 .50 => a.mix => b.mix => c.mix;
  13
  14 // shred to modulate the mix
  15 fun void vecho_Shred( )
  16 {
  17     0.0 => float decider;
  18     0.0 => float mix;
  19     0.0 => float old;
  20     0.0 => float inc;
  21     0 => int n;
  22
  23     // time loop
  24     while( true )
  25     {
  26         Std.rand2f(0.0,1.0) => decider;
  27         if( decider < .3 ) 0.0 => mix;
  28         else if( decider < .6 ) .08 => mix;
  29         else if( decider < .8 ) .5 => mix;
  30         else .15 => mix;
  31
  32         // find the increment
  33         (mix-old)/1000.0 => inc;
  34         1000 => n;
  35         while( n-- )
  36         {
  37             old + inc => old;
  38             old => a.mix => b.mix => c.mix;
  39             1::ms => now;
  40         }
  41         mix => old;
  42         Std.rand2(2,6)::second => now;
  43     }
  44 }
  45
  46
  47 // let echo shred go
  48 spork ~ vecho_Shred();
  49
  50 // scale
  51 [ 0, 2, 4, 7, 9 ] @=> int scale[];
  52
  53 // our main loop
  54 while( true )
  55 {
  56     // pentatonic
  57     scale[Std.rand2(0,scale.cap()-1)] => int freq;
  58
  59     Std.mtof( ( 33 + Std.rand2(0,1) * 12 + freq ) ) => voc.freq;
  60     Std.rand2f( 0.6, 0.8 ) => voc.noteOn;
  61
  62     if( Std.randf() > 0.7 )
  63     { 1000::ms => now; }
  64     else if( Std.randf() > .7 )
  65     { 500::ms => now; }
  66     else if( Std.randf() > -0.8 )
  67     { .250::second => now; }
  68     else
  69     {
  70         0 => int i;
  71         2 * Std.rand2( 1, 3 ) => int pick;
  72         0 => int pick_dir;
  73         0.0 => float pluck;
  74
  75         for( ; i < pick; i++ )
  76         {
  77             Std.rand2f(.4,.6) + i*.035 => pluck;
  78             pluck + -0.02 * (i * pick_dir) => voc.noteOn;
  79             !pick_dir => pick_dir;
  80             250::ms => now;
  81         }
  82     }
  83 }