m4/intmax.m4

   1 # intmax.m4 serial 2 (gettext-0.14.2)
   2 dnl Copyright (C) 2002-2005 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8 dnl Test whether the system has the 'intmax_t' type, but don't attempt to
   9 dnl find a replacement if it is lacking.
  10
  11 AC_DEFUN([gt_TYPE_INTMAX_T],
  12 [
  13   AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
  14   AC_REQUIRE([gl_AC_HEADER_STDINT_H])
  15   AC_CACHE_CHECK(for intmax_t, gt_cv_c_intmax_t,
  16     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  17 #include <stddef.h>
  18 #include <stdlib.h>
  19 #if HAVE_STDINT_H_WITH_UINTMAX
  20 #include <stdint.h>
  21 #endif
  22 #if HAVE_INTTYPES_H_WITH_UINTMAX
  23 #include <inttypes.h>
  24 #endif
  25 ]], [[intmax_t x = -1;]])],[gt_cv_c_intmax_t=yes],[gt_cv_c_intmax_t=no])])
  26   if test $gt_cv_c_intmax_t = yes; then
  27     AC_DEFINE(HAVE_INTMAX_T, 1,
  28       [Define if you have the 'intmax_t' type in <stdint.h> or <inttypes.h>.])
  29   fi
  30 ])