tools/removeCustomizationDeclarations.pl

   1 # Purpose: remove customization declarations from shared object templates.
   2 #          Handle p4 checkouts of TPFs requiring changes and do a templatecompile on them.
   3 #
   4 # Strategy:
   5 #
   6 # * Make deletions at the line level: either a whole line stays or gets deleted.
   7 # * Identify lines for removal.
   8 #   * Line removal starts when we see "paletteColorCustomizationVariables = [" or "rangedIntCustomizationVariables = [".
   9 #   * Line remove ends when we hit a line that doesn't match "[variableName=".
  10 #
  11 # * P4 handling.
  12 #
  13 #   * Two passes over the file.  First one is read-only pass where we scan for "paletteColorCustomizationVariables"
  14 #     or "rangedIntCustomizationVariables".
  15 #   * If first pass find a match on any line, start an edit pass.  Edit pass does this:
  16 #     * Does a p4 edit on the tpf and iff.  Die if unsuccessful.
  17 #     * Generates new file contents to a temporary file.
  18 #     * Closes the temporary file.
  19 #     * Renames the temporary file to the p4 file.
  20 #     * Does a templateCompiler -compile on the new file.
  21
  22 use strict;
  23
  24 use Cwd;
  25 use File::Find;
  26 use File::Spec;
  27 use File::Temp;
  28
  29 # =====================================================================
  30
  31 (@ARGV > 0) or die "Usage: perl removeCustomizationDeclarations.pl <TPF directory> [<TPF directory> ...]\n";
  32
  33 # =====================================================================
  34
  35 my $debug = 0;
  36
  37 my $checkedFileCount = 0;
  38 my $changedFileCount = 0;
  39
  40 my $newTotalBytes = 0;
  41 my $savedBytes    = 0;
  42
  43 my $p4EditRetryCount = 10;
  44
  45 # =====================================================================
  46
  47 sub doesFileNeedModification
  48 {
  49     my $tpfFileName = shift;
  50
  51     # Looks like the base must have this.
  52     if ($tpfFileName =~ m/shared_tangible_base\.tpf$/)
  53     {
  54         return 0;
  55     }
  56
  57     my $inputFile;
  58     open($inputFile, "< " . $tpfFileName) or die "Failed to open [$tpfFileName] for reading: $!";
  59
  60     my $foundMatch = 0;
  61
  62     while (<$inputFile>)
  63     {
  64         ++$foundMatch if (m/(paletteColorCustomizationVariables|rangedIntCustomizationVariables)\s*=/);
  65     }
  66
  67     close($inputFile) or die "Failed to close file [$tpfFileName]: $!";
  68
  69     ++$checkedFileCount;
  70
  71     return ($foundMatch > 0);
  72 }
  73
  74 # ----------------------------------------------------------------------
  75
  76 sub getIffFileName
  77 {
  78     my $iffFileName = shift;
  79     $iffFileName =~ s!/dsrc/!/data/!;
  80     $iffFileName =~ s!\.tpf$!.iff!;
  81
  82     return $iffFileName;
  83 }
  84
  85 # ----------------------------------------------------------------------
  86
  87 sub p4EditFile
  88 {
  89     my $fileName     = shift;
  90     my $attemptCount = 0;
  91
  92     # Do a p4 edit on the file.
  93     do
  94     {
  95         ++$attemptCount;
  96         my $commandResult = `p4 edit $fileName`;
  97         print "p4 edit $fileName: $commandResult\n" if $debug;
  98     } while (($? != 0) && ($attemptCount < $p4EditRetryCount));
  99
 100     die "Failed to run p4 edit on $fileName, tried $attemptCount times: [$?]" if ($? != 0);
 101 }
 102
 103 # ----------------------------------------------------------------------
 104
 105 sub removeCustomizationDeclarations
 106 {
 107     # Get args.
 108     my $tpfFileName = shift;
 109     my $iffFileName = shift;
 110
 111     # Find directory name of tpf.
 112     my ($tpfVolumeName, $tpfDirName, $unusedFileName) = File::Spec->splitpath($tpfFileName);
 113     my $tempFileDir = File::Spec->catpath($tpfVolumeName, $tpfDirName, "");
 114     print "tempFileDir=$tempFileDir\n" if $debug;
 115
 116     # Create the tempfile.
 117     my ($outputFile, $outputFileName) = File::Temp::tempfile(DIR => $tempFileDir);
 118     die "failed to create tempfile: $!" if !defined($outputFile);
 119
 120     # Open the tpf file for reading.
 121     my $inputFile;
 122     open($inputFile, "< " . $tpfFileName) or die "failed to open tpf file [$tpfFileName] for reading: $!";
 123
 124     my $skipLines = 0;
 125
 126     # Process the TPF
 127     while (<$inputFile>)
 128     {
 129         chomp();
 130
 131         # Determine if we should be skipping lines.
 132         if (!$skipLines)
 133         {
 134             # Check if we should start skipping lines.
 135             $skipLines = m/(?:paletteColorCustomizationVariables|rangedIntCustomizationVariables)\s*=/;
 136         }
 137         else
 138         {
 139             # Check if should keep skipping lines.
 140             $skipLines = m/\[variableName\s*=/;
 141         }
 142
 143         print $outputFile "$_\n" if !$skipLines;
 144         print "DEL: $_\n" if $skipLines && $debug;
 145     }
 146
 147     # Close up.
 148     close($inputFile) or die "failed to close tpf file [$tpfFileName]: $!";
 149     close($outputFile) or die "failed to close temp output file [$outputFileName]: $!";
 150
 151     # Rename modified file to tpf file.
 152     rename($outputFileName, $tpfFileName) or die "failed to rename modified tpf file [$outputFileName] to [$tpfFileName]: $!";
 153
 154     ++$changedFileCount;
 155 }
 156
 157 # ----------------------------------------------------------------------
 158
 159 sub compileTpf
 160 {
 161     my $tpfFileName = shift;
 162     my $output = `TemplateCompiler -compile $tpfFileName`;
 163     die "failed to compile $tpfFileName: $output" if ($? != 0);
 164     print "TemplateCompiler -compile $tpfFileName: $output\n" if $debug;
 165 }
 166
 167 # ----------------------------------------------------------------------
 168
 169 sub filenameProcessor
 170 {
 171     # Check if target is a file, is readable and is a TPF.
 172     if (-f and -r and m/\.tpf$/i)
 173     {
 174         # Process the file.
 175         my $tpfFileName = $File::Find::name;
 176         print "Processing file [$tpfFileName].\n" if $debug;
 177
 178         # Check if the file needs to be modified.
 179         if (doesFileNeedModification($tpfFileName))
 180         {
 181             print "Modifying [$tpfFileName].\n";
 182
 183             # Get the iff filename for the given tpf filename.
 184             my $iffFileName = getIffFileName($tpfFileName);
 185
 186             # Get stats for the original iff file.
 187             my @originalStats = stat $iffFileName;
 188
 189             # Open files for edit.
 190             p4EditFile($tpfFileName);
 191             p4EditFile($iffFileName);
 192
 193             # Remove the customization-related entries.
 194             removeCustomizationDeclarations($tpfFileName, $iffFileName);
 195
 196             # Compile the tpf into the iff.
 197             compileTpf($tpfFileName);
 198
 199             # Get stats for the modified iff file.
 200             my @modifiedStats = stat $iffFileName;
 201
 202             # Update statistics.
 203             $newTotalBytes += $modifiedStats[7];
 204             $savedBytes    += ($originalStats[7] - $modifiedStats[7]);
 205         }
 206     }
 207 }
 208
 209 # ----------------------------------------------------------------------
 210
 211 my @dirs;
 212
 213 foreach my $dir (@ARGV)
 214 {
 215     push @dirs, Cwd::abs_path($dir);
 216 }
 217
 218 File::Find::find(\&filenameProcessor, @dirs);
 219
 220 print "Statistics:\n";
 221 print  "\tfiles checked:   $checkedFileCount\n";
 222 print  "\tfiles modified:  $changedFileCount\n";
 223 printf "\tmodified size:   %.2f KB\n", $newTotalBytes / (1024);
 224 printf "\treduced size by: %.2f KB\n", $savedBytes / (1024);
 225
 226 # =====================================================================