configure.ac

   1 AC_INIT(Cinelerra, 2.1)
   2
   3 AC_CANONICAL_SYSTEM
   4
   5 # Test for minimal version of autoconf
   6 AC_PREREQ(2.57)
   7
   8 AM_INIT_AUTOMAKE
   9 AC_CONFIG_HEADER(config.h)
  10 AM_GNU_GETTEXT([external])
  11 AM_GNU_GETTEXT_VERSION(0.12.1)
  12 AM_PROG_AS
  13
  14 AC_LANG_CPLUSPLUS
  15 AC_LANG_C
  16 AC_PROG_CXX
  17
  18 AC_ENABLE_SHARED
  19 AC_DISABLE_STATIC
  20 AC_PROG_LIBTOOL
  21
  22 # hack for libtool 1.5 -- this is ugly and probably wrong, but works
  23 if test `libtool --version | grep ltmain.sh | cut -b 25-27` = "1.5"; then
  24    LTC_FLAGS="--tag=CC"
  25    LTCXX_FLAGS="--tag=CXX"
  26 fi
  27 AC_SUBST(LTC_FLAGS)
  28 AC_SUBST(LTCXX_FLAGS)
  29
  30
  31 # hack for using nasm for .S files
  32 CCAS="\$(top_srcdir)/admin/nasm"
  33 AC_SUBST(CCAS)
  34 AC_SUBST(CCASFLAGS)
  35
  36 dnl Check for Video4Linux2
  37 AH_TEMPLATE(HAVE_VIDEO4LINUX2, [Define to 1 if Video4Linux2 is available.])
  38 AC_CHECK_HEADER([linux/videodev2.h],
  39         [AC_CHECK_MEMBER(struct v4l2_buffer.index, [AC_DEFINE(HAVE_VIDEO4LINUX2)], [],
  40                 [#include <linux/time.h>
  41 #include <linux/videodev2.h>])],
  42         [],[#include <linux/time.h>] )
  43
  44 ############## SPECIAL DIRECTORIES
  45 AC_ARG_WITH(plugindir,
  46                                                 AC_HELP_STRING([--with-plugindir], [sets the directory where the plugins should be installed]),
  47                                                 [ plugindir=$withval ],
  48                                                 [ plugindir="\${exec_prefix}/lib/cinelerra" ])
  49 AC_SUBST(plugindir)
  50
  51 AC_ARG_WITH(fontsdir,
  52                                                 AC_HELP_STRING([--with-fontsdir], [sets the directory where the fonts should be installed]),
  53                                                 [ fontsdir=$withval ],
  54                                                 [ fontsdir="\${plugindir}/fonts" ])
  55 AC_SUBST(fontsdir)
  56 ############## END OF SPECIAL DIRECTORIES
  57
  58 ############## XLIB
  59 AC_PATH_XTRA
  60 if test "$no_x" = yes; then
  61   if test "x$have_x" = "xdisabled"; then
  62     AC_MSG_WARN([Do not use --without-x or --with-x=no.])
  63   else
  64     AC_MSG_WARN([X Windows development tools were not found.])
  65     AC_MSG_WARN([Please install xlib-dev or xorg-x11-devel.])
  66   fi
  67   AC_MSG_ERROR([Cinelerra requires X Windows.])
  68 fi
  69 AH_TEMPLATE(HAVE_LIBXXF86VM, [Define to 1 if libXxf86vm is available.])
  70 AC_DEFINE(HAVE_LIBXXF86VM)
  71 ############## END XLIB
  72
  73 ############## SOUND
  74 # the sound options are propagated by SOUND_CFLAGS and SOUND_LDFLAGS
  75 AC_ARG_ENABLE(oss,
  76                                                         AC_HELP_STRING([--disable-oss], [disable support for oss (default=enabled)]))
  77 AC_ARG_ENABLE(alsa,
  78         AC_HELP_STRING([--disable-alsa],[disable support for ALSA (default=autodetect)]),
  79         [enable_alsa=$enableval],[enable_alsa=yes])
  80 AC_ARG_ENABLE(esd,
  81         AC_HELP_STRING([--disable-esd], [disable support for ESD (default=autodetect)]),
  82         [enable_esd=$enableval],[enable_esd=yes])
  83
  84 if test "x$enable_oss" = "xyes" || test "x$enable_oss" = "x"; then
  85         SOUND_CFLAGS="-DHAVE_OSS $SOUND_CFLAGS"
  86 fi
  87 if test "x$enable_alsa" = "xyes"; then
  88         AM_PATH_ALSA(1.0.2,[alsa=yes])
  89         if test "x$alsa" = "xyes"; then
  90                 SOUND_CFLAGS="$ALSA_CFLAGS -DHAVE_ALSA $SOUND_CFLAGS"
  91                 SOUND_LDFLAGS="$ALSA_LIBS $SOUND_LDFLAGS"
  92                 enable_alsa=ok
  93         fi
  94         dnl This added -lasound to LIBS. LIBS is used in every link command.
  95         dnl But we do not want to link all shared libraries against -lasound.
  96         dnl So we remove it again.
  97         LIBS=`echo "$LIBS" | sed -e s/-lasound//g`
  98 fi
  99
 100 if test "x$enable_esd" = "xyes"; then
 101         AM_PATH_ESD(,[esound=yes])
 102         if test "x$esound" = xyes; then
 103                 SOUND_CFLAGS="$ESD_CFLAGS -DHAVE_ESOUND $SOUND_CFLAGS"
 104                 SOUND_LDFLAGS="$ESD_LIBS $SOUND_LDFLAGS"
 105                 enable_esd=ok
 106         fi
 107 fi
 108 AC_SUBST(SOUND_CFLAGS)
 109 AC_SUBST(SOUND_LDFLAGS)
 110 ############### END OF SOUND
 111
 112 ############## MJPEGTOOLS (for YUV4MPEG)
 113 PKG_CHECK_MODULES(MJPEG, mjpegtools,[mjpegtools=yes],:)
 114 AC_SUBST(MJPEG_CFLAGS)
 115 AC_SUBST(MJPEG_LIBS)
 116 AC_MSG_CHECKING([for number of arguments to y4m_write_frame_header])
 117 # check if mjpegtools has 3 arguements for y4m_write_frame_header
 118 # Note: this test came from transcode...
 119 save_CFLAGS="$CFLAGS"
 120 save_LIBS="$LIBS"
 121 CFLAGS="$CFLAGS $MJPEG_CFLAGS"
 122 LIBS="$LIBS $MJPEG_LIBS"
 123 AC_TRY_LINK(
 124 [
 125 #include <mjpegtools/yuv4mpeg.h>
 126 #include <mjpegtools/mpegconsts.h>
 127 ],
 128 [y4m_write_frame_header(1,NULL,NULL)],
 129 [
 130 AC_DEFINE(
 131            [MJPEGTOOLS_Y4M_WRITE_FRAME_HEADER__3ARGS],
 132            [1],
 133            [using y4m_write_frame_header with 3 arguments]
 134           )
 135 mjpeg_version_info="3 arguments (new versions)"
 136 ],[mjpeg_version_info="assuming 2 arguments (older versions)"])
 137 AC_MSG_RESULT($mjpeg_version_info)
 138 CFLAGS="$save_CFLAGS"
 139 LIBS="$save_LIBS"
 140 ############## END MJPEGTOOLS
 141
 142 ############## MISC LIBRARIES
 143 AC_CHECK_HEADER(uuid/uuid.h,[libuuidh=yes])
 144 AC_CHECK_LIB(uuid, uuid_clear,[libuuid=yes])
 145
 146 AC_CHECK_HEADER(fftw3.h,[libfftw3h=yes])
 147 AC_CHECK_LIB(fftw3, fftw_free,[libfftw3=yes])
 148
 149 PKG_CHECK_MODULES(LIBDV,libdv >= 0.103,[libdv=yes],:)
 150 AC_SUBST(LIBDV_CFLAGS)
 151 AC_SUBST(LIBDV_LIBS)
 152
 153 PKG_CHECK_MODULES(PNG,libpng,[libpng=yes],:)
 154
 155 AC_CHECK_HEADER(jpeglib.h,[libjpegh=yes])
 156 AC_CHECK_LIB(jpeg,jpeg_start_decompress,[libjpeg=yes])
 157
 158 AC_CHECK_HEADER(tiffio.h,[libtiffh=yes])
 159 AC_CHECK_LIB(tiff,TIFFOpen,[libtiff=yes])
 160
 161 AC_ARG_ENABLE(freetype2,
 162         AC_HELP_STRING([--enable-freetype2],[enables freetype2 usage (default is use pkg-config detection)]),
 163         [
 164           [freetype2=yes] ],
 165         [ PKG_CHECK_MODULES(FREETYPE,freetype2,[freetype2=yes],:) ])
 166 ############## END OF MISC LIBRARIES
 167
 168 LARGEFILE_CFLAGS="-D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE -D_FILE_OFFSET_BITS=64"
 169 AC_SUBST(LARGEFILE_CFLAGS)
 170
 171 ############## A52DEC
 172 AC_CHECK_LIB(a52,a52_init,[liba52=yes])
 173 AC_CHECK_HEADER(a52dec/a52.h,[liba52h=yes])
 174
 175 if test "x$liba52$liba52h" = "xyesyes"; then
 176     A52DEC_CFLAGS=
 177     A52DEC_LIBS=-la52
 178 fi
 179 AC_SUBST(A52DEC_CFLAGS)
 180 AC_SUBST(A52DEC_LDFLAGS)
 181 ############## END OF A52DEC
 182
 183 ############## LIBSNDFILE
 184 AC_CHECK_LIB(sndfile, sf_open,[libsndfile=yes])
 185 AC_CHECK_HEADERS(sndfile.h,[libsndfileh=yes])
 186 ############## END OF LIBSNDFILE
 187
 188 ############## OpenEXR
 189 PKG_CHECK_MODULES(OPENEXR, OpenEXR,[libOpenEXR=yes],:)
 190 AC_SUBST(OPENEXR_CFLAGS)
 191 AC_SUBST(OPENEXR_LIBS)
 192 ############## END OF OpenEXR
 193
 194 ############## LIBFAAD, LIBFAAC
 195 AC_CHECK_LIB(faac, faacEncOpen,[libfaac=yes])
 196 AC_CHECK_HEADER(faac.h,[libfaach=yes])
 197
 198 AC_CHECK_LIB(faad, faacDecInit,[libfaad=yes],
 199         AC_CHECK_LIB(faad, NeAACDecInit,[libfaad=yes]))
 200 AC_CHECK_HEADER(faad.h,[libfaadh=yes])
 201 if test "x$libfaad$libfaadh" = xyesyes; then
 202     FAAD_CFLAGS=
 203     FAAD_LIBS="-lfaad"
 204 fi
 205 AC_SUBST(FAAD_CFLAGS)
 206 AC_SUBST(FAAD_LIBS)
 207 ############## END OF LIBFAAD, LIBFAAC
 208
 209 ############## FIREWIRE
 210 # firewire settings are propagated through FIREWIRE_CFLAGS and FIREWIRE_LDFLAGS
 211 AC_ARG_ENABLE(firewire,
 212                                                         AC_HELP_STRING([--disable-firewire], [disable support for firewire (default=enabled)]),
 213                                                         [ enable_firewire=$enableval ],
 214                                                         [ enable_firewire=yes ])
 215
 216 if test "x$enable_firewire" = "xyes"; then
 217         PKG_CHECK_MODULES(LIBRAW1394, libraw1394 >= 1.2.0,[libraw1394=yes],:)
 218         PKG_CHECK_MODULES(LIBIEC61883, libiec61883,[libiec61883=yes],:)
 219
 220         AC_CHECK_LIB(avc1394, avc1394_send_command,[libavc1394=yes],:,$LIBRAW1394_LIBS)
 221         AC_CHECK_HEADER([libavc1394/avc1394.h],[libavc1394h=yes])
 222         AC_CHECK_LIB(rom1394, rom1394_get_bus_id,[librom1394=yes],:,$LIBRAW1394_LIBS)
 223         AC_CHECK_HEADER([libavc1394/rom1394.h],[librom1394h=yes])
 224 fi
 225
 226 if test "x$enable_firewire$libraw1394$libiec61883$libavc1394$libavc1394h$librom1394$librom1394h" = "xyesyesyesyesyesyesyes"; then
 227         FIREWIRE_CFLAGS="-DHAVE_FIREWIRE $LIBIEC61883_CFLAGS $LIBRAW1394_CFLAGS"
 228         FIREWIRE_LDFLAGS="-lavc1394 -lrom1394 $LIBIEC61883_LIBS $LIBRAW1394_LIBS"
 229         enable_firewire=ok
 230 fi
 231 AC_SUBST(FIREWIRE_CFLAGS)
 232 AC_SUBST(FIREWIRE_LDFLAGS)
 233 AM_CONDITIONAL(HAVE_FIREWIRE,test "x$enable_firewire" = "xok")
 234 ############## END OF FIREWIRE
 235
 236 ############# BUILDINFO display, (for displaying version / date)
 237 AC_ARG_WITH(buildinfo,
 238           AC_HELP_STRING(
 239                   [--with-buildinfo],
 240                   [includes revision information in the 'About' box; allowed values: svn, git; add /recompile to force rebuild on each make invocation, or cust/"Custom string" for packagers]),
 241         [ buildinfo=$withval],
 242         [ buildinfo="none" ])
 243 AC_SUBST(buildinfo)
 244
 245 BUILDINFO_repository=$(echo $buildinfo | sed 's=/recompile==')
 246 BUILDINFO_recompile=$(echo $buildinfo | sed 's=.*/recompile=yes=')
 247 BUILDINFO_custom=$(echo $buildinfo | sed 's=cust.*=yes=')
 248 BUILDINFO_CUSTOM_TAG=$(echo $buildinfo | sed 's=cust/==')
 249 AC_SUBST(BUILDINFO_CUSTOM_TAG)
 250 AM_CONDITIONAL(BUILDINFO_GIT, test "x$BUILDINFO_repository" = "xgit")
 251 AM_CONDITIONAL(BUILDINFO_SVN, test "x$BUILDINFO_repository" = "xsvn")
 252 AM_CONDITIONAL(BUILDINFO_RECOMPILE, test "x$BUILDINFO_recompile" = "xyes")
 253 AM_CONDITIONAL(BUILDINFO_CUST, test "x$BUILDINFO_custom" = "xyes")
 254
 255 echo removing cinelerra/versioninfo.h to force a re-build
 256 rm -f cinelerra/versioninfo.h > /dev/null 2>&1
 257
 258 ############# END BUILDINFO display, (for displaying version / date)
 259
 260 ############# CSS SUPPORT IN LIBMPEG3
 261 if test "x$enable_css" = "xyes"; then
 262         CSS_CFLAGS="-DHAVE_CSS"
 263 fi
 264 AC_SUBST(CSS_CFLAGS)
 265 AC_ARG_ENABLE(css,
 266                                                         AC_HELP_STRING([--disable-css], [disable support for css in libmpeg3 (default=enabled)]),,
 267                                                         [ enable_css=$enableval ],
 268                                                         [ enable_css=yes ])
 269 ############## END OF CSS SUPPORT IN LIBMPEG3
 270
 271
 272 ############## libx264
 273 LIBX264_LIBS=""
 274 AC_CHECK_LIB(x264, x264_encoder_open,
 275         [libx264=yes LIBX264_LIBS=-lx264],,-lpthread -lm)
 276 if test "x$with_pic" = "xyes"; then
 277         AC_CHECK_LIB(x264_pic, x264_encoder_open,
 278                 [libx264=yes LIBX264_LIBS=-lx264_pic],,-lpthread -lm)
 279 fi
 280 AC_CHECK_HEADER(x264.h, [libx264h=yes])
 281 AC_SUBST(LIBX264_LIBS)
 282 ##############
 283
 284 ############## MMX / 3DNOW  POWERPC / ALTIVEC
 285
 286 AC_ARG_ENABLE(mmx,
 287         AC_HELP_STRING([--enable-mmx], [enables support for mmx (default is autodetect)]),
 288                 [ enable_mmx=$enableval ],[ enable_mmx=auto ])
 289 AC_ARG_ENABLE(3dnow,
 290         AC_HELP_STRING([--enable-3dnow], [enables support for 3dnow (default is disabled)]),
 291                 [ enable_3dnow=$enableval ], [ enable_3dnow=no ])
 292
 293 AC_ARG_ENABLE(altivec,
 294         AC_HELP_STRING([--enable-altivec], [enables altivec support (default is disabled)]),
 295                 [ enable_altivec=$enableval ],
 296                 [ enable_altivec=no ])
 297
 298 case "$target_cpu" in
 299 i586 | i686)
 300         test "x$enable_mmx" = "xauto" && enable_mmx=yes
 301
 302         CPU_CFLAGS="-DX86_CPU $CPU_CFLAGS"
 303
 304         if test "x$enable_mmx" = "xyes"; then
 305                 CPU_CFLAGS="-DHAVE_MMX -DUSE_MMX $CPU_CFLAGS" # -D_MMX_ doesn't work
 306         fi
 307         if test "x$enable_3dnow" = "xyes"; then
 308                 CPU_CFLAGS="-DHAVE_3Dnow $CPU_CFLAGS" # -DUSE_3DNOW --> don't use, not compilin
 309         fi
 310 ;;
 311 powerpc)
 312         CPU_CFLAGS="-mcpu=powerpc $CPU_CFLAGS"
 313         if test "x$enable_altivec" = "xyes"; then
 314                 CPU_CFLAGS="-maltivec -mabi=altivec $CPU_CFLAGS"
 315         fi
 316 ;;
 317 esac
 318
 319 test "x$enable_mmx" = "xauto" && enable_mmx=no
 320
 321 AM_CONDITIONAL(USEMMX, test "x$enable_mmx" = "xyes")
 322 AM_CONDITIONAL(TARGET_BUILTIN_VECTOR,test "x$enable_mmx" = "xyes")
 323 AM_CONDITIONAL(USE3DNOW, test "x$enable_3dnow" = "xyes")
 324 AM_CONDITIONAL(TARGET_ARCH_POWERPC, test "x$target_cpu" = "xpowerpc")
 325 AM_CONDITIONAL(TARGET_ALTIVEC, test "x$enable_altivec" = "xyes")
 326 AC_SUBST(LIBDECORE_LIBADD)
 327 AC_SUBST(CPU_CFLAGS)
 328
 329 ############## END OF MMX / 3DNOW
 330
 331 ############ external ffmpeg
 332 AC_ARG_WITH([external-ffmpeg], AC_HELP_STRING([--with-external-ffmpeg], [use external ffmpeg library]))
 333
 334 if test "x$with_external_ffmpeg" = "xyes"; then
 335      PKG_CHECK_MODULES([FFMPEG], [libavcodec libpostproc])
 336      FFMPEG_FOLDER=""
 337      FFMPEG_EXTERNALTEXT="External ffmpeg"
 338 else
 339      FFMPEG_FOLDER=ffmpeg
 340      FFMPEG_CFLAGS="-I\$(top_srcdir)/quicktime/ffmpeg/libavcodec"
 341      FFMPEG_LIBS="ffmpeg/libavcodec/libavcodec.la"
 342      FFMPEG_EXTERNALTEXT="Internal ffmpeg"
 343 fi
 344
 345 AC_SUBST(FFMPEG_FOLDER)
 346 AC_SUBST(FFMPEG_CFLAGS)
 347 AC_SUBST(FFMPEG_LIBS)
 348 AC_SUBST(FFMPEG_EXTERNALTEXT)
 349 ############# END external ffmpeg
 350
 351 ############# run ffmpeg configure to generates avconfig.h
 352 echo --- FFMPEG CONFIGURATION SECTION --------------
 353 if test "x$with_external_ffmpeg" = "xyes"; then
 354         echo Using external ffmpeg - no configuration needed
 355 else
 356         ff_conf_args=" "
 357
 358         if test "x$enable_mmx" = "xno"; then
 359                 ff_conf_args="$ff_conf_args --disable-mmx"
 360         fi
 361
 362         # Where altivec is not present
 363         if test "x$enable_altivec" = "xno"; then
 364                 ff_conf_args="$ff_conf_args --disable-altivec"
 365         fi
 366
 367
 368         srcdir_c=$(readlink -f $srcdir)
 369         mkdir -p quicktime/ffmpeg/ > /dev/null 2>&1
 370         cd quicktime/ffmpeg/
 371         echo quicktime/ffmpeg/configure $ff_conf_args
 372         $srcdir_c/quicktime/ffmpeg/configure $ff_conf_args
 373         cd ../../
 374 fi
 375 echo --------------------------------------------------
 376 ############# END run ffmpeg configure to generates avconfig.h
 377
 378 ############## XIPH
 379 PKG_CHECK_MODULES(libogg,ogg >= 1.1,[libogg=yes],:)
 380 PKG_CHECK_MODULES(libvorbis,vorbis,[libvorbis=yes],:)
 381 PKG_CHECK_MODULES(libvorbisenc,vorbisenc,[libvorbisenc=yes],:)
 382 PKG_CHECK_MODULES(libvorbisfile,vorbisfile,[libvorbisfile=yes],:)
 383 PKG_CHECK_MODULES(libtheora,theora,[libtheora=yes],:)
 384 XIPH_CFLAGS="$libogg_CFLAGS $libvorbis_CFLAGS $libvorbisenc_CFLAGS $libvorbisfile_CFLAGS $libtheora_CFLAGS"
 385 XIPH_LIBS="$libogg_LIBS $libvorbis_LIBS $libvorbisenc_LIBS $libvorbisfile_LIBS $libtheora_LIBS"
 386 AC_SUBST(XIPH_CFLAGS)
 387 AC_SUBST(XIPH_LIBS)
 388 ############## END OF XIPH
 389
 390 ############## LAME
 391 # Just test to see if we have lame installed.
 392 AC_CHECK_HEADER(lame/lame.h,[libmp3lameh=yes])
 393 AC_CHECK_LIB(mp3lame,lame_init,[libmp3lame=yes],,[$XIPH_LIBS])
 394 # END LAME
 395
 396 ############## OpenGL
 397 AH_TEMPLATE(HAVE_GL, [Define to 1 if OpenGL 2.0 is available.])
 398 AC_ARG_ENABLE(opengl,
 399         AC_HELP_STRING([--disable-opengl],
 400                 [disables hardware accelerated rendering (default=autodetect, requires OpenGL 2.0)]),
 401         [ enable_opengl=$enableval ],
 402         [ enable_opengl=yes ])
 403 if test "x$enableval" = "xyes"; then
 404         AC_CHECK_LIB([GL], [glUseProgram],
 405                 [OPENGL_LIBS="-lGL"; libGL=yes],
 406 # On SUSE 10.1, NVidia places the OpenGL 2.0 capable library in /usr/X11R6/lib
 407 # but it doesn't place a libGL.so there, so the linker won't pick it up
 408 # we have to use the explicit libGL.so.1 path.
 409                 save_LIBS="$LIBS"
 410                 LIBS="/usr/X11R6/lib/libGL.so.1"
 411                 AC_MSG_CHECKING(for glUseProgram in /usr/X11R6/lib/libGL.so.1)
 412                 AC_TRY_LINK([],[extern int glUseProgram(); glUseProgram();],
 413                         [OPENGL_LIBS="/usr/X11R6/lib/libGL.so.1"; libGL=yes],[libGL=no])
 414                 AC_MSG_RESULT([$libGL])
 415                 LIBS="$save_LIBS"
 416         )
 417 fi
 418 if test "x$libGL" = "xyes"; then
 419         enable_opengl=ok
 420         OPENGL_LIBS="-lGLU $OPENGL_LIBS"
 421         AC_DEFINE(HAVE_GL)
 422 fi
 423 AC_SUBST(OPENGL_LIBS)
 424 # END OpenGL
 425
 426
 427 ############## NoBug build levels
 428 AC_ARG_ENABLE(alpha, AC_HELP_STRING([--enable-alpha], [select NoBug ALPHA build level]),
 429               AC_DEFINE(EBUG_ALPHA),
 430 [
 431 AC_ARG_ENABLE(beta, AC_HELP_STRING([--enable-beta], [select NoBug BETA build level]),
 432               AC_DEFINE(EBUG_BETA),
 433 [
 434 AC_ARG_ENABLE(release, AC_HELP_STRING([--enable-release], [select NoBug RELEASE build level]),
 435               AC_DEFINE(NDEBUG),
 436
 437 # default to ALPHA
 438               AC_DEFINE(EBUG_ALPHA)
 439 )])])
 440 # END NoBug
 441
 442
 443 ############## .png TO .o CONVERSION
 444
 445 AC_CHECK_TOOL(OBJCOPY, objcopy)
 446 if test "x$OBJCOPY" = "x"; then
 447         AC_MSG_ERROR("objcopy from GNU binutils >= 2.11.90 not found")
 448 fi
 449 AC_CHECK_TOOL(OBJDUMP, objdump)
 450 dnl extract target and architecture if objdump was found
 451 if test "x$OBJDUMP" = "x"; then :; else
 452   AC_MSG_CHECKING(for object target)
 453   octarget=`$OBJDUMP --info | sed -ne '2p'` # extract first target
 454   AC_MSG_RESULT($octarget)
 455   AC_MSG_CHECKING(for object architecture)
 456   ocarch=`$OBJDUMP --info | sed -ne '4p'` # extract corresponding arch
 457   AC_MSG_RESULT($ocarch)
 458 fi
 459 AC_SUBST(OBJCOPYTARGET, $octarget)
 460 AC_SUBST(OBJCOPYARCH, $ocarch)
 461
 462 ############## END of .png TO .o CONVERSION
 463
 464
 465 AC_OUTPUT(Makefile cinelerra-cvs-current.spec po/Makefile.in \
 466         m4/Makefile \
 467                                         libmpeg3/Makefile libmpeg3/video/Makefile libmpeg3/audio/Makefile \
 468                                         quicktime/Makefile \
 469                                         quicktime/encore50/Makefile \
 470         quicktime/ffmpeg/Makefile \
 471         quicktime/ffmpeg/libavcodec/Makefile \
 472         quicktime/ffmpeg/libavcodec/i386/Makefile \
 473         quicktime/ffmpeg/libavcodec/ppc/Makefile \
 474                                         mpeg2enc/Makefile toolame-02l/Makefile \
 475                                         guicast/Makefile cinelerra/Makefile \
 476         cinelerra/data/Makefile \
 477         mplexlo/Makefile \
 478                                         plugins/colors/Makefile \
 479                                         plugins/libfourier/Makefile \
 480                                         plugins/libeffecttv/Makefile \
 481                                         plugins/Makefile
 482                                         plugins/1080to540/Makefile \
 483                                         plugins/histogram/Makefile \
 484                                         plugins/720to480/Makefile \
 485                                         plugins/bandslide/Makefile \
 486                                         plugins/bandwipe/Makefile
 487                                         plugins/blur/Makefile
 488                                         plugins/brightness/Makefile \
 489                                         plugins/burn/Makefile plugins/parametric/Makefile plugins/aging/Makefile \
 490                                         plugins/cdripper/Makefile \
 491                                         plugins/chromakey/Makefile \
 492                                         plugins/chromakeyhsv/Makefile \
 493                                         plugins/colorbalance/Makefile \
 494                                         plugins/compressor/Makefile \
 495                                         plugins/crossfade/Makefile \
 496                                         plugins/decimate/Makefile \
 497                                         plugins/deinterlace/Makefile plugins/delayaudio/Makefile plugins/delayvideo/Makefile \
 498                                         plugins/denoise/Makefile plugins/denoisefft/Makefile plugins/denoisevideo/Makefile \
 499                                         plugins/denoisemjpeg/Makefile \
 500                                         plugins/despike/Makefile plugins/dissolve/Makefile plugins/dot/Makefile \
 501                                         plugins/fieldframe/Makefile plugins/flip/Makefile plugins/framefield/Makefile \
 502                                         plugins/freeverb/Makefile plugins/freezeframe/Makefile plugins/gain/Makefile \
 503         plugins/gamma/Makefile \
 504                                         plugins/holo/Makefile plugins/huesaturation/Makefile \
 505                                         plugins/interpolate/Makefile \
 506                                         plugins/interpolateaudio/Makefile \
 507                                         plugins/interpolatevideo/Makefile \
 508                                         plugins/invertaudio/Makefile plugins/invertvideo/Makefile plugins/irissquare/Makefile \
 509                                         plugins/ivtc/Makefile \
 510         plugins/liveaudio/Makefile \
 511         plugins/livevideo/Makefile \
 512                                         plugins/loopaudio/Makefile \
 513                                         plugins/loopvideo/Makefile \
 514                                         plugins/motion/Makefile \
 515                                         plugins/motionblur/Makefile \
 516                                         plugins/normalize/Makefile \
 517                                         plugins/oilpainting/Makefile \
 518                                         plugins/overlay/Makefile \
 519         plugins/overlayaudio/Makefile \
 520                                         plugins/pitch/Makefile \
 521                                         plugins/polar/Makefile \
 522                                         plugins/reframert/Makefile
 523                                         plugins/reframe/Makefile plugins/resample/Makefile plugins/reverb/Makefile \
 524                                         plugins/reverseaudio/Makefile plugins/reversevideo/Makefile plugins/rgb601/Makefile \
 525                                         plugins/rotate/Makefile \
 526                                         plugins/scale/Makefile \
 527                                         plugins/denoiseseltempavg/Makefile \
 528                                         plugins/shapewipe/Makefile \
 529                                         plugins/sharpen/Makefile \
 530                                         plugins/shiftinterlace/Makefile plugins/slide/Makefile plugins/spectrogram/Makefile \
 531         plugins/suv/Makefile \
 532         plugins/suv/data/Makefile \
 533         plugins/bluedottheme/Makefile \
 534         plugins/bluedottheme/data/Makefile \
 535         plugins/defaulttheme/Makefile \
 536         plugins/defaulttheme/data/Makefile \
 537                                         plugins/swapchannels/Makefile \
 538                                         plugins/synthesizer/Makefile \
 539                                         plugins/threshold/Makefile \
 540                                         plugins/timeavg/Makefile \
 541                                         plugins/timestretch/Makefile plugins/titler/Makefile plugins/translate/Makefile \
 542                                         plugins/unsharp/Makefile \
 543                                         plugins/videoscope/Makefile plugins/wave/Makefile plugins/whirl/Makefile \
 544                                         plugins/wipe/Makefile \
 545                                         plugins/yuv/Makefile \
 546                                         plugins/downsample/Makefile plugins/flash/Makefile plugins/gradient/Makefile \
 547                                         plugins/level/Makefile plugins/linearblur/Makefile \
 548                                         plugins/perspective/Makefile plugins/radialblur/Makefile plugins/zoomblur/Makefile \
 549                                         plugins/timefront/Makefile \
 550                                         plugins/svg/Makefile \
 551                                         plugins/diffkey/Makefile \
 552                                         plugins/fonts/Makefile \
 553                                         image/Makefile)
 554
 555 succeeded=yes
 556 AC_DEFUN([RPT],[if test "x$$1" = "xyes"; then status=found; else status=missing; succeeded=no; fi
 557 echo "AC_HELP_STRING($2,$status)"])
 558
 559 echo
 560 echo "Summary of mandatory components:"
 561 RPT(libogg,libogg)
 562 RPT(libvorbis,libvorbis)
 563 RPT(libvorbisenc,libvorbisenc)
 564 RPT(libvorbisfile,libvorbisfile)
 565 RPT(libtheora,libtheora)
 566 RPT(libOpenEXR,OpenEXR)
 567 RPT(libdv,libdv)
 568 RPT(libpng,libpng)
 569 RPT(libjpeg,libjpeg libraries)
 570 RPT(libjpegh,libjpeg headers)
 571 RPT(libtiff,libtiff libraries)
 572 RPT(libtiffh,libtiff headers)
 573 RPT(freetype2,FreeType 2)
 574 RPT(libx264,libx264 libraries)
 575 RPT(libx264h,libx264 headers)
 576 RPT(libuuid,libuuid libraries)
 577 RPT(libuuidh,libuuid headers)
 578 RPT(mjpegtools,mjpegtools)
 579 RPT(libfftw3,libfftw3 libraries)
 580 RPT(libfftw3h,libfftw3 headers)
 581 RPT(liba52,liba52 libraries)
 582 RPT(liba52h,liba52 headers)
 583 RPT(libmp3lame,libmp3lame libraries)
 584 RPT(libmp3lameh,libmp3lame headers)
 585 RPT(libsndfile,libsndfile libraries)
 586 RPT(libsndfileh,libsndfile headers)
 587 RPT(libfaac,libfaac libraries)
 588 RPT(libfaach,libfaac headers)
 589 RPT(libfaad,libfaad libraries)
 590 RPT(libfaadh,libfaad headers)
 591 mandatory="$succeeded"
 592
 593 echo
 594 echo "Summary of optional components:"
 595 AC_DEFUN([ORPT],[if test "x$$1" = "xno"; then
 596         echo "$2 was opted out with $3"
 597 else
 598         if test "x$$1" = "xok"; then component=enabled; else component=disabled; fi
 599         $4
 600         echo "$2 is $component"
 601 fi])
 602 ORPT(enable_esd,ESD (Enlightenment Sound Daemon),--disable-esd,RPT(esound,ESD subsystem))
 603 ORPT(enable_alsa,ALSA,--disable-alsa,RPT(alsa,ALSA subsystem))
 604 ORPT(enable_firewire,Firewire,--disable-firewire,
 605         RPT(libraw1394,libraw1394)
 606         RPT(libiec61883,libiec61883)
 607         RPT(libavc1394,libavc1394 libraries)
 608         RPT(libavc1394h,libavc1394 headers)
 609         RPT(librom1394,librom1394 libraries)
 610         RPT(librom1394h,librom1394 headers)
 611 )
 612 ORPT(enable_opengl,Hardware acceleration using OpenGL 2.0,--disable-opengl,
 613         RPT(libGL,OpenGL 2.0 libraries)
 614 )
 615
 616 if test "x$mandatory" = "xno"; then
 617         echo
 618         echo "WARNING: Mandatory components are missing; compilation may fail!"
 619 else
 620         echo
 621         echo "Now type"; echo "          make"; echo; echo "to start compilation."
 622 fi